inisel.f

Go to the documentation of this file.

!                       *****************
                        SUBROUTINE inisel
!                       *****************
!
     &(npoin1,typele,std,nsfond,fusion,ihaut,ngeo,nfo1)
!
!***********************************************************************
! PROGICIEL : STBTEL  V5.2           11/02/93    J.M. JANIN
!***********************************************************************
!
!   FONCTION  : RECHERCHE LES NOMBRES TOTAUX DE NOEUDS ET D'ELEMENTS DU
!               MAILLAGE DANS LE FICHIER D'ENTREE SELAFIN
!
!-----------------------------------------------------------------------
!                             ARGUMENTS
! .________________.____.______________________________________________
! |      NOM       |MODE|                   ROLE
! |________________|____|______________________________________________
! | NPOIN1         |<-- | NOMBRE REEL DE POINTS DU MAILLAGE
! |                |    | (NPOIN REPRESENTE L'INDICE MAX DES NOEUDS CAR
! |                |    | SUPERTAB LAISSE DES TROUS DANS LA NUMEROTATION
! | TYPELE         |<-- | TYPE D'ELEMENTS
! | IHAUT          |<-- | NUMERO DE LA VARIABLE HAUTEUR D'EAU
! |________________|____|______________________________________________
! | COMMON:        |    |
! |  GEO:          |    |
! |    MESH        |<-- | TYPE DES ELEMENTS DU MAILLAGE
! |    NDP         | -->| NOMBRE DE NOEUDS PAR ELEMENTS
! |    NPOIN       |<-- | NOMBRE TOTAL DE NOEUDS DU MAILLAGE
! |    NELEM       |<-- | NOMBRE TOTAL D'ELEMENTS DU MAILLAGE
! |    NPMAX       | -->| DIMENSION EFFECTIVE DES TABLEAUX X ET Y
! |                |    | (NPMAX = NPOIN + 0.1*NELEM)
! |    NELMAX      | -->| DIMENSION EFFECTIVE DES TABLEAUX CONCERNANT
! |                |    | LES ELEMENTS (NELMAX = NELEM + 0.2*NELEM)
! |  FICH:         |    |
! |    NRES        |--> | NUMERO DU CANAL DU FICHIER DE SERAFIN
! |    NGEO        |--> | NUMERO DU CANAL DU FICHIER MAILLEUR
! |    NLIM        |--> | NUMERO DU CANAL DU FICHIER DYNAM DE TELEMAC
! |    NFO1        |--> | NUMERO DU CANAL DU FICHIER TRIANGLE TRIGRID
! |________________|____|______________________________________________
! MODE : -->(DONNEE NON MODIFIEE), <--(RESULTAT), <-->(DONNEE MODIFIEE)
!-----------------------------------------------------------------------
! APPELE PAR : HOMERE
! APPEL DE : -
!***********************************************************************
!
      USE declarations_special
      USE declarations_stbtel, ONLY: nelem,mesh,ndp,npoin,
     &                typ_elem,typ_bnd_elem,nptir,fformat
      USE interface_stbtel, ex_inisel => inisel
      USE interface_hermes
      IMPLICIT NONE
!
      INTEGER, INTENT(INOUT) :: NPOIN1,NSFOND
      CHARACTER(LEN=11), INTENT(INOUT) :: TYPELE
      CHARACTER(LEN=3), INTENT(IN) :: STD
      LOGICAL, INTENT(IN) :: FUSION
      INTEGER, INTENT(INOUT) :: IHAUT
      INTEGER, INTENT(IN) :: NGEO , NFO1
!
      INTEGER NVAR , I , IB(10)
!
!
! COMMON
!
      CHARACTER(LEN=16), ALLOCATABLE :: VARUNIT(:), VARNAME(:)
      INTEGER :: IERR
!
!
!=======================================================================
! LECTURE SEQUENTIELLE DU FICHIER ET RECHERCHE ENREGISTREMENT 5
!=======================================================================
!
      CALL get_data_nvar(fformat, ngeo, nvar, ierr)
      CALL check_call(ierr, 'INISEL:GET_DATA_NVAR')

      ALLOCATE(varunit(nvar))
      ALLOCATE(varname(nvar))
      CALL get_data_var_list(fformat,ngeo,nvar,varname,varunit,ierr)
      CALL check_call(ierr, 'INISEL:GET_DATA_VAR_LIST')

      DO i=1,nvar
        IF( varname(i) .EQ. 'FOND            ' .OR.
     &      varname(i) .EQ. 'BOTTOM          ' ) nsfond = i
        IF( varname(i) .EQ. 'HAUTEUR D''EAU   ' .OR.
     &      varname(i) .EQ. 'WATER DEPTH     ' ) ihaut = i
      ENDDO

      DEALLOCATE(varunit)
      DEALLOCATE(varname)
!
!=======================================================================
! AFFECTATION DES VALEURS LUES AUX VARIABLES CONCERNEES
!=======================================================================
!
      ! TEST FOR TRIANGLE
      typ_elem = triangle_elt_type
      CALL get_mesh_nelem(fformat,ngeo,typ_elem,nelem,ierr)
      CALL check_call(ierr,'inisel:GET_MESH_NELEM:TRIANGLE')
      ndp = 3
      IF(nelem.EQ.0) THEN
        ! TEST FOR QUADRANGLE
        typ_elem = quadrangle_elt_type
        CALL get_mesh_nelem(fformat,ngeo,typ_elem,nelem,ierr)
        CALL check_call(ierr, 'INISEL:GET_MESH_NELEM:QUADRANGLE')
        ndp = 4
        IF(nelem.EQ.0) THEN
          WRITE(lu,*) 'NO 2D ELEMENTS IN A 2D MESH'
          CALL plante(1)
        ENDIF
      ENDIF
      typ_bnd_elem = point_bnd_elt_type

      CALL get_mesh_npoin(fformat,ngeo,typ_elem,npoin,ierr)
      CALL check_call(ierr, 'GET_MESH_NPOIN:TRIA')

      CALL get_mesh_nptir(fformat,ngeo,nptir,ierr)

      npoin1= npoin
!
!=======================================================================
! LECTURE SEQUENTIELLE DU SECOND FICHIER EN CAS DE FUSION
!=======================================================================
!
      IF (fusion) THEN
!
        CALL get_mesh_nelem(fformat,nfo1,typ_elem,ib(1),ierr)
        CALL check_call(ierr,'INISEL:GET_MESH_NELEM:TRIANGLE')

        CALL get_mesh_npoin(fformat,nfo1,typ_elem,ib(2),ierr)
        CALL check_call(ierr, 'GET_MESH_NPOIN:TRIA')

        CALL get_mesh_npoin_per_element(fformat,nfo1,typ_elem,
     &                                  ib(3),ierr)
!
        nelem = nelem + ib(1)
        npoin = npoin + ib(2)
!
        IF (ndp.NE.ib(3)) THEN
          WRITE(lu,3130)
 3130     FORMAT(' INISEL : TYPES OF MESH INHOMOGENEOUS')
          CALL plante(1)
          stop
        ENDIF
!
      ENDIF
!
!=======================================================================
! MISE DES VALEURS DE MESH AU STANDARD TELEMAC
!=======================================================================
!
      IF (ndp.EQ.4) THEN
        mesh = 2
        typele = 'QUADRANGLES'
      ELSEIF (ndp.EQ.3) THEN
        mesh = 3
        typele = 'TRIANGLES  '
      ELSE
        WRITE(lu,3140) mesh
 3140   FORMAT(' INISEL : TYPE OF MESH NOT AVAILABLE IN TELEMAC,
     &           MESH = ',i4)
        CALL plante(1)
        stop
      ENDIF
!
      RETURN
      END