init_mixte.f

Go to the documentation of this file.

!                   *********************
                    SUBROUTINE init_mixte
!                   *********************
!
     &(xmvs,npoin,avail,nsicla,es,es_sable, es_vase,elay,nomblay,
     & conc_vase,ms_sable,ms_vase,zf,zr,ava0,conc,debu,mixte)
!
!***********************************************************************
! SISYPHE   V6P2                                   21/07/2011
!***********************************************************************
!
!brief
!
!history
!+
!+        V6P0
!+
!
!history  N.DURAND (HRW), S.E.BOURBAN (HRW)
!+        13/07/2010
!+        V6P0
!+   Translation of French comments within the FORTRAN sources into
!+   English comments
!
!history  N.DURAND (HRW), S.E.BOURBAN (HRW)
!+        21/08/2010
!+        V6P0
!+   Creation of DOXYGEN tags for automated documentation and
!+   cross-referencing of the FORTRAN sources
!
!history  C.VILLARET (EDF-LNHE), P.TASSI (EDF-LNHE)
!+        19/07/2011
!+        V6P1
!+  Name of variables
!+
!history  C.VILLARET (EDF-LNHE)
!+        22/08/2012
!+        V6P2
!+  Changing the calling to init_compo_coh: the number of layers is fixed
!+  Testing SUM(layers) = ZF-ZR
!+  Compute the initial mass balance
!+
!history  PABLO SANTORO (IMFIA) AND PABLO TASSI (EDF R&D - LHSV)
!+        01/08/2015
!+        V7P1
!+  small correction for continuous computation
!
!history  J,RIEHME (ADJOINTWARE)
!+        November 2016
!+        V7P2
!+   Replaced EXTERNAL statements to parallel functions / subroutines
!+   by the INTERFACE_PARALLEL
!
!~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~
!| AVA0           |-->| VOLUME PERCENT
!| AVAIL          |<->| VOLUME PERCENT OF EACH CLASS
!| CONC           |<->| CONC OF EACH BED LAYER (KG/M3)
!| CONC_VASE      |<->| MUD CONCENTRATION FOR EACH LAYER
!| DEBU           |-->| FLAG, FOR PREVIOUS SEDIMENTOLOGICAL FILE
!| ELAY           |<->| THICKNESS OF TOTAL LAYER
!| ES             |<->| LAYER THICKNESSES AS DOUBLE PRECISION
!| ES_SABLE       |<->| THICKNESS OF SAND LAYER (M)
!| ES_VASE        |<->| THICKNESS OF MUD LAYER (M)
!| MIXTE          |-->| SEDIMENT MIXTE (SABLE + VASE)
!| MS_SABLE       |<->| MASS OF SAND PER LAYER (KG/M2)
!| MS_VASE        |<->| MASS OF MUD PER LAYER (KG/M2)
!| NOMBLAY        |-->| NUMBER OF LAYERS FOR CONSOLIDATION
!| NPOIN          |-->| NUMBER OF POINTS
!| NSICLA         |-->| NUMBER OF SIZE CLASSES FOR BED MATERIALS
!| XMVS           |-->| WATER DENSITY
!| ZF             |-->| ELEVATION OF BOTTOM
!| ZR             |-->| NON ERODABLE BED
!~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~
!
      USE bief
      USE interface_sisyphe, ex_init_mixte=> init_mixte
      USE declarations_sisyphe, ONLY :masvt,masv0,t1,bilma,volu2d
      USE declarations_sisyphe, ONLY :masst,mass0,t2
!
      USE declarations_special
      USE interface_parallel, ONLY : p_dsum
      IMPLICIT NONE
!
!+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+
!
      INTEGER, INTENT(IN)              :: NPOIN,NSICLA,NOMBLAY
      DOUBLE PRECISION, INTENT(IN)     :: XMVS
      DOUBLE PRECISION, INTENT(INOUT)  :: AVAIL(npoin,nomblay,nsicla)
      DOUBLE PRECISION, INTENT(INOUT)  :: ES(npoin,nomblay)
      DOUBLE PRECISION, INTENT(INOUT)  :: ELAY(npoin)
      DOUBLE PRECISION, INTENT(IN)     :: ZR(npoin),ZF(npoin)
      DOUBLE PRECISION,  INTENT(INOUT) :: MS_SABLE(npoin,nomblay)
      DOUBLE PRECISION,  INTENT(INOUT) :: MS_VASE(npoin,nomblay)
!
      DOUBLE PRECISION,  INTENT(INOUT) :: ES_SABLE(npoin,nomblay)
      DOUBLE PRECISION,  INTENT(INOUT) :: ES_VASE(npoin,nomblay)
!
      DOUBLE PRECISION, INTENT(IN)     :: CONC_VASE(nomblay)
      DOUBLE PRECISION,  INTENT(INOUT) :: CONC(npoin,nomblay)
      DOUBLE PRECISION, INTENT(IN)     :: AVA0(nsicla)
      LOGICAL, INTENT (IN)             :: DEBU, MIXTE
!
!+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+
!
!     LOCAL VARIABLES
!
      INTEGER I,J,K,NK
      DOUBLE PRECISION HAUTSED
      DOUBLE PRECISION DIFF,EST
!
!-----------------------------------------------------------------------
!
!*******INITIAL SEDIMENT COMPOSITION IS IDENTICAL AT EACH NODE
! DEFAULT INITIALISATION: ALL LAYERS ARE EMPTY EXCEPT BED LAYER
! OTHERWISE SET THICKNESS OF THE MUD LAYERS IN EPAI_VASE(I= 1, NCOUCH_TASS-1)
!

