fropro.f

Go to the documentation of this file.

!                   *****************
                    SUBROUTINE fropro
!                   *****************
!
     &(nbor,ikle,nelem,nelmax,npoin,npmax,nptfr,ielm,
     & iklem1,limvoi,optass,produc,mxptvs,t1,
     & gloseg,sizglo,nseg)
!
!***********************************************************************
! BIEF   V6P3                                  21/08/2010
!***********************************************************************
!
!brief    COMPUTES THE ARRAYS GIVING ADRESSES FOR
!+                FRONTAL MATRIX-VECTOR PRODUCT.
!
!history  J-M HERVOUET (LNHE)
!+        20/03/08
!+        V5P9
!+
!
!history  N.DURAND (HRW), S.E.BOURBAN (HRW)
!+        13/07/2010
!+        V6P0
!+   Translation of French comments within the FORTRAN sources into
!+   English comments
!
!history  N.DURAND (HRW), S.E.BOURBAN (HRW)
!+        21/08/2010
!+        V6P0
!+   Creation of DOXYGEN tags for automated documentation and
!+   cross-referencing of the FORTRAN sources
!
!history  J-M HERVOUET (EDF R&D, LNHE)
!+        11/03/2013
!+        V6P3
!+   Dimension of LIMVOI now set to 11.
!
!~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~
!| GLOSEG         |-->| FIRST AND SECOND POINT OF SEGMENTS
!| IELM           |-->| TYPE OF ELEMENT.
!|                |   | 11 : TRIANGLES.
!|                |   | 21 : QUADRANGLES.
!| IKLE           |-->| CONNECTIVITY TABLE.
!| IKLEM1         |<--| VARIOUS ADDRESSES IN OFF-DIAGONAL PART
!|                |   | OF A MATRIX
!| LIMVOI         |<--| LIMVOI(K,1) : BEGINNING OF SERIES WITH K NEIGHBOURS
!|                |   | LIMVOI(K,2) : END       OF SERIES WITH K NEIGHBOURS
!| MXPTVS         |-->| MAXIMUM NUMBER OF NEIGHBOURS OF A POINT
!| NBOR           |-->| GLOBAL NUMBER OF BOUNDARY POINTS
!| NELEM          |-->| NUMBER OF ELEMENTS
!| NELMAX         |-->| MAXIMUM NUMBER OF ELEMENTS
!| NPMAX          |-->| MAXIMUM NUMBER OF POINTS
!| NPOIN          |-->| NUMBER OF POINTS
!| NPTFR          |-->| NUMBER OF BOUNDARY POINTS
!| NSEG           |-->| NUMBER OF SEGMENTS
!| OPTASS         |-->| OPTION OF MATRIX STORAGE
!|                |   | 1: ELEMENT PER ELEMENT 3: EDGE-BASED
!| PRODUC         |-->| CHOICE OF MATRIX-VECTOR PRODUCT
!|                |   | 1: NORMAL 2: FRONTAL
!| SIZGLO         |-->| FIRST DIMENSION OF GLOSEG
!| T1             |-->| INTEGER WORK ARRAY
!~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~
!
      USE bief, ex_fropro => fropro
!
      USE declarations_special
      IMPLICIT NONE
!
!+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+
!
      INTEGER, INTENT(IN)    :: NELMAX,NPMAX,MXPTVS,NELEM
      INTEGER, INTENT(IN)    :: NPOIN,NPTFR,IELM,OPTASS,PRODUC
      INTEGER, INTENT(IN)    :: NSEG,SIZGLO,NBOR(*)
      INTEGER, INTENT(IN)    :: IKLE(nelmax,*),GLOSEG(sizglo,2)
      INTEGER, INTENT(OUT)   :: IKLEM1(npmax,mxptvs,4,2)
!                                      11: SEE ALMESH AND OPASS
      INTEGER, INTENT(OUT)   :: LIMVOI(11,2)
      INTEGER, INTENT(OUT)   :: T1(npoin)
!
!+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+
!
      INTEGER IELEM,IPTFR,IPOIN,ISG,K,I,I1,I2,NBVOIS
!
!-----------------------------------------------------------------------
!
      IF(ielm.NE.11) THEN
        WRITE(lu,901) ielm
901     FORMAT(1x,'FROPRO: IELM=',1i6,' UNKNOWN TYPE OF ELEMENT')
        CALL plante(1)
        stop
      ENDIF
!
      IF(produc.EQ.2) THEN
!
!=======================================================================
! COMPUTES THE NUMBER OF NEIGHBOURING POINTS AND ELEMENTS
!=======================================================================
!
        DO ipoin = 1,npoin
          t1(ipoin) = 0
        ENDDO
!
!       NUMBER OF ELEMENTS NEIGHBOURING A POINT
!
        DO ielem = 1,nelem
          t1(ikle(ielem,1)) = t1(ikle(ielem,1)) + 1
          t1(ikle(ielem,2)) = t1(ikle(ielem,2)) + 1
          t1(ikle(ielem,3)) = t1(ikle(ielem,3)) + 1
        ENDDO
