intlu.f

Go to the documentation of this file.

!                   **********************
                    INTEGER FUNCTION intlu
!                   **********************
!
     &( icol , ligne )
!
!***********************************************************************
! DAMOCLES   V7P1
!***********************************************************************
!
!brief    DECODES AN INTEGER, FROM COLUMN ICOL+1 OF THE LINE.
!+             MOVES THE POINTER ICOL TO THE LAST DECODED CHARACTER.
!+             IF THE STRING IS NOT COMPLETE, GOES TO THE NEXT LINE
!+             IF NEED BE.
!+             MOVES THE POINTER ICOL TO THE LAST DECODED CHARACTER.
!+             OR TO ICOL=0 IF THE NEXT LINE WAS READ.
!
!note     PORTABILITY : IBM,CRAY,HP,SUN
!
!warning  IF THE VALUE READ IS NOT AN INTEGER, COULD YIELD A
!+            NON-CONTROLLED ERROR BY THE PROGRAM
!
!history  J.M. HERVOUET (LNH); A. YESSAYAN
!+        30/09/1993
!+        V5P1
!+   First version
!
!history  N.DURAND (HRW), S.E.BOURBAN (HRW)
!+        13/07/2010
!+        V6P0
!+   Translation of French comments within the FORTRAN sources into
!+   English comments
!
!history  N.DURAND (HRW), S.E.BOURBAN (HRW)
!+        21/08/2010
!+        V6P0
!+   Creation of DOXYGEN tags for automated documentation and
!+   cross-referencing of the FORTRAN sources
!
!history  J.M. HERVOUET (EDF LAB, LNHE)
!+        23/06/2015
!+        V7P1
!+   Mixture of French and English corrected in an error message.
!
!~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~
!| ICOL           |<->| POSITION COURANTE DU POINTEUR DANS LA LIGNE
!| LIGNE          |<->| LIGNE EN COURS DE DECODAGE
!~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~
!
      USE declarations_damocles
      USE declarations_special
      IMPLICIT NONE
!
      INTEGER, INTENT(INOUT)       :: ICOL
      CHARACTER(LEN=*), INTENT(INOUT) :: LIGNE
!
      INTEGER          NEXT,PREVAL
      EXTERNAL next,preval
!
!-----------------------------------------------------------------------
!
      INTRINSIC log10,dble,int,char
!
      INTEGER           I1,I2,ILONG,ISIGNE,IVAL,JD1,I3
      LOGICAL           LUFIC,LISUIV
      CHARACTER(LEN=1)  CDEB,TABUL
      CHARACTER(LEN=3)  LLONG
      CHARACTER(LEN=72) LIGNE2,FORMA
!
!***********************************************************************
!
      lufic = .false.
      lisuiv = .false.
      tabul = char(9)
!
      i1     = next( icol+1 , ligne )
!
!     //// DECODES THE SIGN IF NEED BE ////
!
      IF ( ligne(i1:i1).EQ.'-' ) THEN
        isigne = -1
        i1     =   next( i1+1      , ligne )
      ELSE IF ( ligne(i1:i1).EQ.'+' ) THEN
        isigne = +1
        i1     =   next( i1+1      , ligne )
      ELSE
        isigne = +1
      ENDIF
!
!     //// SEEKS THE FIRST WHITE CHARACTER FOLLOWING THE NUMBER ////
!                       OR A SEPARATOR ';'
!
      i2 = preval(  i1  , ligne ,  ' ' , ';' , tabul)
!
!     CASE WHERE THE INTEGER DOES NOT FINISH ON THE LINE                                                                                                                                                                                                                                                                                                                                                                                                                                              LINE
!
      IF (i2.GT.longli) THEN
        lufic=.true.
        READ(nfic,end=900,err=998,fmt='(A)') ligne2
        cdeb = ligne2(1:1)
        IF (cdeb.EQ.'0'.OR.cdeb.EQ.'1'.OR.cdeb.EQ.'2'.OR.
     &      cdeb.EQ.'3'.OR.cdeb.EQ.'4'.OR.cdeb.EQ.'5'.OR.
     &      cdeb.EQ.'6'.OR.cdeb.EQ.'7'.OR.cdeb.EQ.'8'.OR.
     &      cdeb.EQ.'9'.OR.cdeb.EQ.'.') THEN
          lisuiv = .true.
          i3=1
          i3=preval(i3,ligne2 , ' ' , ';', tabul)
          IF (i1.LE.longli) THEN
            ligne = ligne(i1:longli)//ligne2(1:i3)
          ELSE
            ligne =ligne2(1:i3)
          ENDIF
          i2 = longli-i1+1+i3
          i1 = 1
        ENDIF
      ENDIF
      GOTO 910
!
 900  CONTINUE
      retour = .true.
 910  CONTINUE
!     ACCEPTS THE CASE WHERE A USER WRITES AN INTEGER IN
!     REAL FORM WITH A POINT AT THE END
      IF(ligne(i2-1:i2-1).EQ.'.') THEN
        ligne(i2-1:i2-1)=' '
        i2 = i2 - 1
      ENDIF
!
!     ILONG: LENGTH OF THE INTEGER
      ilong  = i2 - i1
!
!     //// DECODING FORMAT ////
!
      jd1 = 3 - int(log10(dble(ilong)))
      WRITE ( llong , '(I3)' ) ilong
!
      IF(i1.EQ.1) THEN
        WRITE (forma , 1101 )  llong(jd1:3)
      ELSE
        WRITE (forma , 1100 )  i1-1 , llong(jd1:3)
      ENDIF
!
!     ////  DECODES ////
!
      READ  ( ligne , forma , err=995 ) ival
      intlu = isigne * ival
!
!     //// UPDATES THE POINTER ////
!
      IF (lufic) THEN
        nlign = nlign + 1
        ligne = ligne2
        IF (lisuiv) THEN
          icol = i3-1
        ELSE
          icol = 0
        ENDIF
      ELSE
        icol = i2 - 1
      ENDIF
!
1100  FORMAT('(',i3,'X,I',a,')')
1101  FORMAT('(I',a,')')
!
!-----------------------------------------------------------------------
!
      RETURN
!
! TREATS THE ERRORS DUE TO THE INTERNAL READ FOR CONVERSION
!
995   CONTINUE
      WRITE(lu,1996) nlign
      WRITE(lu,*) ligne
1996  FORMAT(1x,'ERROR LINE ',1i6,', INTEGER EXPECTED : ',/)
      erreur=.true.
      RETURN
!
! TREATS THE ERRORS DUE TO FILE MISREADING
!
998   CONTINUE
      WRITE(lu,1999) nfic,nlign+1
1999  FORMAT(1x,'LOGICAL UNIT ',1i2,'   ERROR LINE ',1i6)
      retour = .true.
      RETURN
!
      END