get_data_timestep.f

Go to the documentation of this file.

!                   ****************************
                    SUBROUTINE get_data_timestep
!                   ****************************
!
     &(fformat,fid,record,time,ierr)
!
!***********************************************************************
! HERMES   V7P3
!***********************************************************************
!
!brief    Returns the time step of a given time value
!
!history  N.DURAND (HRW)
!+        September 2017
!+        V7P3
!+   First version
!
!~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~
!| FFORMAT        |-->| FORMAT OF THE FILE
!| FID            |-->| FILE DESCRIPTOR
!| RECORD         |-->| NUMBER OF THE TIME STEP
!| TIME           |<->| TIME IN SECOND OF THE TIME STEP
!| IERR           |<--| 0 IF NO ERROR DURING THE EXECUTION
!~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~
!
      USE interface_hermes, tmp => get_data_timestep
      USE declarations_special
      IMPLICIT NONE
!
!+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+
!
      CHARACTER(LEN=8), INTENT(IN)  :: FFORMAT
      INTEGER,          INTENT(IN)  :: FID
      INTEGER,          INTENT(OUT) :: RECORD
      DOUBLE PRECISION, INTENT(IN)  :: TIME
      INTEGER,          INTENT(OUT) :: IERR
!
!+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+
!
      INTEGER          :: NTIMESTEP
      DOUBLE PRECISION :: TIME1,FIRSTTIME,LASTTIME,EPS
!
!-----------------------------------------------------------------------
!
      record = 0
      eps=0.d0
      CALL get_data_time(fformat,fid,0,firsttime,ierr)
      IF(ierr.NE.0) RETURN
      CALL get_data_ntimestep(fformat,fid,ntimestep,ierr)
      IF(ierr.NE.0) RETURN
      CALL get_data_time(fformat,fid,ntimestep-1,lasttime,ierr)
      IF(ierr.NE.0) RETURN
      !
      ! FIRST CHECK IF THE TIME VALUE IS IN THE FILE
      IF((time.GT.lasttime.OR.time.LT.firsttime).AND.
     &   ntimestep.GT.0) THEN
        ierr = hermes_record_unknown_err
        WRITE(error_message, *) 'TIME FOR GET_DATA_TIMESTEP: ', time,
     &      ' IS NOT IN THE FILE [',firsttime,', ',lasttime,']'
        RETURN
      !
      ELSE
        record = 0
        time1 = firsttime
        DO WHILE ((time1.LT.time).AND.(abs(time1-time).GT.eps) )
          record = record + 1
          CALL get_data_time(fformat,fid,record,time1,ierr)
          IF(ierr.NE.0) RETURN
        ENDDO
      ENDIF
!
!-----------------------------------------------------------------------
!
      RETURN
      END