kmoyen.f

Go to the documentation of this file.

!                   *****************
                    SUBROUTINE kmoyen
!                   *****************
!
     &(xkmoy, xk, f, nf, ndire, npoin2, aux1, aux2, aux3)
!
!***********************************************************************
! TOMAWAC   V6P3                                   20/06/2011
!***********************************************************************
!
!brief    COMPUTES THE AVERAGE WAVE NUMBER FOR ALL THE NODES
!+                IN THE 2D MESH.
!
!note     THE HIGH-FREQUENCY PART OF THE SPECTRUM IS ONLY CONSIDERED
!+          IF THE TAIL FACTOR (TAILF) IS STRICTLY GREATER THAN 1.
!
!history  P. THELLIER; M. BENOIT (EDF/DER/LNH)
!+        04/04/95
!+        V1P0
!+
!
!history  N.DURAND (HRW), S.E.BOURBAN (HRW)
!+        13/07/2010
!+        V6P0
!+   Translation of French comments within the FORTRAN sources into
!+   English comments
!
!history  N.DURAND (HRW), S.E.BOURBAN (HRW)
!+        21/08/2010
!+        V6P0
!+   Creation of DOXYGEN tags for automated documentation and
!+   cross-referencing of the FORTRAN sources
!
!history  G.MATTAROLO (EDF - LNHE)
!+        20/06/2011
!+        V6P1
!+   Translation of French names of the variables in argument
!
!history  J-M HERVOUET (EDF R&D, LNHE)
!+        18/01/2013
!+        V6P3
!+   ARITHMETIC AVERAGE WHEN ENERGY WEIGHTED AVERAGE IS NOT POSSIBLE
!
!~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~
!| AUX1           |<->| WORK TABLE
!| AUX2           |<->| WORK TABLE
!| AUX3           |<->| WORK TABLE
!| DFREQ          |-->| FREQUENCY STEPS BETWEEN DISCRETIZED FREQUENCIES
!| F              |---| VARIANCE DENSITY DIRECTIONAL SPECTRUM
!| FREQ           |-->| DISCRETIZED FREQUENCIES
!| NF             |-->| NUMBER OF FREQUENCIES
!| NDIRE          |-->| NUMBER OF DIRECTIONS
!| NPOIN2         |-->| NUMBER OF POINTS IN 2D MESH
!| TAILF          |-->| SPECTRUM QUEUE FACTOR
!| XK             |-->| DISCRETIZED WAVE NUMBER
!| XKMOY          |<--| AVERAGE WAVE NUMBER
!~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~
!
      USE declarations_tomawac, ONLY : deupi, gravit, freq, dfreq, tailf
!
      USE declarations_special
      USE interface_tomawac, ex_kmoyen => kmoyen
      IMPLICIT NONE
!
!
!+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+
!
      INTEGER, INTENT(IN)             :: NF,NDIRE,NPOIN2
      DOUBLE PRECISION, INTENT(IN)    :: F(npoin2,ndire,nf)
      DOUBLE PRECISION, INTENT(IN)    :: XK(npoin2,nf)
      DOUBLE PRECISION, INTENT(INOUT) :: AUX1(npoin2),AUX2(npoin2)
      DOUBLE PRECISION, INTENT(INOUT) :: AUX3(npoin2)
      DOUBLE PRECISION, INTENT(INOUT) :: XKMOY(npoin2)
!
!+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+
!
      INTEGER  IDIRE , JF    , IP
      DOUBLE PRECISION COEFF , SEUIL , CTE1  , CTE2  , AUX4
!
!-----------------------------------------------------------------------
!
      seuil = 1.d-20
      coeff = sqrt(gravit)/deupi
!
      DO ip = 1,npoin2
        aux1(ip) = 0.d0
        aux2(ip) = 0.d0
      ENDDO
!
!     SUMS UP THE CONTRIBUTIONS FOR THE DISCRETISED PART OF THE SPECTRUM
!
      DO jf = 1, nf
!
        aux4=dfreq(jf)
!
        DO ip=1,npoin2
          aux3(ip) = 0.d0
        ENDDO
        DO idire = 1, ndire
          DO ip=1, npoin2
            aux3(ip) = aux3(ip) + f(ip,idire,jf)
          ENDDO
        ENDDO
!
        DO ip = 1,npoin2
          aux1(ip)=aux1(ip)+aux3(ip)*aux4
          aux2(ip)=aux2(ip)+aux3(ip)/sqrt(xk(ip,jf))*aux4
        ENDDO
!
      ENDDO
!
!     (OPTIONALLY) TAKES INTO ACCOUNT THE HIGH-FREQUENCY PART
!
      IF(tailf.GT.1.d0) THEN
        cte1=freq(nf)/(tailf-1.d0)
        cte2=coeff/tailf
        DO ip=1,npoin2
          aux1(ip) = aux1(ip) + aux3(ip)*cte1
          aux2(ip) = aux2(ip) + aux3(ip)*cte2
        ENDDO
      ENDIF
!
!     COMPUTES THE AVERAGE WAVE NUMBER
!
      DO ip=1,npoin2
        IF(aux2(ip).LT.seuil) THEN
!         ARITHMETIC AVERAGE WHEN ENERGY WEIGHTED
!         AVERAGE IS NOT POSSIBLE
          xkmoy(ip)=xk(ip,1)
          DO jf=2,nf
            xkmoy(ip)=xkmoy(ip)+xk(ip,jf)
          ENDDO
          xkmoy(ip)=xkmoy(ip)/nf
        ELSE
          xkmoy(ip) = (aux1(ip)/aux2(ip))**2
        ENDIF
      ENDDO
!
!-----------------------------------------------------------------------
!
      RETURN
      END