initab.f

Go to the documentation of this file.

!                   *****************
                    SUBROUTINE initab
!                   *****************
!
     &(ibor1,ifabor1,nelem2_dim,part)
!
!***********************************************************************
! TOMAWAC   V7P0                                   20/06/2011
!***********************************************************************
!
!brief    INITIALISES USEFUL ARRAYS.
!
!history  F.MARCOS (LNH)
!+        23/05/96
!+        V1P2
!+
!
!history  DC
!+
!+
!+   ADDED ARG NPOIN2 TO DIMENSION THE ARRAYS
!
!history  N.DURAND (HRW), S.E.BOURBAN (HRW)
!+        13/07/2010
!+        V6P0
!+   Translation of French comments within the FORTRAN sources into
!+   English comments
!
!history  N.DURAND (HRW), S.E.BOURBAN (HRW)
!+        21/08/2010
!+        V6P0
!+   Creation of DOXYGEN tags for automated documentation and
!+   cross-referencing of the FORTRAN sources
!
!history  G.MATTAROLO (EDF)
!+        05/2011
!+        V6P1
!+   Modification for direct coupling with TELEMAC
!+   Initialisation of the variabel BETA
!
!history  G.MATTAROLO (EDF - LNHE)
!+        20/06/2011
!+        V6P1
!+   Translation of French names of the variables in argument
!
!history  J-M HERVOUET (EDF - LNHE)
!+        07/12/2012
!+        V6P3
!+   Optimisation.
!
!history  J-M HERVOUET (EDF - LNHE)
!+        08/01/2014
!+        V7P0
!+   CALL PARCOM suppressed by using new argument ASSPAR in VECTOR
!
!~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~
!| IBOR1          |<--| WORK TABLE
!| IFABOR1        |-->| ELEMENTS BEHIND THE EDGES OF A TRIANGLE
!|                |   | IF NEGATIVE OR ZERO, THE EDGE IS A LIQUID,
!|                |   | SOLID OR PERIODIC BOUNDARY
!| NELEM2_DIM     |---| NUMBER OF ELEMENTS IN 2D
!| PART           |-->| FLAG FOR DIRECT COUPLING WITH TELEMAC
!~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~
!
      USE bief
      USE declarations_telemac
      USE declarations_tomawac
!
      USE interface_tomawac, ex_initab => initab
      IMPLICIT NONE
!
!+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+
!
      INTEGER, INTENT(IN)    :: PART,NELEM2_DIM
      INTEGER, INTENT(IN)    :: IFABOR1(nelem2_dim,3)
      INTEGER, INTENT(INOUT) :: IBOR1(nelem2_dim,7)
!
!+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+
!
      INTEGER IDIRE,IPOIN,IELEM2,IFREQ
      DOUBLE PRECISION AUXI
!
!-----------------------------------------------------------------------
!
      DO idire = 1, ndire
        costet(idire) = cos(teta(idire))
        sintet(idire) = sin(teta(idire))
      ENDDO
!
      auxi=(raisf-1.d0)/2.d0
      dfreq(1)=auxi*freq(1)
      dfreq(nf)=auxi*freq(nf-1)
      DO ifreq = 2,nf-1
        dfreq(ifreq) = auxi*(freq(ifreq)+freq(ifreq-1))
        DO ipoin=1,npoin2
          b(ipoin+(ifreq-1)*npoin2)=0.d0
        ENDDO
      ENDDO
!
      IF(sphe) THEN
        DO ipoin=1,npoin2
          cosf(ipoin)=cos(y(ipoin)*degrad)
          tgf(ipoin)=tan(y(ipoin)*degrad)
        ENDDO
      ENDIF
!
      DO ielem2=1,nelem2
        ibor1(ielem2,1)=ifabor1(ielem2,1)
        ibor1(ielem2,2)=ifabor1(ielem2,2)
        ibor1(ielem2,3)=ifabor1(ielem2,3)
        ibor1(ielem2,4)=1
        ibor1(ielem2,5)=1
        ibor1(ielem2,6)=1
        ibor1(ielem2,7)=1
      ENDDO
!
!     INITIALISES THE VARIABLE BETA
!
      DO ipoin=1,npoin2
        betabr(ipoin)=0.d0
      ENDDO
!
!     INITIALISES THE GRADIENTS OF DEPTH, U AND V
!
!
!     INVERSE OF INTEGRAL OF TEST FUNCTIONS
!
      IF(.NOT.proinf.OR.couran.OR.part.EQ.wac_cpl_init) THEN
        CALL vector(st0,'=','MASBAS          ',ielm2,1.d0,mesh%X,
     &              st1,st1,st1,st1,st1,mesh,.false.,st1,
     &              asspar=.true.)
        CALL ov('X=1/Y   ', x=st0%R, y=st0%R, dim1=npoin2)
      ENDIF
!
!     NOW PROJECTED GRADIENTS DIVIDED BY INTEGRALS OF TEST FUNCTIONS
!
      IF(.NOT.proinf) THEN
        CALL vector(sdzx,'=','GRADF          X',ielm2,1.d0,sdepth,
     &              st0,st0,st0,st0,st0,mesh,.false.,st0,
     &              asspar=.true.)
        CALL vector(sdzy,'=','GRADF          Y',ielm2,1.d0,sdepth,
     &              st0,st0,st0,st0,st0,mesh,.false.,st0,
     &              asspar=.true.)
        CALL ov('X=XY    ', x=sdzx%R, y=st0%R, dim1=npoin2)
        CALL ov('X=XY    ', x=sdzy%R, y=st0%R, dim1=npoin2)
      ENDIF
!
      IF(couran.OR.part.EQ.wac_cpl_init) THEN
        CALL vector(sdux,'=','GRADF          X',ielm2,1.d0,suc,
     &              st0,st0,st0,st0,st0,mesh,.false.,st0,asspar=.true.)
        CALL vector(sdvx,'=','GRADF          X',ielm2,1.d0,svc,
     &              st0,st0,st0,st0,st0,mesh,.false.,st0,asspar=.true.)
        CALL vector(sduy,'=','GRADF          Y',ielm2,1.d0,suc,
     &              st0,st0,st0,st0,st0,mesh,.false.,st0,asspar=.true.)
        CALL vector(sdvy,'=','GRADF          Y',ielm2,1.d0,svc,
     &              st0,st0,st0,st0,st0,mesh,.false.,st0,asspar=.true.)
        CALL ov('X=XY    ', x=sdux%R, y=st0%R, dim1=npoin2)
        CALL ov('X=XY    ', x=sdvx%R, y=st0%R, dim1=npoin2)
        CALL ov('X=XY    ', x=sduy%R, y=st0%R, dim1=npoin2)
        CALL ov('X=XY    ', x=sdvy%R, y=st0%R, dim1=npoin2)
      ENDIF
!
!-----------------------------------------------------------------------
!
      RETURN
      END