!
!       NUMBER OF POINTS NEIGHBOURING A POINT
!     = NUMBER OF ELEMENTS NEIGHBOURING A POINT
!     + 1 ON BOUNDARIES
!
        DO iptfr = 1,nptfr
          t1(nbor(iptfr)) = t1(nbor(iptfr)) + 1
        ENDDO
!
!=======================================================================
! CHECKS THAT THE RENUMBERING WAS MADE CORRECTLY IN STBTEL
! FILLS IN LIMVOI AND IKLEM1
!=======================================================================
!
        IF(t1(1).EQ.0) THEN
          WRITE(lu,97)
97        FORMAT(1x,'FROPRO: POINT NUMBER 1 HAS NO NEIGHBOUR')
          CALL plante(1)
          stop
        ENDIF
!
        DO ipoin = 2,npoin
          IF(t1(ipoin).LT.t1(ipoin-1)) THEN
            WRITE(lu,99)
99          FORMAT(1x,'FROPRO: FRONTAL PRODUCT REQUIRES A',/,1x,
     &                'RENUMBERING OF POINTS WITH STBTEL')
            CALL plante(1)
            stop
          ELSEIF(t1(ipoin).GT.mxptvs) THEN
            WRITE(lu,95) ipoin
95          FORMAT(1x,'FROPRO: POINT ',1i6,' HAS TOO MANY NEIGHBOURS')
            CALL plante(1)
            stop
          ENDIF
        ENDDO
!
!  BUILDS ARRAY LIMVOI
!  LIMVOI(K,1) : BEGINNING OF SERIES WITH K NEIGHBOURS
!  LIMVOI(K,2) : END       OF SERIES WITH K NEIGHBOURS
!
        DO k=1,mxptvs
          limvoi(k,1) = 0
          limvoi(k,2) = 0
        ENDDO
!       POINT 1 IS THE BEGINNING OF SERIES WITH T1(1) NEIGHBOURS
        nbvois = t1(1)
        limvoi(nbvois,1) = 1
        DO i=2,npoin
          IF(t1(i).NE.nbvois) THEN
!         PREVIOUS POINT WAS AN END OF A SERIES
          limvoi(nbvois,2) = i-1
!         CURRENT POINT IS THE BEGINNING OF A SERIES
          nbvois = t1(i)
          limvoi(nbvois,1) = i
          ENDIF
        ENDDO
!       POINT NPOIN IS THE END OF ITS SERIES
        limvoi(nbvois,2) = npoin
!
!   ARRAYS FOR FRONTAL MATRIX-VECTOR PRODUCT :
!
        DO ipoin = 1,npoin
          t1(ipoin) = 1
        ENDDO
!
        IF(optass.EQ.3) THEN
!
!       IY DOES NOT DEPEND HERE ON THE DIRECT OR TRANSPOSE CHARACTER
        DO isg = 1,nseg
          i1 = gloseg(isg,1)
          i2 = gloseg(isg,2)
!
!         ANY MATRIX
!         IXM IN DIRECT PRODUCT
          iklem1(i1,t1(i1),1,1) = isg
          iklem1(i2,t1(i2),1,1) = isg + nseg
!         IY IN DIRECT PRODUCT
          iklem1(i1,t1(i1),2,1) = i2
          iklem1(i2,t1(i2),2,1) = i1
!         IXM IN TRANSPOSE PRODUCT
          iklem1(i1,t1(i1),3,1) = isg + nseg
          iklem1(i2,t1(i2),3,1) = isg
!         IY IN TRANSPOSE PRODUCT
          iklem1(i1,t1(i1),4,1) = i2
          iklem1(i2,t1(i2),4,1) = i1
!
!         SYMMETRICAL MATRIX
!         IXM IN DIRECT PRODUCT
          iklem1(i1,t1(i1),1,2) = isg
          iklem1(i2,t1(i2),1,2) = isg
!         IY IN DIRECT PRODUCT
          iklem1(i1,t1(i1),2,2) = i2
          iklem1(i2,t1(i2),2,2) = i1
!         IXM IN TRANSPOSE PRODUCT
          iklem1(i1,t1(i1),3,2) = isg
          iklem1(i2,t1(i2),3,2) = isg
!         IY IN TRANSPOSE PRODUCT
          iklem1(i1,t1(i1),4,2) = i2
          iklem1(i2,t1(i2),4,2) = i1
!
!         UPDATES THE NUMBER OF NEIGHBOURS
          t1(i1) = t1(i1) + 1
          t1(i2) = t1(i2) + 1
        ENDDO
!
        ELSE
          WRITE(lu,*) 'UNKNOWN STORAGE IN FROPRO :',optass
          CALL plante(1)
          stop
        ENDIF
!
      ENDIF
!
!-----------------------------------------------------------------------
!
      RETURN
      END