iniphy.f

Go to the documentation of this file.

!                   *****************
                    SUBROUTINE iniphy
!                   *****************
!
     &( xk    , cg    , b     , npoin2, nf   )
!
!***********************************************************************
! TOMAWAC   V6P1                                   20/06/2011
!***********************************************************************
!
!brief    COMPUTES THE WAVE PARAMETERS THAT ARE TIME-INDEPENDENT
!+               (WAVE NUMBER, GROUP VELOCITY,...).
!
!note     ALL THE DIRECTIONS ARE IN RADIAN AND IN THE RANGE [0 ; 2PI].
!
!history  M. BENOIT (EDF/DER/LNH)
!+        07/02/95
!+        V1P0
!+
!
!history  N.DURAND (HRW), S.E.BOURBAN (HRW)
!+        13/07/2010
!+        V6P0
!+   Translation of French comments within the FORTRAN sources into
!+   English comments
!
!history  N.DURAND (HRW), S.E.BOURBAN (HRW)
!+        21/08/2010
!+        V6P0
!+   Creation of DOXYGEN tags for automated documentation and
!+   cross-referencing of the FORTRAN sources
!
!history  G.MATTAROLO (EDF - LNHE)
!+        20/06/2011
!+        V6P1
!+   Translation of French names of the variables in argument
!
!~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~
!| B              |<--| JACOBIAN TO TRANSFORM N(KX,KY) INTO F(FR,TETA)
!| CG             |<--| DISCRETIZED GROUP VELOCITY
!| COSPHI         |-->| COSINE OF THE LATITUDES OF THE POINTS 2D
!| DEPTH          |-->| WATER DEPTH
!| FREQ           |-->| DISCRETIZED FREQUENCIES
!| NF             |-->| NUMBER OF FREQUENCIES
!| NPOIN2         |-->| NUMBER OF POINTS IN 2D MESH
!| PROINF         |-->| LOGICAL INDICATING INFINITE DEPTH ASSUMPTION
!| SPHE           |-->| LOGICAL INDICATING SPHERICAL COORD ASSUMPTION
!| XK             |<--| DISCRETIZED WAVE NUMBER
!~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~
!
      USE declarations_tomawac, ONLY : deupi,gravit,r2, depth, freq,
     &                                 cosf, proinf, sphe
!
      USE interface_tomawac, ex_iniphy => iniphy
      IMPLICIT NONE
!
!.....VARIABLES IN ARGUMENT
!     """"""""""""""""""""
      INTEGER, INTENT(IN)             :: NF    , NPOIN2
      DOUBLE PRECISION, INTENT(INOUT) :: B(npoin2,nf)  , XK(npoin2,nf)
      DOUBLE PRECISION, INTENT(INOUT) :: CG(npoin2,nf)
!
!.....LOCAL VARIABLES
!     """""""""""""""""
      INTEGER          IP    , JF
      DOUBLE PRECISION DEUPI2,DPDSUG,AUX2,AUX1,AUX3,DEUKD
!
      deupi2=deupi**2
      dpdsug=deupi2/gravit
!
      IF (proinf) THEN
!                               +----------------------+
!.............................. ! INFINITE WATER DEPTH !
!                               +----------------------+
        DO jf=1,nf
          aux1=dpdsug*(freq(jf))**2
          aux3=0.5d0*gravit/(deupi*freq(jf))
          DO ip=1,npoin2
            xk(ip,jf)=aux1
            cg(ip,jf)=aux3
          ENDDO ! IP
        ENDDO ! JF
      ELSE
!                               +--------------------+
!.............................. ! FINITE WATER DEPTH !
!                               +--------------------+
        DO jf=1,nf
          aux2=deupi*freq(jf)
          DO ip=1,npoin2
            CALL wnscou(aux1,freq(jf),depth(ip))
            deukd=2.d0*aux1*depth(ip)
            IF (deukd.GT.7.d2) THEN
              aux3=0.5d0*aux2/aux1
            ELSE
              aux3=0.5d0*(1.d0+deukd/sinh(deukd))*aux2/aux1
            ENDIF
            xk(ip,jf)=aux1
            cg(ip,jf)=aux3
          ENDDO ! IP
        ENDDO ! JF
      ENDIF
!
!
!.....COMPUTES B TO GO FROM (KX, KY) TO (FR, TETA)
!     ===================================================
      IF (.NOT.sphe) THEN
!                               +-----------------------------+
!.............................. ! CARTESIAN COORDINATE SYSTEM !
!                               +-----------------------------+
        DO jf=1,nf
          aux1=deupi2*freq(jf)
          DO ip=1,npoin2
            b(ip,jf)= cg(ip,jf)/(aux1*xk(ip,jf))
          ENDDO ! IP
        ENDDO ! JF
!
      ELSE
!                               +-----------------------------+
!.............................. ! SPHERICAL COORDINATE SYSTEM !
!                               +-----------------------------+
        DO jf=1,nf
          aux1=deupi2*freq(jf)*r2
          DO ip=1,npoin2
            b(ip,jf)= cg(ip,jf)/(aux1*xk(ip,jf)*cosf(ip))
          ENDDO ! IP
        ENDDO ! JF
      ENDIF
!
      RETURN
      END