gredel_fdnrst.f

Go to the documentation of this file.

!                       ***************************
                        SUBROUTINE gredel_fdnrst
!                       ***************************
     &(ifrm,ito,x,y,nodenrs,npoin2,ifrm1,itop1)
!
!***********************************************************************
! PARALLEL   V6P0                                   21/08/2010
!***********************************************************************
!
!brief    FINDS THE NEAREST FROM -1 AND TO +1 POINTER.
!
!history  N.DURAND (HRW), S.E.BOURBAN (HRW)
!+        13/07/2010
!+        V6P0
!+   Translation of French comments within the FORTRAN sources into
!+   English comments
!
!history  N.DURAND (HRW), S.E.BOURBAN (HRW)
!+        21/08/2010
!+        V6P0
!+   Creation of DOXYGEN tags for automated documentation and
!+   cross-referencing of the FORTRAN sources
!
!history  LEO POSTMA (DELFT HYDRAULICS)
!+        03/04/2007
!+        V5P7
!+
!
!~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~
!| IFRM           |-->|
!| IFRM1          |---|
!| ITO            |-->|
!| ITOP1          |---|
!| NODENRS        |-->| IF > 0 : NODE NUMBER
!|                |   | IF
!| NPOIN2         |-->| NUMBER OF POINTS IN 2D
!| NPTFR          |-->| NOMBRE DE POINTS FRONTIERES
!| X,Y            |-->| NODE COORDINATES
!~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~
!
      USE declarations_special
      IMPLICIT NONE
!
!+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+
!
      INTEGER, INTENT(IN)          :: IFRM,ITO,NPOIN2
      INTEGER, INTENT(IN)          :: NODENRS(npoin2)
      INTEGER, INTENT(INOUT)       :: IFRM1,ITOP1
      REAL, INTENT(IN) :: X(npoin2), Y(npoin2)
!
!+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+
!
      INTEGER IPOIN
      REAL XFRM1,XTOP1,YFRM1,YTOP1,DISFRM,DISTO,DX,DY
!
!-----------------------------------------------------------------------
!
      xfrm1  = x(ifrm)
      yfrm1  = y(ifrm)
      xtop1  = x(ito )
      ytop1  = y(ito )
      disfrm = xfrm1-xtop1
      xfrm1  = xfrm1 + disfrm
      xtop1  = xtop1 - disfrm
      disfrm = yfrm1-ytop1
      yfrm1  = yfrm1 + disfrm
      ytop1  = ytop1 - disfrm
!
      dx     = xfrm1-x(1)
      dy     = yfrm1-y(1)
      disfrm = dx*dx + dy*dy
      dx     = xtop1-x(1)
      dy     = ytop1-y(1)
      disto  = dx*dx + dy*dy
      ifrm1  = 1
      itop1  = 1
      DO ipoin = 2, npoin2
        dx     = xfrm1-x(ipoin)
        dy     = yfrm1-y(ipoin)
        dx     = dx*dx + dy*dy
        IF(dx.LT.disfrm) THEN
          disfrm = dx
          ifrm1  = ipoin
        ENDIF
        dx     = xtop1-x(ipoin)
        dy     = ytop1-y(ipoin)
        dx     = dx*dx + dy*dy
        IF(dx.LT.disto) THEN
          disto  = dx
          itop1  = ipoin
        ENDIF
      ENDDO
      ifrm1 = nodenrs(ifrm1)
      itop1 = nodenrs(itop1)
!
!-----------------------------------------------------------------------
!
      RETURN
      END SUBROUTINE gredel_fdnrst