geoelt.f

Go to the documentation of this file.

!                   *****************
                    SUBROUTINE geoelt
!                   *****************
!
     &(surdet,surfac,xel,yel,nelem,nelmax,ielm)
!
!***********************************************************************
! BIEF   V6P1                                   21/08/2010
!***********************************************************************
!
!brief    COMPUTES DETERMINANTS AND SOME OTHER VALUES FOR
!+                ISOPARAMETRIC COORDINATES.
!
!history  J-M HERVOUET (LNH)
!+        10/01/95
!+        V5P1
!+
!
!history  N.DURAND (HRW), S.E.BOURBAN (HRW)
!+        13/07/2010
!+        V6P0
!+   Translation of French comments within the FORTRAN sources into
!+   English comments
!
!history  N.DURAND (HRW), S.E.BOURBAN (HRW)
!+        21/08/2010
!+        V6P0
!+   Creation of DOXYGEN tags for automated documentation and
!+   cross-referencing of the FORTRAN sources
!
!~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~
!| IELM           |-->| TYPE OF ELEMENT
!| NELEM          |-->| NUMBER OF ELEMENTS
!| NELMAX         |-->| MAXIMUM NUMBER OF ELEMENTS
!| SURDET         |<--| 1.D0/DETERMINANT(TRANSFORMATION)
!| SURFAC         |<--| AREA OF ELEMENTS
!| XEL            |-->| ABSCISSAE OF POINTS IN THE MESH, PER ELEMENT
!| YEL            |-->| ORDINATES OF POINTS IN THE MESH, PER ELEMENT
!~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~
!
      USE bief, ex_geoelt => geoelt
!
      USE declarations_special
      IMPLICIT NONE
!
!+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+
!
      INTEGER, INTENT(IN)           :: IELM,NELEM,NELMAX
      DOUBLE PRECISION, INTENT(OUT) :: SURDET(nelem),SURFAC(nelem)
      DOUBLE PRECISION, INTENT(IN)  :: XEL(nelmax,*),YEL(nelmax,*)
!
!+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+
!
      INTEGER IELEM
!
      DOUBLE PRECISION XSOM(4,2)
!
      DOUBLE PRECISION T12,T13,T22,T23,DET
!
!-----------------------------------------------------------------------
!
      CALL survol(surfac, xel,yel,nelem,nelmax,ielm)
!
      IF(ielm.EQ.11) THEN
!
        DO ielem = 1 , nelem
!
        xsom(1,1) = xel(ielem,1)
        xsom(2,1) = xel(ielem,2)
        xsom(3,1) = xel(ielem,3)
        xsom(1,2) = yel(ielem,1)
        xsom(2,2) = yel(ielem,2)
        xsom(3,2) = yel(ielem,3)
!
        t12 = - xsom(1,1) + xsom(2,1)
        t13 = - xsom(1,1) + xsom(3,1)
        t22 = - xsom(1,2) + xsom(2,2)
        t23 = - xsom(1,2) + xsom(3,2)
!
        det = t12*t23 - t22*t13
!
        IF(det.LT.1.d-20) THEN
          WRITE(lu,99) ielem
99        FORMAT(1x,'GEOELT: ELEMENT ',1i6,' : NEGATIVE DETERMINANT')
          CALL plante(1)
          stop
        ENDIF
!
        surdet(ielem) = 1.d0/det
!
        ENDDO
!
      ELSE
!
        WRITE(lu,11) ielm
11      FORMAT(1x,'GEOELT: UNKNOWN TYPE OF ELEMENT :',1i6)
        CALL plante(1)
        stop
!
      ENDIF
!
!-----------------------------------------------------------------------
!
      RETURN
      END