hloc.f

Go to the documentation of this file.

!                   ***************
                    SUBROUTINE hloc
!                   ***************
!
     &(npoin,nseg,nelem,nubo,vnocl,airs,dthaut,mesh,eltseg,ifabor)
!
!***********************************************************************
! BIEF   V6P3                                   25/05/2013
!***********************************************************************
!
!brief    COMPUTES THE LOCAL SPACE STEP [ |CI|/SUM(LIJ) ].
!
!
!history  INRIA
!+
!+        V5P4
!+
!
!history  N.DURAND (HRW), S.E.BOURBAN (HRW)
!+        13/07/2010
!+        V6P0
!+   Translation of French comments within the FORTRAN sources into
!+   English comments
!
!history  N.DURAND (HRW), S.E.BOURBAN (HRW)
!+        21/08/2010
!+        V6P0
!+   Creation of DOXYGEN tags for automated documentation and
!+   cross-referencing of the FORTRAN sources
!+
! history R. ATA
!+         25/02/2012
!+         V6P3
!+   remove nubo and change by gloseg
!+   parallelization
!+
!history R. ATA
!+         25/05/2013
!+         V6P3
!+   clean unused variables and loop changed.
!
!~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~
!| AIRS           |-->| AREAS OF CELLS IN THE MESH.
!| DTHAUT         |<--| SPACE STEP
!| NBOR           |-->| GLOBAL NUMBER OF BOUNDARY POINTS
!| NPOIN          |-->| NUMBER OF POINTS
!| NPTFR          |-->| NUMBER OF BOUNDARY POINTS
!| NSEG           |-->| NUMBER OF SEGMENTS
!| NUBO           |-->| FIRST AND SECOND POINT OF SEGMENTS
!| VNOCL          |-->| NORMAL VECTOR TO INTERFACE
!|                |   | (2 FIRST COMPONENTS) AND
!|                |   | SEGMENT LENGTH (3RD COMPONENT)
!| XNEBOR         |-->| X-COMPONENT OF NORMAL VECTOR AT BOUNDARY POINT
!| YNEBOR         |-->| Y-COMPONENT OF NORMAL VECTOR AT BOUNDARY POINT
!~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~
!
      USE bief_def
      USE bief, ex_hloc => hloc
      USE declarations_special
      IMPLICIT NONE
!
!+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+
!
      INTEGER, INTENT(IN)            :: NSEG,NPOIN
      INTEGER, INTENT(IN)            :: NUBO(2,*)
      INTEGER, INTENT(IN)            :: NELEM
      INTEGER, INTENT(IN)            :: ELTSEG(nelem,3)
      DOUBLE PRECISION, INTENT(IN)   :: VNOCL(3,*)
      DOUBLE PRECISION, INTENT(IN)   :: AIRS(npoin)
      DOUBLE PRECISION, INTENT(OUT)  :: DTHAUT(npoin)
      TYPE(bief_mesh), INTENT(INOUT) :: MESH
      INTEGER, INTENT(IN)            :: IFABOR(nelem,3)
!
!+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+
!
      INTEGER I,NSG,NUBO1,NUBO2,IELEM,IER
      LOGICAL, ALLOCATABLE :: YESNO(:)
      ALLOCATE(yesno(nseg),stat=ier)
      CALL check_allocate(ier, 'HLOC')
!
!-----------------------------------------------------------------------
!
!     INITIALISES
!
      DO i=1,npoin
        dthaut(i) = 0.d0
      ENDDO
!     INITIALIZATION OF YESNO
      DO i=1,nseg
        yesno(i)=.false.
      ENDDO
!
      DO ielem=1, nelem
        DO i = 1,3
          IF(.NOT.yesno(eltseg(ielem,i)))THEN
            nsg = eltseg(ielem,i)
            nubo1 = nubo(1,nsg)
            nubo2 = nubo(2,nsg)
!           NUBO OR GLOSEG ARE THE SAME .. TO REMOVE NUBO (REDUNDANCE)
            IF(ncsize.GT.1.AND.ifabor(ielem,i).EQ.-2)THEN !THIS IS AN INTERFACE EDGE
              dthaut(nubo1)=dthaut(nubo1) + 0.5d0*vnocl(3,nsg)
              dthaut(nubo2)=dthaut(nubo2) + 0.5d0*vnocl(3,nsg)
            ELSE
              dthaut(nubo1)=dthaut(nubo1) + vnocl(3,nsg)
              dthaut(nubo2)=dthaut(nubo2) + vnocl(3,nsg)
            ENDIF
            yesno(nsg)=.true.
          ENDIF
        ENDDO
      ENDDO
!
      IF(ncsize.GT.1) THEN
        CALL parcom2(dthaut,dthaut,dthaut,npoin,1,2,1,mesh)
      ENDIF
!
      DO i=1,npoin
        dthaut(i) = airs(i)/ dthaut(i)
      ENDDO
!
      DEALLOCATE(yesno)
!
!-----------------------------------------------------------------------
!
      RETURN
      END