lecdoi.f

Go to the documentation of this file.

!                   *****************
                    SUBROUTINE lecdoi
!                   *****************
!
     &(f1,name1,mode1, f2,name2,mode2,f3,name3,mode3,
     & npoin2,ndon,fformat,at,tv1,tv2,
     & f11,f12,f21,f22,f31,f32,indic,chdon,nvar,texte,
     & trouve,unitime,phastime)
!
!***********************************************************************
! TOMAWAC   V6P3                                   20/06/2011
!***********************************************************************
!
!brief    THIS SUBROUTINE PROJECTS THE CURRENTS / WINDS ON THE
!+                COMPUTATION MESH AND INTERPOLATES TO FIRST TIME STEP.
!+
!+           (INSPIRED FROM SUBROUTINE FOND IN TELEMAC2D AMONGST OTHERS)
!
!history
!+
!+        V5P0
!+
!
!history  N.DURAND (HRW), S.E.BOURBAN (HRW)
!+        13/07/2010
!+        V6P0
!+   Translation of French comments within the FORTRAN sources into
!+   English comments
!
!history  N.DURAND (HRW), S.E.BOURBAN (HRW)
!+        21/08/2010
!+        V6P0
!+   Creation of DOXYGEN tags for automated documentation and
!+   cross-referencing of the FORTRAN sources
!
!history  G.MATTAROLO (EDF)
!+        05/2011
!+        V6P1
!+   Bug correction in the reading of the TELEMAC format file
!
!history  G.MATTAROLO (EDF - LNHE)
!+        20/06/2011
!+        V6P1
!+   Translation of French names of the variables in argument
!
!history  J-M HERVOUET (EDF - LNHE)
!+        16/11/2012
!+        V6P3
!+   Only SELAFIN format with same mesh kept. A number of arguments
!+   removed
!
!history  J-M HERVOUET (EDF - LNHE)
!+        24/01/2013
!+        V6P3
!+   Generalised for reading 3 variables with given names.
!
!history Y AUDOUIN (LNHE)
!+       25/05/2015
!+       V7P0
!+       Modification to comply with the hermes module
!
!~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~
!| AT             |-->| COMPUTATION TIME
!| FONFMT         |-->| DATA FILE FORMAT
!| CHDON          |-->| NAME OF THE VARIABLE READ FROM THE DATA FILE
!| F1             |<--| FIRST VARIABLE TO READ
!| F2             |<--| SECOND VARIABLE TO READ
!| F3             |<--| THIRD VARIABLE TO READ
!| F11            |<->| DATA VALUES AT TIME TV1 IN THE DATA FILE FOR F1
!| F12            |<->| DATA VALUES AT TIME TV2 IN THE DATA FILE FOR F1
!| F21            |<->| DATA VALUES AT TIME TV1 IN THE DATA FILE FOR F2
!| F22            |<->| DATA VALUES AT TIME TV2 IN THE DATA FILE FOR F2
!| F31            |<->| DATA VALUES AT TIME TV1 IN THE DATA FILE FOR F3
!| F32            |<->| DATA VALUES AT TIME TV2 IN THE DATA FILE FOR F3
!| INDIC          |-->| FILE FORMAT
!| MODE1          |-->| MODE: 0= DO NOT READ
!|                |   |       1= READ IF PRESENT
!|                |   |       2= READ AND STOP IF NOT PRESENT
!| MODE2          |-->| LIKE MODE1 FOR SECOND VARIABLE
!| MODE3          |-->| LIKE MODE1 FOR THIRD VARIABLE
!| NAME1          |-->| NAME OF FIRST VARIABLE
!| NAME2          |-->| NAME OF SECOND VARIABLE
!| NAME3          |-->| NAME OF THIRD VARIABLE
!| NDON           |-->| LOGICAL UNIT NUMBER OF THA DATA FILE
!| NPOIN2         |-->| NUMBER OF POINTS IN 2D MESH
!| NVAR           |<--| NUMBER OF VARIABLES READ
!| PHASTIME       |-->| TIME SHIFT IN FILE
!| TEXTE          |<->| NAMES OF VARIABLES IN SERAFIN FILE
!| TROUVE         |<->| 3 LOGICAL, WILL SAY IF VARIABLES HAVE BEEN FOUND
!| TV1            |<->| DATA TIME T1
!| TV2            |<->| DATA TIME T2
!| UNITIME        |-->| UNIT OF TIME IN FILE
!~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~
!
      USE bief
      USE interface_tomawac, ex_lecdoi => lecdoi
      USE interface_hermes
!
      USE declarations_special
      IMPLICIT NONE