!  INITIALISATION OF ES : THICKNESS OF EACH LAYERS
!  INIT_COMPO_COH : composition of the sediment bed : thickness of layers
!                  and concentrations The number of sediment bed layers is fixed

      IF(.NOT.debu) THEN
!
        CALL init_compo_coh(es,conc_vase,conc,npoin,
     &     nomblay,nsicla,avail,ava0)
!
!       Recalcul des epaisseurs pour satisfaire : Sum (ES)=ZF-ZR
!
        DO i=1,npoin
!
          elay(i)=zf(i)-zr(i)
!
!
!         THE HEIGHT OF SEDIMENT (SUM OF ES) MUST BE EQUAL TO ZF-ZR
!         IF SO, THE HEIGHT OF THE LAST LAYER IS REDUCED
!         IF THERE ARE LAYERS UNDER ZR, THEY ARE NOT TAKEN INTO ACCOUNT
!
          hautsed = 0.d0
!
          nk=nomblay
          DO k=1,nomblay
!
            IF(hautsed + es(i,k) .GE. elay(i)) THEN
              es(i,k) = elay(i) -  hautsed
              nk=k
              hautsed = hautsed + es(i,k)
              GOTO 144
            ENDIF
            hautsed = hautsed + es(i,k)
!
          ENDDO
!
144       CONTINUE
!
!         FOR CLEAN OUTPUTS
!
          IF(nk.LT.nomblay) THEN
            DO k=nk+1,nomblay
              es(i,k) = 0.d0
            ENDDO
          ENDIF
!
!         THE THICKNESS OF THE LAST LAYER IS ENLARGED SO THAT
!         THE HEIGHT OF SEDIMENT (SUM OF ES) IS EQUAL TO ZF-ZR
!
          IF(hautsed.LT.elay(i)) THEN
            es(i,nomblay)=es(i,nomblay)+elay(i)-hautsed
          ENDIF
!
        ENDDO
!
      ELSE
!
!      En cas de suite de calcul
!      Check that sum of layers (simple precision) is equal to ZF-ZR
!
        DO i=1,npoin
!
          elay(i)=zf(i)-zr(i)
!
          est=0.d0
!
!         IF(NOMBLAY.GT.1) THEN
!
          DO j=1,nomblay
            est=est+es(i,j)
            conc(i,j) = conc_vase(j)
          ENDDO
!         ELSE
!           EST=ES(I,1)
!         ENDIF
!
          diff= elay(i) - est
!
          IF(abs(diff).GE.1.d-4) THEN
            WRITE(lu,*) 'ERROR IN INIT-MIXTE:'
            WRITE(lu,*) 'THE SUM OF THICKNESS OF BED LAYERS
     &     IS DIFFERENT FROM ERODIBLE BED THICKNESS'
            CALL plante(1)
            stop
          ELSE
            es(i,nomblay) = max(es(i,nomblay)+ diff,0.d0)
          ENDIF
!
        ENDDO
!
      ENDIF
!
! END LOOP  (initialization of layers)
!
! Check sum ELAY = ZF-ZR
!                = SUM (ES)
      DO i = 1, npoin
        est=0.d0
        DO j= 1, nomblay
          est=est+es(i,j)
        ENDDO
        diff=abs(est-elay(i))
        IF(diff.GT.1.d-08) THEN
          WRITE(lu,*) 'ERREUR POINT I'
     &     , i, 'ELAY=',elay(i), 'EST=', est
          CALL plante(1)
          stop
        ENDIF
      ENDDO
!

!  COMPUTING THE INITIAL MASSES OF MUD AND SAND
!
      DO i=1,npoin
        t1%R(i)=0.d0
        t2%R(i)=0.d0
        DO j=1,nomblay
          IF(nsicla.EQ.1) THEN
            es_vase(i,j) = es(i,j)
            ms_vase(i,j) = es(i,j)*conc(i,j)
          ELSE
! FOR MIXTE SEDIMENTS : (MUD, second class )
!....         FILLING VOIDS BETWEEN SAND GRAINS ....(XKV=1)
!
            es_sable(i,j)=es(i,j)*avail(i,j,1)
            es_vase(i,j)= es(i,j)*avail(i,j,2)
!
            ms_vase(i,j) = es_vase(i,j)*conc(i,j)
            ms_sable(i,j)= es_sable(i,j)*xmvs
          ENDIF
          t1%R(i)= t1%R(i)+ms_vase(i,j)
          IF(mixte) t2%R(i)=t2%R(i) + ms_sable(i,j)
        ENDDO
      ENDDO
!
!
! FOR MASS BALANCE
!
      IF(bilma) THEN
        masv0=dots(t1,volu2d)
        IF(mixte) mass0= dots(t2,volu2d)
        IF(ncsize.GT.1) THEN
          masv0=p_dsum(masv0)
          IF(mixte) mass0=p_dsum(mass0)
        ENDIF
!
        masvt=masv0
        IF(mixte) masst=mass0
        IF (.NOT.mixte) THEN
          WRITE(lu,2) masv0
        ELSE
          WRITE(lu,20) masv0, mass0
        ENDIF
      ENDIF
!
002   FORMAT(1x,'INITIAL MASS OF THE MUD BED: ', g20.11, ' KG')
020   FORMAT(1x,'INITIAL MASS OF THE MUD BED: ', g20.11, ' KG',
     &     /,1x,'INITIAL MASS OF THE SAND BED: ', g20.11, ' KG')

!
!-----------------------------------------------------------------------
!
      RETURN
      END