fluxpr.f

Go to the documentation of this file.

!                   *****************
                    SUBROUTINE fluxpr
!                   *****************
!
     &(nsec,ctrlsc,flx,volneg,volpos,info,tps,nseg,ncsize,cumflo)
!
!***********************************************************************
! BIEF   V6P1                                   21/08/2010
!***********************************************************************
!
!brief    COMPUTES FLUXES THROUGH CONTROL SECTIONS
!+                AND SUMS THEM UP TO OBTAIN OSCILLATING VOLUMES.
!
!note     PRINTOUTS OF DISCHARGES THROUGH CONTROL SECTIONS ARE DONE
!+            IN THIS ROUTINE. YOU CAN REWRITE IT TO DIVERT THESE
!+            PRINTOUTS TO A FILE OR TO CHANGE THE FORMAT
!
!history  J-M HERVOUET (LNH)
!+        25/03/99
!+        V5P5
!+
!
!history  N.DURAND (HRW), S.E.BOURBAN (HRW)
!+        13/07/2010
!+        V6P0
!+   Translation of French comments within the FORTRAN sources into
!+   English comments
!
!history  N.DURAND (HRW), S.E.BOURBAN (HRW)
!+        21/08/2010
!+        V6P0
!+   Creation of DOXYGEN tags for automated documentation and
!+   cross-referencing of the FORTRAN sources
!
!history  J,RIEHME (ADJOINTWARE)
!+        November 2016
!+        V7P2
!+   Replaced EXTERNAL statements to parallel functions / subroutines
!+   by the INTERFACE_PARALLEL
!
!~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~
!| CTRLSC         |-->| NUMBERS OF POINTS IN THE CONTROL SECTIONS
!| CUMFLO         |-->| KEY-WORD: PRINTING CUMULATED FLOWRATES
!| FLX            |-->| FLUXES THROUGH CONTROL SECTIONS
!| INFO           |-->| IF YES : INFORMATION IS PRINTED
!| NCSIZE         |-->| NUMBER OF PROCESSORS
!| NSEC           |-->| NUMBER OF CONTROL SECTIONS
!| NSEG           |-->| NUMBER OF SEGMENTS
!| TPS            |-->| TIME
!| VOLNEG         |-->| CUMULATED NEGATIVE VOLUME THROUGH SECTIONS
!| VOLPOS         |-->| CUMULATED POSITIVE VOLUME THROUGH SECTIONS
!~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~
!
      USE declarations_special
      USE interface_parallel, ONLY : p_max,p_min
      IMPLICIT NONE
!
!+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+
!
      INTEGER, INTENT(IN)          :: NSEC,NCSIZE
      INTEGER, INTENT(IN)          :: CTRLSC(*)
      INTEGER, INTENT(IN)          :: NSEG(nsec)
      LOGICAL, INTENT(IN)          :: INFO,CUMFLO
      DOUBLE PRECISION, INTENT(IN) :: FLX(nsec),TPS
      DOUBLE PRECISION, INTENT(IN) :: VOLNEG(nsec),VOLPOS(nsec)
!
!+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+
!
      INTEGER ISEC,II
!
!-----------------------------------------------------------------------
!
      IF(.NOT.info) THEN
        RETURN
      ENDIF
!
      IF(ncsize.LE.1) THEN
!
        DO isec = 1,nsec
!
          IF(cumflo) THEN
            WRITE(lu,131) isec,ctrlsc(1+2*(isec-1)),
     &                    ctrlsc(2+2*(isec-1)),
     &                    flx(isec),
     &                    volneg(isec),
     &                    volpos(isec)
          ELSE
            WRITE(lu,137) isec,ctrlsc(1+2*(isec-1)),
     &                    ctrlsc(2+2*(isec-1)),
     &                    flx(isec)
          ENDIF
!
        ENDDO
!
      ELSE
!
        DO isec = 1,nsec
!         SECTIONS ACROSS 2 SUB-DOMAINS WILL HAVE NSEG=0 OR -1
!         AND -1 WANTED HERE FOR RELEVANT MESSAGE
          ii=p_min(nseg(isec))
!
          IF(ii.GE.0) THEN
!
            WRITE(lu,133) isec,ctrlsc(1+2*(isec-1)),
     &                    ctrlsc(2+2*(isec-1)),
     &                    p_min(flx(isec))+p_max(flx(isec)),
     &                    p_min(volneg(isec)),
     &                    p_max(volpos(isec))
!
          ELSE
!
            WRITE(lu,135) isec,ctrlsc(1+2*(isec-1)),
     &                    ctrlsc(2+2*(isec-1))
          ENDIF
!
        ENDDO
!
      ENDIF
!
131   FORMAT(1x,/,1x,'CONTROL SECTION NUMBER ',1i2,
     &               ' (BETWEEN POINTS ',1i5,' AND ',1i5,')',//,5x,
     &               'DISCHARGE: '                 ,g16.7,/,5x,
     &               'NEGATIVE VOLUME THROUGH THE SECTION: ',g16.7,/,
     &               5x,
     &               'POSITIVE VOLUME THROUGH THE SECTION: ',g16.7)
137   FORMAT(1x,/,1x,'CONTROL SECTION NUMBER ',1i2,
     &               ' (BETWEEN POINTS ',1i5,' AND ',1i5,')',//,5x,
     &               'DISCHARGE: '                 ,g16.7)
135   FORMAT(1x,/,1x,'CONTROL SECTION NUMBER ',1i2,
     &               ' (BETWEEN POINTS ',1i5,' AND ',1i5,')',//,5x,
     &               'ACROSS TWO SUB-DOMAINS, NO COMPUTATION')
133   FORMAT(1x,/,1x,'CONTROL SECTION NUMBER ',1i2,
     &               ' (BETWEEN POINTS ',1i5,' AND ',1i5,')',//,5x,
     &               'DISCHARGE: '                 ,g16.7,/,5x,
     &               'NEGATIVE VOLUME THROUGH THE SECTION: ',g16.7,/,5x,
     &               'POSITIVE VOLUME THROUGH THE SECTION: ',g16.7)
!
!-----------------------------------------------------------------------
!
      RETURN
      END