hvf.f

Go to the documentation of this file.

!                   **************
                    SUBROUTINE hvf
!                   **************
!
     &(h,hn,fxmat,unsv2d,dt,fxbor,smh,yasmh,nseg,npoin,nptfr,gloseg,
     & sizglo,nbor,optsou,t7,mesh,msk,rain,pluie)
!
!***********************************************************************
! BIEF   V6P2                                   21/08/2010
!***********************************************************************
!
!brief    FOR FINITE VOLUMES ADVECTION, COMPUTES AN INTERMEDIATE DEPTH
!+                IF THERE ARE SUB-ITERATIONS.
!
!history  CHI-TUAN PHAM (LNHE)
!+        09/02/2009
!+        V5P9
!+   JMH : SEQUENCE IF(MSK) : AVOIDS NEGATIVE DEPTHS
!
!history  N.DURAND (HRW), S.E.BOURBAN (HRW)
!+        13/07/2010
!+        V6P0
!+   Translation of French comments within the FORTRAN sources into
!+   English comments
!
!history  N.DURAND (HRW), S.E.BOURBAN (HRW)
!+        21/08/2010
!+        V6P0
!+   Creation of DOXYGEN tags for automated documentation and
!+   cross-referencing of the FORTRAN sources
!
!history  J-M HERVOUET (LNHE)
!+        24/02/2012
!+        V6P2
!+   Rain and evaporation added (after initiative by O. Boutron, from
!+   Tour du Valat, and O. Bertrand, Artelia group)
!
!~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~
!| DT             |-->| TIME STEP
!| FXBOR          |-->| FLUX ON BOUNDARIES (DEFINED ON ALL DOMAIN
!|                |   | AND ASSEMBLED IN PARALLEL)
!| FXMAT          |-->| MATRIX FOR STORING FLUXES.
!| GLOSEG         |-->| GLOBAL NUMBER OF THE 2 POINTS OF A SEGMENT
!| H              |-->| WATER DEPTH AT TIME N+1
!| HN             |-->| WATER DEPTH AT TIME N
!| MESH           |-->| MESh STRUCTURE
!| MSK            |-->| MSK : IF YES, MASKING OF DRY ELEMENTS
!| NBOR           |-->| GLOBAL NUMBER OF BOUNDARY POINTS
!| NPOIN          |-->| NUMBER OF POINTS
!| NPTFR          |-->| NUMBER OF BOUNDARY POINTS
!| NSEG           |-->| NUMBER OF SEGMENTS
!| OPTSOU         |-->| OPTION FOR THE TREATMENT OF SOURCES
!|                |   | 1: NORMAL  2: DIRAC
!|                |   | SEE PROPAG IN TELEMAC-2D
!| PLUIE          |-->| RAIN OR EVAPORATION, IN M/S
!| RAIN           |-->| IF YES: RAIN OR EVAPORATION
!| SIZGLO         |-->| FIRST DIMENSION OF GLOSEG
!| SMH            |-->| SOURCE TERM IN CONTINUITY EQUATION
!| T7             |<->| WORK BIEF_OBJ STRUCTURE
!| UNSV2D         |-->| INVERSE OF INTEGRALS OF TEST FUNCTIONS
!| YASMH          |-->| IF YES, SMH MUST BE TAKEN INTO ACCOUNT
!~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~
!
      USE bief, ex_hvf => hvf
!
      USE declarations_special
      IMPLICIT NONE
!
!+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+
!
      INTEGER, INTENT(IN)             :: NSEG,NPOIN,NPTFR,OPTSOU,SIZGLO
      INTEGER, INTENT(IN)             :: GLOSEG(sizglo,2)
      INTEGER, INTENT(IN)             :: NBOR(nptfr)
      DOUBLE PRECISION, INTENT(IN)    :: DT
      DOUBLE PRECISION, INTENT(INOUT) :: H(npoin)
      DOUBLE PRECISION, INTENT(IN)    :: HN(npoin),UNSV2D(npoin)
      DOUBLE PRECISION, INTENT(IN)    :: FXBOR(npoin),SMH(npoin)
      DOUBLE PRECISION, INTENT(IN)    :: FXMAT(nseg*2),PLUIE(npoin)
      LOGICAL, INTENT(IN)             :: YASMH,MSK,RAIN
      TYPE(bief_obj), INTENT(INOUT)   :: T7
      TYPE(bief_mesh), INTENT(INOUT)  :: MESH
!
!+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+
!
      INTEGER I,N
!
!-----------------------------------------------------------------------
!
      DO i = 1,npoin
        h(i) = hn(i)
      ENDDO
!
!     SOURCES
!
      IF(yasmh) THEN
        IF(optsou.EQ.1) THEN
          DO i = 1,npoin
            h(i) = h(i) + dt*smh(i)
          ENDDO
        ELSEIF(optsou.EQ.2) THEN
          DO i = 1,npoin
            h(i) = h(i) + dt*unsv2d(i)*smh(i)
          ENDDO
        ENDIF
      ENDIF
!
!     RAIN OR EVAPORATION
!
      IF(rain) THEN
        DO i = 1,npoin
          h(i) = h(i) + dt*pluie(i)
        ENDDO
      ENDIF
!
      IF(ncsize.GT.1) THEN
        DO i = 1,npoin
          t7%R(i) = 0.d0
        ENDDO
        DO i = 1,nseg
          t7%R(gloseg(i,1))=t7%R(gloseg(i,1))
     &                     -dt*unsv2d(gloseg(i,1))*fxmat(i)
          t7%R(gloseg(i,2))=t7%R(gloseg(i,2))
     &                     +dt*unsv2d(gloseg(i,2))*fxmat(i)
        ENDDO
        CALL parcom(t7,2,mesh)
        DO i = 1,npoin
          h(i) = h(i) + t7%R(i)
        ENDDO
      ELSE
        DO i = 1,nseg
          h(gloseg(i,1))=h(gloseg(i,1))-dt*unsv2d(gloseg(i,1))*fxmat(i)
          h(gloseg(i,2))=h(gloseg(i,2))+dt*unsv2d(gloseg(i,2))*fxmat(i)
        ENDDO
      ENDIF
!
!     ON THE BOUNDARIES : BOUNDARY FLUX TERMS
!
      DO i=1,nptfr
        n=nbor(i)
        h(n) = h(n) - dt*unsv2d(n)*fxbor(n)
      ENDDO
!
!-----------------------------------------------------------------------
!
!     WHEN NEGATIVE DEPTHS APPEAR WHILE COMPUTING H, THE PREVIOUS
!     VALUE OF H IS KEPT
!
      IF(msk) THEN
        DO i = 1,npoin
          IF(h(i).LT.0.d0) h(i) = max(1.d-2,hn(i))
        ENDDO
      ENDIF
!
!-----------------------------------------------------------------------
!
      RETURN
      END