latitu.f

Go to the documentation of this file.

!                   *****************
                    SUBROUTINE latitu
!                   *****************
!
     &(ydist,coslat,sinlat,lambd0,y,npoin)
!
!***********************************************************************
! BIEF   V7P1
!***********************************************************************
!
!brief    COMPUTES THE ARRAYS THAT DEPEND ON THE LATITUDE
!+                OF THE GIVEN POINT.
!
!history  J-M HERVOUET (LNH)
!+        10/01/95
!+        V5P1
!+   First version.
!
!history  N.DURAND (HRW), S.E.BOURBAN (HRW)
!+        13/07/2010
!+        V6P0
!+   Translation of French comments within the FORTRAN sources into
!+   English comments
!
!history  N.DURAND (HRW), S.E.BOURBAN (HRW)
!+        21/08/2010
!+        V6P0
!+   Creation of DOXYGEN tags for automated documentation and
!+   cross-referencing of the FORTRAN sources
!
!history  C-T PHAM (R&D, LNHE)
!+        17/01/2013
!+        V6P3
!+   More precise value of Earth radius.
!
!history  M.S.TURNBULL (HRW)
!+        24/09/2015
!+        V7P1
!+   Correction to the computation of the Y in spherical coordinates.
!
!~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~
!| COSLAT         |<--| COSINUS OF LAMBDA0
!| LAMBD0         |-->| LATITUDE OF ORIGIN POINT
!| NPOIN          |-->| NUMBER OF POINTS
!| SINLAT         |<--| SINUS OF LAMBDA0
!| Y              |-->| ORDINATES OF POINTS IN THE MESH
!~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~
!
      USE declarations_special
      IMPLICIT NONE
!
!+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+
!
      INTEGER         , INTENT(IN)    :: NPOIN
      DOUBLE PRECISION, INTENT(IN)    :: Y(npoin)
      DOUBLE PRECISION, INTENT(INOUT) :: YDIST(npoin)
      DOUBLE PRECISION, INTENT(INOUT) :: COSLAT(npoin),SINLAT(npoin)
      DOUBLE PRECISION, INTENT(IN)    :: LAMBD0
!
!+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+
!
      INTEGER I
!
      DOUBLE PRECISION LB2RAD,R,SURR,PISUR4,PISUR2,XLAMB
!
      INTRINSIC tan,atan,sin,cos,exp
!
!-----------------------------------------------------------------------
!
! EARTH RADIUS
!
      r = 6370000.d0
      surr = 1.d0 / r
!
!-----------------------------------------------------------------------
!
      pisur4 = atan(1.d0)
      pisur2 = pisur4 + pisur4
!
!     LAMBD0/2 IN RADIANS
!
      lb2rad = lambd0 * pisur4 / 90.d0
!
!     1/COS(LAMBDA),COS(LAMBDA),SIN(LAMBDA)
!
      DO i = 1 , npoin
!
        xlamb = 2.d0* atan(exp(y(i)*surr)*tan(lb2rad+pisur4))-pisur2
        ydist(i) = xlamb * r
        coslat(i) = cos(xlamb)
        sinlat(i) = sin(xlamb)
!
      ENDDO
!
!-----------------------------------------------------------------------
!
      RETURN
      END