fsprd3.f

Go to the documentation of this file.

!                   *****************
                    SUBROUTINE fsprd3
!                   *****************
!
     &( fra   , ndire , spred1, teta1 , spred2, teta2 , xlamda)
!
!***********************************************************************
! TOMAWAC   V6P1                                   15/06/2011
!***********************************************************************
!
!brief    COMPUTES THE BIMODAL DIRECTIONAL SPREADING FUNCTION
!+                FOR A RANGE OF DIRECTIONS.
!code
!+              2S
!+           COS  ((T-T0)/2.)    (MITSUYASU)
!
!history  M. BENOIT
!+        07/11/96
!+        V1P2
!+   CREATED
!
!history  N.DURAND (HRW), S.E.BOURBAN (HRW)
!+        13/07/2010
!+        V6P0
!+   Translation of French comments within the FORTRAN sources into
!+   English comments
!
!history  N.DURAND (HRW), S.E.BOURBAN (HRW)
!+        21/08/2010
!+        V6P0
!+   Creation of DOXYGEN tags for automated documentation and
!+   cross-referencing of the FORTRAN sources
!
!history  G.MATTAROLO (EDF - LNHE)
!+        15/06/2011
!+        V6P1
!+   Translation of French names of the variables in argument
!
!~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~
!| FRA            |<--| DIRECTIONAL SPREADING FUNCTION VALUES
!| NDIRE          |-->| NUMBER OF DIRECTIONS
!| SPRED1         |-->| DIRECTIONAL SPREAD 1
!| SPRED2         |-->| DIRECTIONAL SPREAD 1
!| TETA1          |-->| MAIN DIRECTION 1
!| TETA2          |-->| MAIN DIRECTION 2
!| XLAMDA         |-->| WEIGHTING FACTOR FOR FRA
!~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~
!
      USE declarations_tomawac, ONLY : teta
!
      USE interface_tomawac, ex_fsprd3 => fsprd3
      IMPLICIT NONE
!
!.....VARIABLES IN ARGUMENT
!     """"""""""""""""""""
      INTEGER,INTENT(IN)             :: NDIRE
      DOUBLE PRECISION,INTENT(IN)    :: SPRED1, TETA1 , SPRED2, TETA2
      DOUBLE PRECISION,INTENT(IN)    :: XLAMDA
      DOUBLE PRECISION,INTENT(INOUT) :: FRA(ndire)
!
!.....LOCAL VARIABLES
!     """""""""""""""""
      INTEGER  JP
      DOUBLE PRECISION DELT1 , DELT2 , FTH   , FRA1  , FRA2  , ARGUM
      DOUBLE PRECISION ARGMI1, ARGMI2
      delt1 = 0.5d0/delfra(spred1)
      delt2 = 0.5d0/delfra(spred2)
      IF (spred1.GT.1.d-1) THEN
        argmi1=10.d0**(-4.d0/spred1)
      ELSE
        argmi1=0.d0
      ENDIF
      IF (spred2.GT.1.d-1) THEN
        argmi2=10.d0**(-4.d0/spred2)
      ELSE
        argmi2=0.d0
      ENDIF
!
      DO jp=1, ndire
        fth = teta(jp)
!
        argum = abs(cos(0.5d0*(fth-teta1)))
        IF (argum.GT.argmi1) THEN
          fra1=delt1*argum**(2.d0*spred1)
        ELSE
          fra1=0.d0
        ENDIF
!
        argum = abs(cos(0.5d0*(fth-teta2)))
        IF (argum.GT.argmi2) THEN
          fra2=delt2*argum**(2.d0*spred2)
        ELSE
          fra2=0.d0
        ENDIF
!
        fra(jp)=xlamda*fra1+(1.d0-xlamda)*fra2
        IF (fra(jp).LT.1.d-10) fra(jp)=0.d0
      ENDDO ! JP
!
      RETURN
      END