goup.f

Go to the documentation of this file.

!                   ***************
                    SUBROUTINE goup
!                   ***************
!
     &(x, a,b ,ditr,mesh,copy)
!
!***********************************************************************
! BIEF   V6P0                                   21/08/2010
!***********************************************************************
!
!brief    SOLVES THE SYSTEM U X = B (ELEMENT BY ELEMENT).
!code
!+            THE MATRIX U IS HERE THE RESULT OF A DECOMPOSITION
!+            DONE IN SUBROUTINE DECLDU
!+
!+            EACH ELEMENTARY MATRIX WAS FACTORISED IN THE FORM:
!+
!+            LE X DE X UE
!+
!+            LE : LOWER TRIANGULAR WITH 1S ON THE DIAGONAL
!+            DE : DIAGONAL
!+            UE : UPPER TRIANGULAR WITH 1S ON THE DIAGONAL
!+
!+                                                T
!+            IF THE MATRIX IS SYMMETRICAL : LE =  UE
!
!code
!+-----------------------------------------------------------------------
!+  MEANING OF IELM :
!+
!+  TYPE OF ELEMENT      NUMBER OF POINTS      CODED IN THIS SUBROUTINE
!+
!+  11 : P1 TRIANGLE            3                       YES
!+  12 : QUASI-BUBBLE TRIANGLE  4                       YES
!+  21 : Q1 QUADRILATERAL       4                       YES
!+  41 : TELEMAC-3D PRISMS      6                       YES
!+
!+-----------------------------------------------------------------------
!
!history  J-M HERVOUET (LNH)
!+        23/12/94
!+        V5P1
!+
!
!history  N.DURAND (HRW), S.E.BOURBAN (HRW)
!+        13/07/2010
!+        V6P0
!+   Translation of French comments within the FORTRAN sources into
!+   English comments
!
!history  N.DURAND (HRW), S.E.BOURBAN (HRW)
!+        21/08/2010
!+        V6P0
!+   Creation of DOXYGEN tags for automated documentation and
!+   cross-referencing of the FORTRAN sources
!
!~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~
!| A              |-->| MATRIX A IN LDU FORM
!| B              |<--| RIGHT-HAND SIDE OF THE SYSTEM
!| COPY           |-->| IF YES. B IS FIRST COPIED ON X.
!| DITR           |-->| OPTION  'D' : MATRIX A IS TAKEN
!|                |   |         'T' : MATRIX TRANSPOSED(A)
!| MESH           |-->| MESH STRUCTURE
!| X              |<--| SOLUTION OF SYSTEM AX = B
!~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~
!
      USE bief, ex_goup => goup
!
      USE declarations_special
      IMPLICIT NONE
!
!+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+
!
      TYPE(bief_obj), INTENT(INOUT) :: X
      TYPE(bief_obj), INTENT(IN)    :: A,B
      TYPE(bief_mesh), INTENT(IN)   :: MESH
      CHARACTER(LEN=1), INTENT(IN)  :: DITR
      LOGICAL, INTENT(IN) :: COPY
!
!+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+
!
      INTEGER S,SA,I
!
!-----------------------------------------------------------------------
!
      IF(x%TYPE.EQ.4) THEN
        s = x%N
      ELSE
        s = 0
      ENDIF
!
!     CASE WHERE THE SYSTEM IS A BLOCK BUT WHERE ONLY ONE
!     PRECONDITIONING MATRIX IS USED
!
      IF(a%TYPE.EQ.3) THEN
        sa = 0
      ELSEIF(a%TYPE.EQ.4) THEN
        sa = a%N
      ELSE
        WRITE(lu,400) a%TYPE
400     FORMAT(1x,'GOUP (BIEF) :',1i6,' UNEXPECTED TYPE FOR A.')
        CALL plante(0)
        stop
      ENDIF
!
!-----------------------------------------------------------------------
!
      IF(s.EQ.0.AND.sa.EQ.0) THEN
!
!     CASE WHERE A IS A SIMPLE MATRIX AND X A SIMPLE VECTOR
!
        CALL goup1(x, a,b ,ditr,mesh,copy)
!
      ELSEIF(s.GT.0.AND.s.EQ.sa) THEN
!
!     CASE WHERE BLOCK A ONLY HAS DIAGONALS
!
        DO i=1,s
          CALL goup1( x%ADR(i)%P,a%ADR(i)%P,b%ADR(i)%P,ditr,mesh,copy)
        ENDDO ! I
!
      ELSEIF(s.GT.0.AND.s**2.EQ.sa) THEN
!
!     CASE WHERE BLOCK A HAS AS MANY MATRICES AS THE WHOLE SYSTEM :
!     ONLY CONSIDERS THE DIAGONALS
!
        DO i=1,s
          CALL goup1( x%ADR(i)%P,
     &                a%ADR(1+(s+1)*(i-1))%P,
     &                b%ADR(i)%P,
     &                ditr,mesh,copy)
        ENDDO ! I
!
!     CASE WHERE A IS A SINGLE MATRIX AND X A BLOCK
!
      ELSEIF(s.GT.0.AND.sa.EQ.0) THEN
!
        DO i=1,s
          CALL goup1(x%ADR(i)%P,
     &                a,
     &                b%ADR(i)%P,
     &                ditr,mesh,copy)
        ENDDO ! I
!
      ELSE
        WRITE(lu,401)
401     FORMAT(1x,'GOUP (BIEF) : UNEXPECTED CASE')
        CALL plante(1)
        stop
      ENDIF
!
!-----------------------------------------------------------------------
!
      RETURN
      END