gregtim.f

Go to the documentation of this file.

!                           ******************
                            SUBROUTINE gregtim
!                           ******************
!
     &(jultim,year,month,day,hour,minu,sec)
!
!
!***********************************************************************
! BIEF   V6P2                                   31/08/2011
!***********************************************************************
!
!brief    COMPUTES THE GREGORIAN CALENDAR DATE
!+        (YEAR,MONTH,DAY,HOUR,MIN,SEC)
!+        GIVEN THE JULIAN DATE (JD) IN CENTURY
!
!history  C.-T. PHAM (EDF-LNHE)
!+        31/08/2011
!+        V6P2
!+        FROM http://aa.usno.navy.mil/faq/docs/JD_Formula.php :
!+        GDATE ALGORITHM
!+        ORIGINAL ARTICLE: FLIEGEL AND VAN FLANDERN (1968),
!+        A MACHINE ALGORITHM FOR PROCESSING CALENDAR DATES
!+        FOR YEAR, MONTH AND DAY;
!+        AND FROM DELTARES, INITIALLY WL, SECTOR WATERBEHEER & MILIEU
!+        PROJET T0467 OR T1234.56, ANDRE HENDRIKS, V 1.01 (930429)
!+        FOR HOUR,MIN,SEC
!+
!
!history  U.H.Merkel
!+        19/07/2012
!+        V6P2
!+        Renamed MIN -> MINU because of Problems with NAG Compiler
!
!
!~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~
!| DAY            |<->| DAY    (1-28, 29, 30 OR 31)
!| HOUR           |<->| HOUR   (0-23) IN UNIVERSAL TIME
!| JULTIM         |-->| JULIAN DAY IN CENTURY
!| MIN            |<->| MINUTE (0-59) IN UNIVERSAL TIME
!| MONTH          |<->| MONTH  (1-12)
!| SEC            |<->| SECOND (0-59) IN UNIVERSAL TIME
!| YEAR           |<->| YEAR   (-4713-..)
!~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~
!
      USE declarations_special
      IMPLICIT NONE
!
!
!+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+
!
      INTEGER,          INTENT(INOUT) :: YEAR,MONTH,DAY,HOUR,MINU,SEC
      DOUBLE PRECISION, INTENT(IN)    :: JULTIM
!
!+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+
!
      INTEGER I,J,K,L,N
      DOUBLE PRECISION JD,JDR
!
      INTRINSIC int
!
!-----------------------------------------------------------------------
!
!  JULTIM UNIT: CENTURY
!  JD UNIT    : DAY
!
!  2415020 <=> 31/12/1899: DUE TO THE SHIFT IN JULTIM IN TELEMAC/BIEF
!
      jd=jultim*36525.d0+2415020.d0
!
      jdr=mod(jd,1.d0)
!
      IF (jdr.LT.0.5d0) THEN
        jdr = jdr+0.5d0
      ELSE
        jdr = jdr-0.5d0
        jd  = jd+1.d0
      ENDIF
!
      l = int(jd)+68569
      n = 4*l/146097
      l = l-(146097*n+3)/4
      i = 4000*(l+1)/1461001
      l = l-1461*i/4+31
      j = 80*l/2447
      k = l-2447*j/80
      l = j/11
      j = j+2-12*l
      i = 100*(n-49)+i+l
!
      year  = i
      month = j
      day   = k
!
      hour = int(jdr*24.d0)
      minu  = int(jdr*1440.d0)-60*hour
      sec  = nint(jdr*86400.d0)-3600*hour-60*minu
!
!  TO AVOID SEC = 60
!
      IF(sec.EQ.60) THEN
        sec = 0
        minu = minu + 1
      ENDIF
!
      IF(minu.GE.60) THEN
        minu  = minu  - 60
        hour = hour + 1
      ENDIF
!
      IF(hour.GE.24) THEN
        hour = hour - 24
        day  = day  + 1
      ENDIF
!
!-----------------------------------------------------------------------
!
      RETURN
      END