init_compo_coh.f

Go to the documentation of this file.

!                 *************************
                  SUBROUTINE init_compo_coh
!                 *************************
!
     &(es,conc_vase,conc,npoin,nomblay,nsicla,avail,ava0)
!
!***********************************************************************
! SISYPHE   V6P2                                   21/07/2011
!***********************************************************************
!
!brief    INITIAL FRACTION DISTRIBUTION, STRATIFICATION,
!+                VARIATION IN SPACE.
!
!!~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~
!| AVA0           |-->| VOLUME PERCENT
!| AVAIL          |<->| VOLUME PERCENT OF EACH CLASS
!| CONC           |<->| CONC OF EACH BED LAYER (KG/M3)
!| CONC_VASE      |<->| MUD CONCENTRATION FOR EACH LAYER
!| ES             |<->| LAYER THICKNESSES AS DOUBLE PRECISION
!| NOMBLAY        |-->| NUMBER OF LAYERS FOR CONSOLIDATION
!| NPOIN          |-->| NUMBER OF POINTS
!| NSICLA         |-->| NUMBER OF SIZE CLASSES FOR BED MATERIALS
!~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~
!
      USE bief
      USE interface_sisyphe, ex_init_compo_coh=> init_compo_coh
      USE declarations_sisyphe, ONLY : nlaymax
!
      USE declarations_special
      IMPLICIT NONE
!
!+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+
!
      INTEGER, INTENT(IN)              :: NPOIN,NOMBLAY,NSICLA
      DOUBLE PRECISION, INTENT(INOUT)  :: ES(npoin,nomblay)
      DOUBLE PRECISION, INTENT(IN)     :: CONC_VASE(nomblay)
      DOUBLE PRECISION,  INTENT(INOUT) :: CONC(npoin,nomblay)
      DOUBLE PRECISION, INTENT(INOUT)  :: AVAIL(npoin,nomblay,nsicla)
      DOUBLE PRECISION, INTENT(IN)     :: AVA0(nsicla)
!
!+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+
!
      DOUBLE PRECISION  EPAI_VASE(nlaymax),EPAI_SABLE(nlaymax)

      INTEGER I,J
!
!-----------------------------------------------------------------------
!
      ! INITIALISING LOCAL VARIABLES
      epai_vase(:) = 0.d0
      epai_sable(:) = 0.d0
      ! USER FUNTION
      CALL user_init_compo_coh
     &(es,conc_vase,conc,npoin,nomblay,nsicla,avail,ava0,
     & epai_vase, epai_sable)
!-----------------------------------------------------------------------
!
!     INITIALISING OF LAYER THICKNESS AND CONC
!

!     BY DEFAULT : UNIFORM BED COMPOSITION (KEY WORDS)
!     V6P3: IT WILL BE POSSIBLE TO HAVE A SPATIAL DISTRIBUTION OF THE BED CONC
!     V6P2: SO FAR THE MUD CONC IS CONSTANT PER LAYER
!     si mixte: calculer aussi les AVAI!
!
      DO i=1,npoin
        DO j= 1,nomblay
!
          conc(i,j) = conc_vase(j)
          es(i,j)   = epai_vase(j)
!
          IF(nsicla.GT.1) THEN
            es(i,j)= es(i,j) + epai_sable(j)
            IF(es(i,j).GE.1.d-6) THEN
!             Class 1 is for sand, class 2 is mud
              avail(i,j,1)= epai_sable(j)/es(i,j)
              avail(i,j,2)= epai_vase(j)/es(i,j)
            ELSE
              avail(i,j,1)= ava0(1)
              avail(i,j,2)= ava0(2)
            ENDIF
          ENDIF
!
        ENDDO
      ENDDO
!
!-----------------------------------------------------------------------
!
      RETURN
      END