gtsh41.f

Go to the documentation of this file.

!                   *****************
                    SUBROUTINE gtsh41
!                   *****************
!
     &(shp,shz,shf,ws,fs,elt,eta,fre,ikle,eltcar,
     & npoin2,nelmax2,nplan,jf,nf,ya4d)
!
!***********************************************************************
! BIEF   V6P2                                   21/08/2010
!***********************************************************************
!
!brief    Gives the starting element and the barycentric coordinates of
!+        the head of characteristics.
!
!history  J-M JANIN (LNH)
!+        21/08/2008
!+        V5P9
!+
!
!history  N.DURAND (HRW), S.E.BOURBAN (HRW)
!+        13/07/2010
!+        V6P0
!+   Translation of French comments within the FORTRAN sources into
!+   English comments
!
!history  N.DURAND (HRW), S.E.BOURBAN (HRW)
!+        21/08/2010
!+        V6P0
!+   Creation of DOXYGEN tags for automated documentation and
!+   cross-referencing of the FORTRAN sources
!
!history  C. DENIS (SINETICS) & J-M HERVOUET (LNHE)
!+        09/05/2012
!+        V6P2
!+   New version using ELTCAR (done in MAKE_ELTCAR called by INBIEF)
!+
!
!~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~
!| ELT            |<--| 2D ELEMENT CHOSEN FOR EVERY POINT
!| ETA            |-->| LEVEL CHOSEN FOR EVERY POINT
!| ELTCAR         |-->| STARTING ELEMENT FOR LINEAR AND QUADRATIC POINTS
!| IKLE           |-->| CONNECTIVITY TABLE
!| NELMAX2        |-->| MAXIMUM NUMBER OF 2D ELEMENTS
!| NPLAN          |-->| NUMBER OF PLANES
!| NPOIN          |-->| NUMBER OF POINTS
!| NSEG           |-->| NUMBER OF SEGMENTS
!| QUAB           |-->| IF YES, THERE ARE QUASI-BUBBLE VARIABLES
!| QUAD           |-->| IF YES, THERE ARE QUADRATIC VARIABLES
!| SHP            |<--| BARYCENTRIC COORDINATES OF NODES IN THEIR
!|                |   | ASSOCIATED ELEMENT "ELT"
!| SHZ            |<--| BARYCENTRIC COORDINATES ON THE VERTICAL
!| WS             |-->| VERTICAL VELOCITY IN TRANSFORMED MESH
!~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~
!
      USE declarations_special
      IMPLICIT NONE
!
!+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+
!
      INTEGER, INTENT(IN)             :: NPOIN2,NELMAX2,NPLAN,JF,NF
      INTEGER, INTENT(IN)             :: IKLE(nelmax2,*),ELTCAR(*)
      INTEGER, INTENT(INOUT)          :: ELT(npoin2,nplan)
      INTEGER, INTENT(INOUT)          :: ETA(npoin2,nplan)
      INTEGER, INTENT(INOUT)          :: FRE(npoin2,nplan)
      DOUBLE PRECISION, INTENT(INOUT) :: SHP(3,npoin2,nplan)
      DOUBLE PRECISION, INTENT(INOUT) :: SHZ(npoin2,nplan)
      DOUBLE PRECISION, INTENT(INOUT) :: SHF(npoin2,nplan)
      DOUBLE PRECISION, INTENT(IN)    :: WS(npoin2,nplan)
      DOUBLE PRECISION, INTENT(IN)    :: FS(npoin2,nplan)
      LOGICAL         , INTENT(IN)    :: YA4D
!
!+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+
!
      INTEGER I,IELEM,IPLAN
!
!-----------------------------------------------------------------------
!
!     POINTS IN THE BOTTOM (LIKE GTSH41)
!
      DO i=1,npoin2
        ielem=eltcar(i)
        elt(i,1) = ielem
        IF(ielem.NE.0) THEN
          IF(ikle(ielem,1).EQ.i) THEN
            shp(1,i,1)=1.d0
            shp(2,i,1)=0.d0
            shp(3,i,1)=0.d0
          ELSEIF(ikle(ielem,2).EQ.i) THEN
            shp(1,i,1)=0.d0
            shp(2,i,1)=1.d0
            shp(3,i,1)=0.d0
          ELSEIF(ikle(ielem,3).EQ.i) THEN
            shp(1,i,1)=0.d0
            shp(2,i,1)=0.d0
            shp(3,i,1)=1.d0
          ELSE
            WRITE(lu,*) 'PROBLEM IN GTSH41'
            CALL plante(1)
            stop
          ENDIF
        ENDIF
      ENDDO
!
!     OTHER PLANES
!
      DO iplan=2,nplan
        DO i=1,npoin2
          elt(i,iplan) = elt(i,1)
          shp(1,i,iplan)=shp(1,i,1)
          shp(2,i,iplan)=shp(2,i,1)
          shp(3,i,iplan)=shp(3,i,1)
        ENDDO
      ENDDO
!
!     NOW ETA AND SHZ, DONE DEPENDING ON THE VERTICAL VELOCITY
!
      DO iplan = 1,nplan
        DO i=1,npoin2
          IF((ws(i,iplan).GT.0.d0.AND.iplan.NE.1).OR.
     &                                              iplan.EQ.nplan) THEN
            eta(i,iplan) = iplan-1
            shz(i,iplan) = 1.d0
          ELSE
            eta(i,iplan) = iplan
            shz(i,iplan) = 0.d0
          ENDIF
        ENDDO
      ENDDO
!
!     NOW FRE AND SHF, DONE DEPENDING ON THE FREQUENCY VELOCITY
!
      IF(ya4d) THEN
        DO iplan = 1,nplan
          DO i=1,npoin2
            IF((fs(i,iplan).GT.0.d0.AND.jf.NE.1).OR.jf.EQ.nf) THEN
              fre(i,iplan) = jf-1
              shf(i,iplan) = 1.d0
            ELSE
              fre(i,iplan) = jf
              shf(i,iplan) = 0.d0
            ENDIF
          ENDDO
        ENDDO
      ENDIF
!
!-----------------------------------------------------------------------
!
      RETURN
      END