!
!
!+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+
!
      INTEGER, INTENT(IN)             :: NDON,NPOIN2,INDIC
      INTEGER, INTENT(IN)             :: MODE1,MODE2,MODE3
      INTEGER, INTENT(INOUT)          :: NVAR
      DOUBLE PRECISION, INTENT(INOUT) :: F1(npoin2),F2(npoin2)
      DOUBLE PRECISION, INTENT(INOUT) :: F3(npoin2)
      DOUBLE PRECISION, INTENT(INOUT) :: F11(npoin2),F12(npoin2)
      DOUBLE PRECISION, INTENT(INOUT) :: F21(npoin2),F22(npoin2)
      DOUBLE PRECISION, INTENT(INOUT) :: F31(npoin2),F32(npoin2)
      DOUBLE PRECISION, INTENT(IN)    :: AT,UNITIME,PHASTIME
      DOUBLE PRECISION, INTENT(INOUT) :: TV1,TV2
      CHARACTER(LEN=8), INTENT(IN)    :: FFORMAT
      CHARACTER(LEN=7), INTENT(IN)    :: CHDON
      CHARACTER(LEN=32),INTENT(IN)    :: NAME1,NAME2,NAME3
      CHARACTER(LEN=32),INTENT(INOUT) :: TEXTE(30)
      LOGICAL, INTENT(INOUT)          :: TROUVE(3)
!
!+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+
!
      INTEGER NP,I,J,MODE(3)
      DOUBLE PRECISION COEF
      CHARACTER(LEN=80) TITCAS
      CHARACTER(LEN=32) NAME(3),FULL_NAME(3)
      CHARACTER(LEN=16), ALLOCATABLE :: VAR_NAME(:), VAR_UNIT(:)
      DOUBLE PRECISION :: TIME1,TIME2
      INTEGER :: RECORD1,RECORD2
      INTEGER :: IERR
!
!-----------------------------------------------------------------------
!
      mode(1)=mode1
      mode(2)=mode2
      mode(3)=mode3
      name(1)=name1
      name(2)=name2
      name(3)=name3
!
!-----------------------------------------------------------------------
!     READS THE POINTS FROM LOGICAL UNIT NDON
!-----------------------------------------------------------------------
!
      IF(indic.EQ.3) THEN
!
!       -----------------------------------------------------------------
!       TELEMAC FORMAT,
!       VARIABLES 1 AND 2 ARE THE X AND Y COMPONENTS OF THE WIND
!       -----------------------------------------------------------------
!
        ! Getting title
        CALL get_mesh_title(fformat,ndon,titcas,ierr)
        CALL check_call(ierr,'LECDOI:GET_MESH_TITLE')
        !
        CALL get_data_nvar(fformat,ndon,nvar,ierr)
        CALL check_call(ierr,'LECDOI:GET_DATA_NVAR')
        !
        ALLOCATE(var_name(nvar),stat=ierr)
        CALL check_allocate(ierr,'LECDOI:VAR_NAME')
        ALLOCATE(var_unit(nvar),stat=ierr)
        CALL check_allocate(ierr,'LECDOI:VAR_UNIT')
        CALL get_data_var_list(fformat,ndon,nvar,var_name,var_unit,ierr)
        CALL check_call(ierr,'LECDOI:GET_DATA_VAR_LIST')
        DO i=1,nvar
          texte(i)(1:16) = var_name(i)
          texte(i)(17:32) = var_unit(i)
          ! CHECK IF THE VARIABLE ARE IN THE FILE
          DO j=1,3
            IF((texte(i).EQ.name(j)).AND.
     &        mode(j).GT.0) THEN
              trouve(j) = .true.
              full_name(j) = name(j)
            ENDIF
          ENDDO
        ENDDO
        DEALLOCATE(var_name)
        DEALLOCATE(var_unit)
        ! get the number of point
        CALL get_mesh_npoin(fformat,ndon,point_bnd_elt_type,np,ierr)
        CALL check_call(ierr,'LECDOI:GET_MESH_NPOIN')
        WRITE(lu,*) '--------------------------------------------'
        WRITE(lu,*) 'LECDOI : READING OF TELEMAC DATA FILE '
        WRITE(lu,*) '         FILE TITLE : ',titcas
        WRITE(lu,*) '         NUMBER OF POINTS   : ',np
        WRITE(lu,*) '--------------------------------------------'
        IF(np.NE.npoin2) THEN
          WRITE(lu,*) ' '
          WRITE(lu,*) 'THE MESH OF THE CURRENTS FILE'
          WRITE(lu,*) 'IS DIFFERENT FROM THE GEOMETRY FILE'
          WRITE(lu,*) ' '
          CALL plante(1)
          stop
        ENDIF
        ! Timesteps
        record1 = 0
        record2 = 1
        CALL get_data_time(fformat,ndon,record1,time1,ierr)
        CALL check_call(ierr,'LECDOI:GET_DATA_TIME')
        tv1=(time1-phastime)*unitime
        !
        IF(tv1.GT.at) THEN
          WRITE(lu,*) '************************************************'
          WRITE(lu,*) 'THE FIRST RECORDING OF THE ',chdon,' FILE '
          WRITE(lu,*) '  ',tv1,' IS OLDER THAN THE BEGINNING '
          WRITE(lu,*) '  OF THE COMPUTATION',at
          WRITE(lu,*) '************************************************'
          CALL plante(1)
          stop
        ENDIF
        !
        ! Get the two records before and after at for the interpolation
        DO
          CALL get_data_time(fformat,ndon,record2,time2,ierr)
          CALL check_call(ierr,'LECDOI:GET_DATA_TIME')
          tv2=(time2-phastime)*unitime
          IF(tv2.LT.at) THEN
            record1 = record2
            record2 = record2 + 1
            tv1 = tv2
          ELSE
            EXIT
          ENDIF
        ENDDO
        ! Check if all the variables are found for record1
        DO j=1,3
          IF(mode(j).EQ.2.AND..NOT.trouve(j)) THEN
            WRITE(lu,*) 'LECDOI: VARIABLE ',name1,' NOT FOUND'
            WRITE(lu,*) trim(name(j)(1:16))
            CALL plante(1)
            stop
          ELSEIF(mode(j).GT.0.AND.trouve(j)) THEN
            WRITE(lu,*) 'VARIABLE ',j,' READ (',
     &      trim(name(j)(1:16)),') AT TIME ',tv1
            ! Read the data for varialbe j on record1
            IF(j.EQ.1) THEN
              CALL get_data_value(fformat,ndon,record1,
     &                            full_name(j),f11,np,ierr)
            ELSEIF(j.EQ.2) THEN
              CALL get_data_value(fformat,ndon,record1,
     &                            full_name(j),f21,np,ierr)
            ELSEIF(j.EQ.3) THEN
              CALL get_data_value(fformat,ndon,record1,
     &                            full_name(j),f31,np,ierr)
            ENDIF
          ENDIF
        ENDDO
        ! Read the variables
        !
        ! Check if all the variables are found for record2
        DO j=1,3
          IF(mode(j).EQ.2.AND..NOT.trouve(j)) THEN
            WRITE(lu,*) 'LECDOI: VARIABLE ',name1,' NOT FOUND'
            WRITE(lu,*) name(j)
            CALL plante(1)
            stop
          ELSEIF(mode(j).GT.0.AND.trouve(j)) THEN
            WRITE(lu,*) 'VARIABLE ',j,' READ (',
     &      trim(name(j)(1:16)),') AT TIME ',tv2
            ! Read the data for varialbe j on record1
            IF(j.EQ.1) THEN
              CALL get_data_value(fformat,ndon,record2,
     &                            full_name(j),f12,np,ierr)
            ELSEIF(j.EQ.2) THEN
              CALL get_data_value(fformat,ndon,record2,
     &                            full_name(j),f22,np,ierr)
            ELSEIF(j.EQ.3) THEN
              CALL get_data_value(fformat,ndon,record2,
     &                            full_name(j),f32,np,ierr)
            ENDIF
          ENDIF
        ENDDO
