lecdon.f

Go to the documentation of this file.

!                   *****************
                    SUBROUTINE lecdon
!                   *****************
!
     &(f1,name1,mode1,f2,name2,mode2, f3,name3,mode3,
     & npoin2,ndon,fformat,indic,chdon,texte,trouve)
!
!***********************************************************************
! TOMAWAC   V6P3                                   21/06/2011
!***********************************************************************
!
!brief    THIS SUBROUTINE PROJECTS THE CURRENTS / WINDS ON THE
!+                COMPUTATION MESH.
!+
!+           (INSPIRED FROM SUBROUTINE FOND IN TELEMAC2D)
!
!history  F.MARCOS (LNH)
!+        01/02/95
!+        V1P0
!+
!
!history  N.DURAND (HRW), S.E.BOURBAN (HRW)
!+        13/07/2010
!+        V6P0
!+   Translation of French comments within the FORTRAN sources into
!+   English comments
!
!history  N.DURAND (HRW), S.E.BOURBAN (HRW)
!+        21/08/2010
!+        V6P0
!+   Creation of DOXYGEN tags for automated documentation and
!+   cross-referencing of the FORTRAN sources
!
!history  G.MATTAROLO (EDF - LNHE)
!+        20/06/2011
!+        V6P1
!+   Translation of French names of the variables in argument
!
!history  J-M HERVOUET (EDF - LNHE)
!+        16/11/2012
!+        V6P3
!+   Only SELAFIN format with same mesh kept.
!
!history  J-M HERVOUET (EDF - LNHE)
!+        21/01/2013
!+        V6P3
!+   Generalised for reading 3 variables with given names.
!
!history Y AUDOUIN (LNHE)
!+       25/05/2015
!+       V7P0
!+       Modification to comply with the hermes module
!
!~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~
!| CHDON          |-->| NAME OF THE VARIABLE READ FROM THE DATA FILE
!| F1             |<--| FIRST VARIABLE TO READ
!| F2             |<--| SECOND VARIABLE TO READ
!| F3             |<--| THIRD VARIABLE TO READ
!| INDIC          |-->| FILE FORMAT
!| MODE1          |-->| MODE: 0= DO NOT READ
!|                |   |       1= READ IF PRESENT
!| MODE2          |-->| LIKE MODE1 FOR SECOND VARIABLE
!| MODE3          |-->| LIKE MODE1 FOR THIRD VARIABLE
!| NAME1          |-->| NAME OF FIRST VARIABLE
!| NAME2          |-->| NAME OF SECOND VARIABLE
!| NAME3          |-->| NAME OF THIRD VARIABLE
!| NDON           |-->| LOGICAL UNIT NUMBER OF THA DATA FILE
!| NPOIN2         |-->| NUMBER OF POINTS IN 2D MESH
!| TEXTE          |<->| NAME OF VARIABLES IN THE SERAFIN FILE
!| TROUVE         |<->| 3 LOGICAL, WILL SAY IF VARIABLES HAVE BEEN FOUND
!| X              |-->| ABSCISSAE OF POINTS IN THE MESH
!| Y              |-->| ORDINATES OF POINTS IN THE MESH
!~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~
!
      USE bief
      USE interface_hermes
      USE declarations_special
      USE declarations_tomawac, ONLY : nptt
      IMPLICIT NONE
!
!
!+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+
!
      INTEGER, INTENT(IN)             :: NDON,NPOIN2,INDIC
      INTEGER, INTENT(IN)             :: MODE1,MODE2,MODE3
      DOUBLE PRECISION, INTENT(INOUT) :: F1(npoin2),F2(npoin2)
      DOUBLE PRECISION, INTENT(INOUT) :: F3(npoin2)
      CHARACTER(LEN=8), INTENT(IN)    :: FFORMAT
      CHARACTER(LEN=7), INTENT(IN)    :: CHDON
      CHARACTER(LEN=32),INTENT(IN)    :: NAME1,NAME2,NAME3
      CHARACTER(LEN=32),INTENT(INOUT) :: TEXTE(30)
      LOGICAL, INTENT(INOUT)          :: TROUVE(3)
!
!+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+
!
      CHARACTER(LEN=16), ALLOCATABLE :: VAR_NAME(:), VAR_UNIT(:)
      INTEGER NP,I,J,NVAR,MODE(3)
      DOUBLE PRECISION TIME
      CHARACTER(LEN=32) NAME(3),FULL_NAME(3)
      CHARACTER(LEN=80) TITCAS
      INTEGER :: RECORD, IERR
!
!-----------------------------------------------------------------------
!
      mode(1)=mode1
      mode(2)=mode2
      mode(3)=mode3
      name(1)=name1
      name(2)=name2
      name(3)=name3
!
!-----------------------------------------------------------------------
!     READS THE POINTS FROM LOGICAL UNIT NDON
!-----------------------------------------------------------------------
!
      IF(indic.EQ.3) THEN
