jultim.f

Go to the documentation of this file.

!                   ********************************
                    DOUBLE PRECISION FUNCTION jultim
!                   ********************************
!
     &(year,month,day,hour,minu,sec,at)
!
!***********************************************************************
! BIEF   V6P2                                   21/08/2010
!***********************************************************************
!
!brief    COMPUTES THE TIME ELAPSED SINCE 31/12/1899.
!+                EXPRESSES IT IN JULIAN CENTURIES.
!
!history  E. DAVID (LHF)
!+        12/07/1995
!+        V5P1
!+
!
!history  JMH (EDF-LNHE)
!+        03/09/2010
!+        V6P0
!+   For consistency, YEAR is now INTENT(IN) only
!
!history  N.DURAND (HRW), S.E.BOURBAN (HRW)
!+        13/07/2010
!+        V6P0
!+   Translation of French comments within the FORTRAN sources into
!+   English comments
!
!history  N.DURAND (HRW), S.E.BOURBAN (HRW)
!+        21/08/2010
!+        V6P0
!+   Creation of DOXYGEN tags for automated documentation and
!+   cross-referencing of the FORTRAN sources
!
!~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~
!| AT             |-->| TIME IN SECONDS
!| DAY            |-->| DAY
!| HOUR           |-->| HOUR IN UNIVERSAL TIME
!| MIN            |-->| MINUTE IN UNIVERSAL TIME
!| MONTH          |-->| MONTH
!| SEC            |-->| SECOND IN UNIVERSAL TIME
!| YEAR           |-->| YEAR
!~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~
!
      USE declarations_special
      IMPLICIT NONE
!
!
!+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+
!
      INTEGER,          INTENT(IN) :: MONTH,DAY,HOUR,MINU,SEC,YEAR
      DOUBLE PRECISION, INTENT(IN) :: AT
!
!+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+
!
      INTEGER Y,M,YEAR2
      DOUBLE PRECISION J
!
      INTRINSIC int
!
      INTEGER, PARAMETER :: GREG=15+31*(10+12*1582)
!
!-----------------------------------------------------------------------
!
      year2=year
      IF(year2.EQ.0) THEN
        WRITE (lu,101)
        CALL plante(1)
        stop
      ENDIF
      IF(year2.LT.0) year2=year2+1
!
      IF (month.GT.2) THEN
        y=year2
        m=month+1
      ELSE
        y=year2-1
        m=month+13
      ENDIF
!
      j=int(365.25d0*y)+int(30.6001d0*m)+day+1720995.d0
      IF(day+31*(month+12*year2).GE.greg) THEN
        j=j+2-int(0.01d0*y)+int(0.25d0*int(0.01d0*y))
      ENDIF
      j=j-2415020.5d0
      jultim=(j+(hour+(minu+(sec+at)/60.d0)/60.d0)/24.d0)/36525.d0
!
!---------------------------------------------------------------
!
101   FORMAT (//,10x,'**********************************',
     &         /,10x,'       JULTIM FUNCTION',
     &         /,10x,' THE VALUE FOR THE YEAR IS ZERO',
     &         /,10x,' COMPUTATION NOT POSSIBLE ...'
     &         /,10x,'**********************************')
!
!---------------------------------------------------------------
!
      RETURN
      END