inifas.f

Go to the documentation of this file.

!                       *****************
                        SUBROUTINE inifas
!                       *****************
!
     &(typele,ngeo)
!
!***********************************************************************
! PROGICIEL : STBTEL V5.2      09.07.1996  P. CHAILLET  (LHF) - FASTTABS
!***********************************************************************
!
!     FONCTION  : INITIALISATION DES INFORMATIONS DANS LE CAS DE FASTTAB
!
!-----------------------------------------------------------------------
!                             ARGUMENTS
! .________________.____.______________________________________________
! !      NOM       |MODE!                   ROLE
! !________________|____!______________________________________________
! ! TYPELE         !<-- ! TYPE D'ELEMENT DU MAILLAGE (ICI TRIANGLES)
! ! NGEO           ! -->! NUMERO DU CANAL DU FICHIER MAILLEUR
! !________________!____!______________________________________________
! MODE : -->(DONNEE NON MODIFIEE), <--(RESULTAT), <-->(DONNEE MODIFIEE)
!-----------------------------------------------------------------------
! APPELE PAR : HOMERE
! APPEL DE :
!***********************************************************************
!
      USE declarations_special
      USE declarations_stbtel, ONLY: nelem,mesh,ndp,npoin
      IMPLICIT NONE
!
      INTEGER, INTENT(IN) ::       NGEO
      CHARACTER(LEN=*), INTENT(INOUT) :: TYPELE
!
      CHARACTER(LEN=80)  LIGNE
      INTEGER       IE,J
      INTEGER       ELMLOC(8)
!
! - INITIALISATION
!
      rewind(ngeo)
      npoin = 0
      nelem = 0
!
!  - BOUCLE DE LECTURE DU FICHIER DE MAILLAGE
!  - TANT QUE NON FIN DE FICHIER
!
 1    CONTINUE
        READ (ngeo, '(A80)', end=9000, err=8000) ligne
!
! - LA LIGNE COMMENCE PAR "GNN" - DEINITION D'UN POINT
!
        IF (ligne(1:3).EQ.'GNN') THEN
          npoin = npoin + 1
        ENDIF
!
! - LA LIGNE COMMENCE PAR "GE" - DEINITION D'UN ELEMENT
!
        IF (ligne(1:2).EQ.'GE') THEN
          nelem = nelem + 1
          READ(ligne(4:80),*,err=8000,end=9000) ie,
     &     (elmloc(j),j=1,8)
          IF (elmloc(8).NE.0.OR.
     &         (elmloc(4).NE.0.AND.elmloc(6).EQ.0) ) THEN
!
! - ON RAJOUTERA DES ELEMENTS
!
            nelem = nelem + 1
          ENDIF
        ENDIF
      GOTO 1
!
 9000 CONTINUE
      typele = 'TRIANGLES  '
      ndp = 3
      mesh = 3
!
      RETURN
!
! - TRAITEMENT ERREUR DE FICHIER
!
 8000 CONTINUE
      WRITE (lu,4001)
 4001 FORMAT (//,1x,'****************************'
     &        ,/,1x,'SUBROUTINE INIFAS :'
     &        ,/,1x,'ERROR READING FASTTABS FILE.'
     &        ,/,1x,'****************************')
      CALL plante(1)
      stop
      END