gsebe.f

Go to the documentation of this file.

!                   ****************
                    SUBROUTINE gsebe
!                   ****************
!
     &(b,a,mesh)
!
!***********************************************************************
! BIEF   V6P1                                   21/08/2010
!***********************************************************************
!
!brief    FACTORISES THE ELEMENTARY MATRICES IN MATRIX A
!+                USING THE GAUSS-SEIDEL EBE METHOD.
!+
!+           (A CAN ALSO BE A BLOCK OF MATRICES; IN THIS CASE ALL
!+                THE MATRICES IN THE BLOCK ARE TREATED).
!
!warning  REQUIRES THAT THE DIAGONAL OF A BE THE IDENTITY
!
!history  J-M HERVOUET (LNH)
!+        23/12/94
!+        V5P1
!+
!
!history  N.DURAND (HRW), S.E.BOURBAN (HRW)
!+        13/07/2010
!+        V6P0
!+   Translation of French comments within the FORTRAN sources into
!+   English comments
!
!history  N.DURAND (HRW), S.E.BOURBAN (HRW)
!+        21/08/2010
!+        V6P0
!+   Creation of DOXYGEN tags for automated documentation and
!+   cross-referencing of the FORTRAN sources
!
!~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~
!| A              |<--| MATRIX A.
!| B              |<--| RESULTING MATRIX.
!| MESH           |-->| MESH STRUCTURE.
!~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~
!
      USE bief, ex_gsebe => gsebe
!
      USE declarations_special
      IMPLICIT NONE
!
!+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+
!
      TYPE(bief_obj), INTENT(IN) :: A
      TYPE(bief_obj), INTENT(INOUT) :: B
      TYPE(bief_mesh), INTENT(IN) :: MESH
!
!+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+
!
      INTEGER SA,SB,I
!
!-----------------------------------------------------------------------
!
      IF(a%TYPE.EQ.3) THEN
        sa = 0
      ELSEIF(a%TYPE.EQ.4) THEN
        sa = a%N
      ELSE
        WRITE(lu,400) a%TYPE
400     FORMAT(1x,'GSEBE (BIEF) :',1i6,' UNEXPECTED TYPE FOR A.')
        CALL plante(1)
        stop
      ENDIF
!
      IF(b%TYPE.EQ.3) THEN
        sb = 0
      ELSEIF(b%TYPE.EQ.4) THEN
        sb = b%N
      ELSE
        WRITE(lu,401) b%TYPE
401     FORMAT(1x,'GSEBE (BIEF) :',1i6,' UNEXPECTED TYPE FOR B.')
        CALL plante(1)
        stop
      ENDIF
!
!-----------------------------------------------------------------------
!
      IF(sa.EQ.0.AND.sb.EQ.0) THEN
!
!         B%D IS HERE A STRUCTURE OF VECTOR
!         USED AS DUMMY DIAGONAL
          CALL om('M=N     ', m=b, n=a, mesh=mesh)
          b%TYPDIA='I'
!
      ELSEIF(sa.GT.0.AND.sb.GT.0) THEN
!
!       TAKES THE DIAGONALS OF BLOCK A
!
        DO i=1,sb
          CALL om('M=N     ', m=b%ADR(i)%P, n=a%ADR(1+(sb+1)*(i-1))%P,
     &            mesh=mesh)
          b%ADR(i)%P%TYPDIA='I'
        ENDDO ! I
!
      ELSEIF(sa.NE.0.AND.sb.EQ.0) THEN
!
!       TAKES THE 1ST DIAGONAL OF BLOCK A
!
        CALL om('M=N     ', m=b, n=a%ADR(1)%P, mesh=mesh)
        b%TYPDIA='I'
!
      ELSE
!
        WRITE(lu,402)
402     FORMAT(1x,'GSEBE (BIEF) : UNEXPECTED CASE')
        CALL plante(1)
        stop
!
      ENDIF
!
!-----------------------------------------------------------------------
!
      RETURN
      END