!
      ELSEIF (indic.EQ.4) THEN
!
!       READS A USER-DEFINED FORMAT
!
        IF(chdon(1:1).EQ.'C') THEN
!         READS A CURRENT FIELD
          trouve(1)=.true.
          trouve(2)=.true.
          nvar=2
          CALL couuti(ndon,fformat)
        ELSEIF(chdon(1:1).EQ.'V') THEN
!         READS A WIND FIELD
          trouve(1)=.true.
          trouve(2)=.true.
          nvar=2
          CALL venuti(ndon,fformat)
        ELSEIF(chdon(1:1).EQ.'H') THEN
!         READS A DEPTH FIELD
          trouve(3)=.true.
          nvar=1
          CALL maruti(ndon,fformat)
        ELSE
          WRITE(lu,*) 'UNKNOWN DATA TYPE'
          CALL plante(1)
          stop
        ENDIF
!
      ELSE
        WRITE(lu,*) '************************************************'
        WRITE(lu,*)'LECDOI : UNKNOWN INDICATOR OF FORMAT : ',indic
        WRITE(lu,*)'         FOR THE ',chdon,' DATA FILE '
        WRITE(lu,*) '************************************************'
        CALL plante(1)
        stop
      ENDIF
!
!-----------------------------------------------------------------------
!   INTERPOLATES IN TIME
!-----------------------------------------------------------------------
!
      coef=(at-tv1)/(tv2-tv1)
!
      IF(trouve(1)) THEN
        DO i=1,npoin2
          f1(i)=(f12(i)-f11(i))*coef+f11(i)
        ENDDO
      ENDIF
      IF(trouve(2)) THEN
        DO i=1,npoin2
          f2(i)=(f22(i)-f21(i))*coef+f21(i)
        ENDDO
      ENDIF
      IF(trouve(3)) THEN
        DO i=1,npoin2
          f3(i)=(f32(i)-f31(i))*coef+f31(i)
        ENDDO
      ENDIF
!
!-----------------------------------------------------------------------
!
      RETURN
      END