!
!       -----------------------------------------------------------------
!       TELEMAC FORMAT,
!       VARIABLES 1 AND 2 ARE THE X AND Y COMPONENTS OF THE WIND
!       -----------------------------------------------------------------
!
        ! Getting title
        CALL get_mesh_title(fformat,ndon,titcas,ierr)
        CALL check_call(ierr,'LECDON:GET_MESH_TITLE')
        !
        CALL get_data_nvar(fformat,ndon,nvar,ierr)
        CALL check_call(ierr,'LECDON:GET_DATA_NVAR')
        !
        ALLOCATE(var_name(nvar),stat=ierr)
        CALL check_allocate(ierr,'LECDON:VAR_NAME')
        ALLOCATE(var_unit(nvar),stat=ierr)
        CALL check_allocate(ierr,'LECDON:VAR_UNIT')
        CALL get_data_var_list(fformat,ndon,nvar,var_name,var_unit,ierr)
        CALL check_call(ierr,'LECDON:GET_DATA_VAR_LIST')
        DO i=1,nvar
          texte(i)(1:16) = var_name(i)
          texte(i)(17:32) = var_unit(i)
          ! CHECK IF THE VARIABLE ARE IN THE FILE
          DO j=1,3
            IF((texte(i).EQ.name(j)).AND.
     &        mode(j).GT.0) THEN
              trouve(j) = .true.
              full_name(j) = name(j)
            ENDIF
          ENDDO
        ENDDO
        DEALLOCATE(var_name)
        DEALLOCATE(var_unit)
        ! get the number of point
        CALL get_mesh_npoin(fformat,ndon,point_bnd_elt_type,np,ierr)
        CALL check_call(ierr,'LECDON:GET_MESH_NPOIN')
        WRITE(lu,*) '--------------------------------------------'
        WRITE(lu,*) 'LECDON : READING OF TELEMAC DATA FILE '
        WRITE(lu,*) '         FILE TITLE : ',titcas
        WRITE(lu,*) '         NUMBER OF POINTS   : ',np
        WRITE(lu,*) '--------------------------------------------'
        IF(np.NE.npoin2) THEN
          WRITE(lu,*) ' '
          WRITE(lu,*) 'THE MESH OF THE CURRENTS FILE'
          WRITE(lu,*) 'IS DIFFERENT FROM THE GEOMETRY FILE'
          WRITE(lu,*) ' '
          CALL plante(1)
          stop
        ENDIF
        ! Timesteps
        CALL get_data_ntimestep(fformat,ndon,nptt,ierr)
        record = nptt - 1
        CALL get_data_time(fformat,ndon,record,time,ierr)
        ! Check if all the variables are found for record1
        DO j=1,3
          IF(mode(j).EQ.2.AND..NOT.trouve(j)) THEN
            WRITE(lu,*) 'LECDON: VARIABLE ',name1,' NOT FOUND'
            WRITE(lu,*) trim(name(j)(1:16))
            CALL plante(1)
            stop
          ELSEIF(mode(j).GT.0.AND.trouve(j)) THEN
            WRITE(lu,*) 'VARIABLE ',j,' READ (',
     &      trim(name(j)(1:16)),') AT TIME ',time
            ! Read the data for varialbe j on record1
            IF(j.EQ.1) THEN
              CALL get_data_value(fformat,ndon,record,
     &                            full_name(j),f1,np,ierr)
            ELSEIF(j.EQ.2) THEN
              CALL get_data_value(fformat,ndon,record,
     &                            full_name(j),f2,np,ierr)
            ELSEIF(j.EQ.3) THEN
              CALL get_data_value(fformat,ndon,record,
     &                            full_name(j),f3,np,ierr)
            ENDIF
          ENDIF
        ENDDO
!
      ELSEIF(indic.EQ.4) THEN
!
!     ------------------------------------------------------------------
!       READS A USER-DEFINED FORMAT
!     ------------------------------------------------------------------
!
        IF(chdon(1:1).EQ.'C') THEN
!         READS A CURRENT FIELD
          CALL couuti(ndon,fformat)
        ELSEIF(chdon(1:1).EQ.'W') THEN
!         READS A WIND FIELD
          CALL venuti(ndon,fformat)
        ELSE
          WRITE(lu,*) 'UNKNOWN DATA TYPE'
          CALL plante(1)
          stop
        ENDIF
!
      ELSE
        WRITE(lu,*)'***********************************************'
        WRITE(lu,*)'LECDON : INDICATOR OF FORMAT FOR THE   '
        WRITE(lu,*)'         DATA FILE UNKNOWN :',indic
        WRITE(lu,*)'***********************************************'
        CALL plante(1)
        stop
      ENDIF
!
!-----------------------------------------------------------------------
!
      RETURN
!
!     IF FAILED TO READ THE FILE ...
!
      WRITE(lu,*)'*********************************************'
      WRITE(lu,*)'  ERROR WHILE READING DATA FILE '
      WRITE(lu,*)'    OR UNEXPECTED END OF FILE           '
      WRITE(lu,*)'*********************************************'
      CALL plante(1)
!
!-----------------------------------------------------------------------
!
      RETURN
      END