frepic.f

Go to the documentation of this file.

!                   *****************
                    SUBROUTINE frepic
!                   *****************
!
     &( fpic, f, nf, ndire, npoin2 )
!
!***********************************************************************
! TOMAWAC   V6P1                                   15/06/2011
!***********************************************************************
!
!brief    COMPUTES THE PEAK FREQUENCY FOR ALL THE NODES IN THE
!+                2D MESH. THIS PEAK FREQUENCY IS DEFINED AS THE
!+                DISCRETISED FREQUENCY FOR WHICH E(F) IS GREATEST.
!~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~
!| E              |<->| WORK TABLE
!| EMAX           |<->| WORK TABLE
!| F              |-->| VARIANCE DENSITY DIRECTIONAL SPECTRUM
!| FPIC           |<--| PEAK FREQUENCIES
!| NF             |-->| NUMBER OF FREQUENCIES
!| NDIRE          |-->| NUMBER OF DIRECTIONS
!| NPOIN2         |-->| NUMBER OF POINTS IN 2D MESH
!~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~
!
      USE interface_tomawac, ex_frepic => frepic
      USE declarations_tomawac, ONLY : freq
      IMPLICIT NONE
!
!.....VARIABLES IN ARGUMENT
!     """"""""""""""""""""
      INTEGER,INTENT(IN)             :: NF    , NDIRE , NPOIN2
      DOUBLE PRECISION,INTENT(IN)    :: F(npoin2,ndire,nf)
      DOUBLE PRECISION,INTENT(INOUT) :: FPIC(npoin2)
!
!.....LOCAL VARIABLES
!     """""""""""""""""
      INTEGER  JP    , JF    , IP
      DOUBLE PRECISION E, EMAX
!
      DO ip = 1,npoin2
        fpic(ip) = 1.d-20
        emax = 0.d0
!
!.....LOOP OVER DISCRETISED FREQUENCIES
!     """""""""""""""""""""""""""""""""""""""""""""
        DO jf = 1,nf
!
!.......INTEGRATES WRT DIRECTIONS TO GET E(F)
!       """""""""""""""""""""""""""""""""""""""""""""""""
          e = 0.d0
          DO jp = 1, ndire
            e = e + f(ip,jp,jf)
          ENDDO                ! JP
!
!.......KEEPS THE MAXIMUM VALUE FOR E(F) AND ASSOCIATED FREQUENCY
!       """""""""""""""""""""""""""""""""""""""""""""""""""""
          IF (e.GT.emax) THEN
            emax = e
            fpic(ip) = freq(jf)
          ENDIF
        ENDDO                   ! JF
      ENDDO                     ! IP
!
!
      RETURN
      END