gtsh11.f

Go to the documentation of this file.

!                   *****************
                    SUBROUTINE gtsh11
!                   *****************
!
     &(shp,elt,ikle,eltcar,npoin,nelem,nelmax,nseg,quab,quad)
!
!***********************************************************************
! BIEF   V6P2                                   21/08/2010
!***********************************************************************
!
!brief    Gives the starting element and the barycentric coordinates of
!+        the head of characteristics.
!
!note    In most cases (linear, quadratic) ELT is a mere copy of ELTCAR,
!+       but it will be changed in the computation of charactristics.
!
!history  J-M HERVOUET (LNHE)
!+        19/08/2008
!+        V5P9
!+
!
!history  N.DURAND (HRW), S.E.BOURBAN (HRW)
!+        13/07/2010
!+        V6P0
!+   Translation of French comments within the FORTRAN sources into
!+   English comments
!
!history  N.DURAND (HRW), S.E.BOURBAN (HRW)
!+        21/08/2010
!+        V6P0
!+   Creation of DOXYGEN tags for automated documentation and
!+   cross-referencing of the FORTRAN sources
!
!history  C. DENIS (SINETICS) & J-M HERVOUET (LNHE)
!+        09/05/2012
!+        V6P2
!+   New version using ELTCAR (done in MAKE_ELTCAR called by INBIEF)
!
!~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~
!| ELT            |<--| ELEMENT CHOSEN FOR EVERY POINT
!| ELTCAR         |-->| STARTING ELEMENT FOR LINEAR AND QUADRATIC POINTS
!|                |   | MUST HAVE THE RELEVANT SIZE.
!| IKLE           |-->| CONNECTIVITY TABLE
!| NELEM          |-->| NUMBER OF ELEMENTS
!| NELMAX         |-->| MAXIMUM NUMBER OF ELEMENTS
!| NPOIN          |-->| NUMBER OF POINTS
!| NSEG           |-->| NUMBER OF SEGMENTS
!| QUAB           |-->| IF YES, THERE ARE QUASI-BUBBLE VARIABLES
!| QUAD           |-->| IF YES, THERE ARE QUADRATIC VARIABLES
!| SHP            |<--| BARYCENTRIC COORDINATES OF NODES IN THEIR
!|                |   | ASSOCIATED ELEMENT "ELT"
!~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~
!
      USE declarations_special
      IMPLICIT NONE
!
!+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+
!
      INTEGER, INTENT(IN)             :: NPOIN,NELEM,NELMAX,NSEG
      INTEGER, INTENT(IN)             :: IKLE(nelmax,*),ELTCAR(*)
!                                            NPOIN
!                                            NPOIN+NELEM
!                                            NPOIN+NSEG
      INTEGER, INTENT(INOUT)          :: ELT(*)
      DOUBLE PRECISION, INTENT(INOUT) :: SHP(3,*)
      LOGICAL, INTENT(IN)             :: QUAB,QUAD
!
!+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+
!
      INTEGER I,IELEM
      DOUBLE PRECISION TIERS
      tiers=1.d0/3.d0
!
!-----------------------------------------------------------------------
!
      DO i=1,npoin
        ielem=eltcar(i)
        elt(i) = ielem
        IF(ielem.NE.0) THEN
          IF(ikle(ielem,1).EQ.i) THEN
            shp(1,i)=1.d0
            shp(2,i)=0.d0
            shp(3,i)=0.d0
          ELSEIF(ikle(ielem,2).EQ.i) THEN
            shp(1,i)=0.d0
            shp(2,i)=1.d0
            shp(3,i)=0.d0
          ELSEIF(ikle(ielem,3).EQ.i) THEN
            shp(1,i)=0.d0
            shp(2,i)=0.d0
            shp(3,i)=1.d0
          ELSE
            WRITE(lu,*) 'PROBLEM IN GTSH11'
            CALL plante(1)
            stop
          ENDIF
        ENDIF
      ENDDO
      IF(quab) THEN
        DO ielem=1,nelem
          i=npoin+ielem
          elt(i)=ielem
          shp(1,i)=tiers
          shp(2,i)=tiers
          shp(3,i)=tiers
        ENDDO
      ENDIF
      IF(quad) THEN
        DO i=npoin+1,npoin+nseg
          ielem=eltcar(i)
          elt(i)=ielem
          IF(ielem.NE.0) THEN
            IF(ikle(ielem,4).EQ.i) THEN
!             POINT 4
              shp(1,i)=0.5d0
              shp(2,i)=0.5d0
              shp(3,i)=0.d0
            ELSEIF(ikle(ielem,5).EQ.i) THEN
!             POINT 5
              shp(1,i)=0.d0
              shp(2,i)=0.5d0
              shp(3,i)=0.5d0
            ELSEIF(ikle(ielem,6).EQ.i) THEN
!             POINT 6
              shp(1,i)=0.5d0
              shp(2,i)=0.d0
              shp(3,i)=0.5d0
            ELSE
              WRITE(lu,*) 'PROBLEM IN GTSH11, QUADRATIC CASE'
              CALL plante(1)
              stop
            ENDIF
          ENDIF
        ENDDO
      ENDIF
!
!-----------------------------------------------------------------------
!
      RETURN
      END