get_bnd_value.f

Go to the documentation of this file.

!                   ************************
                    SUBROUTINE get_bnd_value
!                   ************************
!
     &(fformat,fid,typ_bnd_elem,nelebd,lihbor,liubor,
     & livbor,hbor,ubor,vbor,chbord,trac,
     & litbor,tbor,atbor,btbor,nptfr,ierr)
!
!***********************************************************************
! HERMES   V7P0                                               01/05/2014
!***********************************************************************
!
!brief    Returns an array containing the boundary type for each
!+        boundary point
!
!history  Y AUDOUIN (LNHE)
!+        24/03/2014
!+        V7P0
!+
!
!~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~
!| FFORMAT        |-->| FORMAT OF THE FILE
!| FID            |-->| FILE DESCRIPTOR
!| TYP_BND_ELEM   |-->| TYPE OF THE BOUNDARY ELEMENTS
!| NELEBD         |-->| NUMBER OF BOUNDARY ELEMENTS
!| LIHBOR         |-->| TYPE OF BOUNDARY CONDITIONS ON DEPTH
!| LIUBOR         |-->| TYPE OF BOUNDARY CONDITIONS ON U
!| LIVBOR         |-->| TYPE OF BOUNDARY CONDITIONS ON V
!| HBOR           |<--| PRESCRIBED BOUNDARY CONDITION ON DEPTH
!| UBOR           |<--| PRESCRIBED BOUNDARY CONDITION ON VELOCITY U
!| VBOR           |<--| PRESCRIBED BOUNDARY CONDITION ON VELOCITY V
!| CHBORD         |<--| FRICTION COEFFICIENT AT BOUNDARY
!| TRAC           |-->| IF YES, THERE ARE TRACERS
!| LITBOR         |-->| PHYSICAL BOUNDARY CONDITIONS FOR TRACERS
!| TBOR           |<--| PRESCRIBED BOUNDARY CONDITION ON TRACER
!| ATBOR,BTBOR    |<--| THERMAL EXCHANGE COEFFICIENTS.
!| NPTFR          |-->| NUMBER OF BOUNDARY POINTS
!| IERR           |<--| 0 IF NO ERROR DURING THE EXECUTION
!~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~
!
      USE utils_serafin
      USE utils_med
      USE utils_cgns
      USE declarations_special
      IMPLICIT NONE
!
!+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+
!
      CHARACTER(LEN=8), INTENT(IN)    :: FFORMAT
      INTEGER,          INTENT(IN)    :: FID
      INTEGER,          INTENT(IN)    :: TYP_BND_ELEM
      INTEGER,          INTENT(IN)    :: NELEBD
      INTEGER,          INTENT(IN)    :: NPTFR
      INTEGER,          INTENT(INOUT) :: LIHBOR(nptfr)
      INTEGER,          INTENT(INOUT) :: LIUBOR(nptfr),LIVBOR(nptfr)
      INTEGER,          INTENT(INOUT) :: LITBOR(*)
      DOUBLE PRECISION, INTENT(INOUT) :: UBOR(*),VBOR(*)
      DOUBLE PRECISION, INTENT(INOUT) :: HBOR(nptfr),CHBORD(nptfr)
      DOUBLE PRECISION, INTENT(INOUT) :: TBOR(*),ATBOR(*)
      DOUBLE PRECISION, INTENT(INOUT) :: BTBOR(*)
      LOGICAL,          INTENT(IN)    :: TRAC
      INTEGER,          INTENT(OUT)   :: IERR
!
!+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+
!
      INTEGER :: I
!
!-----------------------------------------------------------------------
!
      IF((typ_bnd_elem.EQ.type_null).OR.(nelebd.EQ.0)) RETURN
!
      SELECT CASE (fformat(1:7))
        CASE ('SERAFIN')
          CALL get_bnd_value_srf(fid, typ_bnd_elem,nptfr,lihbor,liubor,
     &                           livbor,hbor,ubor,vbor,chbord,trac,
     &                           litbor,tbor,atbor,btbor, ierr)
        CASE ('MED    ')
          CALL get_bnd_value_med(fid,typ_bnd_elem,nelebd,lihbor,
     &                           liubor,livbor,trac,litbor,
     &                           nptfr,ierr)
          DO i=1,nptfr
            hbor(i) = 0.d0
            ubor(i) = 0.d0
            vbor(i) = 0.d0
            chbord(i) = 0.d0
            IF(trac) THEN
              tbor(i) = 0.d0
              atbor(i) = 0.d0
              btbor(i) = 0.d0
            ENDIF
          ENDDO
        CASE ('CGNS   ')
          CALL get_bnd_value_cgns(fid, typ_bnd_elem,nptfr,lihbor,liubor,
     &                           livbor,hbor,ubor,vbor,chbord,trac,
     &                           litbor,tbor,atbor,btbor, ierr)
        CASE DEFAULT
          ierr = hermes_unknown_file_format_err
          WRITE(error_message,*)
     &         'GET_BND_VALUE: BAD FILE FORMAT: ',fformat
          RETURN
      END SELECT
!
!-----------------------------------------------------------------------
!
      RETURN
      END