flux3dlim.f

Go to the documentation of this file.

!                   ********************
                    SUBROUTINE flux3dlim
!                   ********************
!
     &(flow,flulim,nplan,nseg2d,npoin2,opt)
!
!***********************************************************************
! BIEF   V6P3                                   21/08/2010
!***********************************************************************
!
!brief    LIMITS 3D HORIZONTAL EDGE BY EDGE FLUXES ON POINTS.
!
!history  J-M HERVOUET (LNHE)
!+        19/05/09
!+        V6P0
!+
!
!history  N.DURAND (HRW), S.E.BOURBAN (HRW)
!+        13/07/2010
!+        V6P0
!+   Translation of French comments within the FORTRAN sources into
!+   English comments
!
!history  N.DURAND (HRW), S.E.BOURBAN (HRW)
!+        21/08/2010
!+        V6P0
!+   Creation of DOXYGEN tags for automated documentation and
!+   cross-referencing of the FORTRAN sources
!
!history  J-M HERVOUET (LNHE)
!+        06/09/2012
!+        V6P2
!+   Option OPT added for crossed segments. Argument NPOIN2 added.
!+   Prisms and prisms cut into tetrahedra now treated.
!
!~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~
!| FLOW           |-->| FLUXES (SIZE OF FLOW MAY NOT EXCEED
!|                |   | NSEG2D*NPLAN, THOUGH THE TOTAL NUMBER OF
!|                |   | SEGMENTS IS LARGER)
!| FLULIM         |-->| LIMITING FACTOR OF 2D SEGMENTS
!| NPLAN          |-->| NUMBER OF PLANES
!| NPOIN2         |-->| NUMBER OF POINTS IN 2D
!| NSEG2D         |-->| NUMBER OF SEGMENTS IN 2D
!| OPT            |-->| 1: HORIZONTAL SEGMENTS
!|                |   | 2: HORIZONTAL AND CROSSED SEGMENTS FOR PRISMS
!|                |   | 3: HORIZONTAL AND CROSSED SEGMENTS FOR PRISMS
!|                |   |    CUT INTO TETRAHEDRA
!~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~
!
      USE bief
!
      USE declarations_special
      IMPLICIT NONE
!
!+++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++
!
      INTEGER, INTENT(IN)             :: NSEG2D,NPLAN,OPT,NPOIN2
      DOUBLE PRECISION, INTENT(INOUT) :: FLOW(*)
!                                        HERE * = NESG2D*NPLAN
      DOUBLE PRECISION, INTENT(IN)    :: FLULIM(nseg2d)
!
!+++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++
!
      INTEGER ISEG,ISEG3D,IPLAN,OTHERS
!
!-----------------------------------------------------------------------
!
!     LIMITS 3D FLUXES BY COEFFICIENT OF 2D FLUXES
!
!-----------------------------------------------------------------------
!
!     HORIZONTAL SEGMENTS
!
      DO iplan=1,nplan
        DO iseg=1,nseg2d
          iseg3d=iseg+(iplan-1)*nseg2d
          flow(iseg3d)=flow(iseg3d)*flulim(iseg)
        ENDDO
      ENDDO
!
!     OPTIONALLY: CROSSED SEGMENTS
!
      IF(opt.EQ.2) THEN
!
!       FOR PRISMS
!
        others=nplan*nseg2d+npoin2*(nplan-1)
        DO iplan=1,nplan-1
          DO iseg=1,nseg2d
            iseg3d=iseg+(iplan-1)*2*nseg2d+others
            flow(iseg3d)=flow(iseg3d)*flulim(iseg)
            iseg3d=iseg3d+nseg2d
            flow(iseg3d)=flow(iseg3d)*flulim(iseg)
          ENDDO
        ENDDO
!
      ELSEIF(opt.EQ.3) THEN
!
!       FOR PRISMS CUT INTO TETRAHEDRA
!
        others=nplan*nseg2d+npoin2*(nplan-1)
        DO iplan=1,nplan-1
          DO iseg=1,nseg2d
            iseg3d=iseg+(iplan-1)*nseg2d+others
            flow(iseg3d)=flow(iseg3d)*flulim(iseg)
          ENDDO
        ENDDO
!
      ELSEIF(opt.NE.1) THEN
!
        WRITE(lu,*) 'FLUX3DLIM : UNEXPECTED OPT:',opt
        CALL plante(1)
        stop
!
      ENDIF
!
!-----------------------------------------------------------------------
!
      RETURN
      END