gradp.f

Go to the documentation of this file.

!                   ****************
                    SUBROUTINE gradp
!                   ****************
!
     &(ns,nt,ikle,airt,x,y,dpx,dpy)
!
!***********************************************************************
! BIEF   V6P1                                   21/08/2010
!***********************************************************************
!
!brief    COMPUTES THE BASES FUNCTIONS GRADIENTS.
!
!history  INRIA
!+
!+        V5P4
!+
!
!history  N.DURAND (HRW), S.E.BOURBAN (HRW)
!+        13/07/2010
!+        V6P0
!+   Translation of French comments within the FORTRAN sources into
!+   English comments
!
!history  N.DURAND (HRW), S.E.BOURBAN (HRW)
!+        21/08/2010
!+        V6P0
!+   Creation of DOXYGEN tags for automated documentation and
!+   cross-referencing of the FORTRAN sources
!
!~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~
!| AIRT           |-->| AREA OF TRIANGLES
!| DPX            |<--| GRADIENT OF BASES FUNCTIONS WITH RESPECT TO X
!| DPY            |<--| GRADIENT OF BASES FUNCTIONS WITH RESPECT TO Y
!| IKLE           |-->| CONNECTIVITY TABLE
!| NS             |-->| NUMBER OF POINTS IN THE MESH
!| NT             |-->| NUMBER OF TRIANGLES IN THE MESH
!| X              |-->| ABSCISSAE OF NODES IN THE MESH
!| Y              |-->| ORDINATES OF NODES IN THE MESH
!~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~
!
      USE declarations_special
      IMPLICIT NONE
!
!+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+
!
      INTEGER, INTENT(IN)           :: NS,NT,IKLE(nt,3)
      DOUBLE PRECISION, INTENT(IN)  :: X(ns),Y(ns),AIRT(nt)
      DOUBLE PRECISION, INTENT(OUT) :: DPX(3,nt),DPY(3,nt)
!
!+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+
!
      INTEGER JT,NUBO1,NUBO2,NUBO3
      DOUBLE PRECISION AIRJI,X1,X2,X3,Y1,Y2,Y3
!
!-----------------------------------------------------------------------
!
      DO jt=1,nt
!
        nubo1 = ikle(jt,1)
        nubo2 = ikle(jt,2)
        nubo3 = ikle(jt,3)
!
        airji = 0.5d0/airt(jt)
!
!       COMPUTES THE P1-GRADIENTS
!
        x1 = x(nubo1)
        y1 = y(nubo1)
        x2 = x(nubo2)
        y2 = y(nubo2)
        x3 = x(nubo3)
        y3 = y(nubo3)
!
        dpx(1,jt) = airji*(y2-y3)
        dpx(2,jt) = airji*(y3-y1)
        dpx(3,jt) = airji*(y1-y2)
        dpy(1,jt) = airji*(x3-x2)
        dpy(2,jt) = airji*(x1-x3)
        dpy(3,jt) = airji*(x2-x1)
!
      ENDDO
!
!-----------------------------------------------------------------------
!
      RETURN
      END