friction_khione.f

Go to the documentation of this file.

!                   **************************
                    SUBROUTINE friction_khione
!                   **************************
!
     &( npoin, kfrot, grav,karman, chestr, cf, h,u,v )
!
!***********************************************************************
! TELEMAC2D   V7P3
!***********************************************************************
!
!brief    Sets the friction coefficient under the ice cover.
!
!code
!+     FRICTION LAWS PROGRAMMED :
!+
!+     KFROT = 0 :  NO FRICTION
!+     KFROT = 1 :  LAW OF HAALAND
!+     KFROT = 2 :  LAW OF CHEZY
!+     KFROT = 3 :  LAW OF STRICKLER
!+     KFROT = 4 :  LAW OF MANNING
!+     KFROT = 5 :  LAW OF NIKURADSE
!
!~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~
!| CF             |<--| ADIMENSIONAL FRICTION COEFFICIENT
!| CHESTR         |-->| FRICTION PARAMETER
!| GRAV           |-->| GRAVITY ACCELERATION
!| H              |-->| WATER DEPTH
!| KARMAN         |-->| VON KARMAN'S CONSTANT
!| KFROT          |-->| LAW USED FOR THE CALCULATION
!| NPOIN          |-->| NUMBER OF NODES
!| U              |-->| X COMPONENT OF THE VELOCITY
!| V              |-->| Y COMPONENT OF THE VELOCITY
!~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~
!
      USE bief
!
      USE declarations_special
      IMPLICIT NONE
!
!+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+
!
      INTEGER,          INTENT(IN)    :: NPOIN, KFROT
      DOUBLE PRECISION, INTENT(IN)    :: GRAV, KARMAN
      TYPE(bief_obj),   INTENT(IN)    :: CHESTR,H,U,V
      TYPE(bief_obj),   INTENT(INOUT) :: CF
!
!+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+
!
      INTEGER                       :: I
      DOUBLE PRECISION, PARAMETER   :: TIERS = 1.d0/3.d0
      DOUBLE PRECISION, PARAMETER   :: SUR30 = 1.d0/30.d0
      DOUBLE PRECISION              :: UNORM, INLOG, AUX
      DOUBLE PRECISION, PARAMETER   :: EPS=1.d-3
!
!=======================================================================!
!=======================================================================!
!                               PROGRAMME                               !
!=======================================================================!
!=======================================================================!
!
      SELECT CASE (kfrot)
!
! NO FRICTION
! -----------
!
      CASE(0)
!
        DO i = 1,npoin
          cf%R(i) = 0.d0
        ENDDO
!
! LAW OF HAALAND
! --------------
!
      CASE(1)
!
        DO i = 1,npoin
          unorm = max(sqrt( u%R(i)**2 + v%R(i)**2 ),1.d-6)
!                       1.D-6: LAMINAR VISCOSITY OF WATER
          inlog = (6.9d0*1.d-6/4.d0  /max(h%R(i),eps)/unorm)**3
     &          + (chestr%R(i)/14.8d0/max(h%R(i),eps))**3.33d0
          inlog = min(1.d0-1.d-6,inlog)
          aux   = -0.6d0*log(inlog)/log(10.d0)
          cf%R(i) = 0.25d0 / aux**2
        ENDDO
!
! LAW OF CHEZY
! ------------
!
      CASE(2)
!
        DO i = 1,npoin
          cf%R(i) = 2.d0*grav/(chestr%R(i)**2)
        ENDDO
!
! LAW OF STRICKLER
! ----------------
!
      CASE(3)
!
        DO i = 1,npoin
          cf%R(i) = 2.d0*grav/chestr%R(i)**2/max(h%R(i),eps)**tiers
        ENDDO
!
! LAW OF MANNING
! --------------
!
      CASE(4)
!
        DO i = 1,npoin
          cf%R(i) = 2.d0*grav*(chestr%R(i)**2)/max(h%R(i),eps)**tiers
        ENDDO
!
! LAW OF NIKURADSE
! ----------------
!
      CASE(5)
!
!       NOTE: 11.036 IS 30.D0/EXP(1.D0)
        DO i = 1,npoin
          aux=max(1.001d0,max(h%R(i),eps)*11.036d0/chestr%R(i))
          cf%R(i) = 2.d0 / (log(aux)/karman)**2
        ENDDO
!
! OTHER CASES
! -----------
!
      CASE DEFAULT
!
        WRITE(lu,2) kfrot
2       FORMAT(i5,' : UNKNOWN UNDER ICE COVER FRICTION LAW')
        CALL plante(1)
        stop
!
      END SELECT
!
!=======================================================================!
!=======================================================================!
!
      RETURN
      END SUBROUTINE friction_khione