init_compo.f

Go to the documentation of this file.

!                   *********************
                    SUBROUTINE init_compo
!                   *********************
!
     &(ncouches)
!
!***********************************************************************
! SISYPHE   V7P3
!***********************************************************************
!
!brief    INITIAL FRACTION DISTRIBUTION, STRATIFICATION,
!+                VARIATION IN SPACE.
!
!history  MATTHIEU GONZALES DE LINARES
!+        2002
!+        V6P0
!+
!
!history  N.DURAND (HRW), S.E.BOURBAN (HRW)
!+        13/07/2010
!+        V6P0
!+   Translation of French comments within the FORTRAN sources into
!+   English comments
!
!history  N.DURAND (HRW), S.E.BOURBAN (HRW)
!+        21/08/2010
!+        V6P0
!+   Creation of DOXYGEN tags for automated documentation and
!+   cross-referencing of the FORTRAN sources
!
!history  J-M HERVOUET (EDF LAB, LNHE)
!+        2016
!+        V7P2
!+   Checking coherence of data: ZR+sediment height=ZF
!
!history  R.KOPMANN (BAW)
!+        30/01/2018
!+        V7P2
!+   Correct initialisation of all layers and consistency with cas-file
!+   by default
!~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~
!| NCOUCHES       |-->| NUMBER OF LAYER FOR EACH POINT
!~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~
!
      USE bief
      USE declarations_telemac
      USE declarations_sisyphe
!
      USE declarations_special
      IMPLICIT NONE
!
!+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+
!
!                                       NPOIN
      INTEGER, INTENT (INOUT)::NCOUCHES(*)
!
!+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+
!
      INTEGER I,J,K
      DOUBLE PRECISION EPAI,HEIGHT
!
!-----------------------------------------------------------------------
!
      DO j=1,npoin
!
!       BY DEFAULT : UNIFORM BED COMPOSITION
!
        ncouches(j) = nomblay
        DO k=1,nomblay
          DO i = 1, nsicla
            avail(j,k,i) = ava0(i)
          ENDDO
        END DO
        es(j,1) = min(elay0,(zf%R(j)-zr%R(j)))
        DO k = 2, nomblay
          height = (zf%R(j)-zr%R(j)-elay0)
          IF(height.GT.0.d0) THEN
            es(j,k)=height/(nomblay-1)
          ELSE
            es(j,k) = 0.d0
          ENDIF
        ENDDO
      ENDDO
!
!-----------------------------------------------------------------------
!
      ! USER FUNCTION
      CALL user_init_compo(ncouches)
!
!-----------------------------------------------------------------------
!
!     CHECKING THE CONSISTENCY OF DATA
!     THE FORMULA USED HERE ZR+SED. HEIGHT = ZF CAN BE USED TO GIVE THE
!     HEIGHT OF THE LAST LAYER.
!
      DO j=1,mesh%NPOIN
        epai=0.d0
        DO i=1,ncouches(j)
          epai=epai+es(j,i)
        ENDDO
        IF(abs(zr%R(j)+epai-zf%R(j)).GT.1.d-6) THEN
          WRITE(lu,*) 'INIT_COMPO, ERROR:'
          WRITE(lu,*) 'ZR+SEDIMENT HEIGHT=',zr%R(j)+epai
          WRITE(lu,*) 'ZF=',zf%R(j),' ZR=',zr%R(j),
     &                ' SEDIMENT HEIGHT=',epai
          WRITE(lu,*) 'AT POINT ',j
          CALL plante(1)
          stop
        ENDIF
      ENDDO
!
!-----------------------------------------------------------------------
!
      RETURN
      END