filter.f

Go to the documentation of this file.

!                   *****************
                    SUBROUTINE filter
!                   *****************
!
     &(vec,bldmat,t1,t2,
     & a,formul,
     & xmul,f,g,h,u,v,w,
     & mesh,msk,maskel,n)
!
!***********************************************************************
! BIEF   V6P1                                   21/08/2010
!***********************************************************************
!
!brief    FILTERS A VECTOR USING A MATRIX.
!+
!+            FOR EXAMPLE, THE USE OF A MASS MATRIX YIELDS
!+                SMOOTHING.
!
!note     IF BLDMAT=.FALSE. MATRIX A IS GIVEN, IT IS NOT RE-BUILT.
!
!history  J-M HERVOUET (LNH)
!+        24/04/97
!+        V5P1
!+
!
!history  N.DURAND (HRW), S.E.BOURBAN (HRW)
!+        13/07/2010
!+        V6P0
!+   Translation of French comments within the FORTRAN sources into
!+   English comments
!
!history  N.DURAND (HRW), S.E.BOURBAN (HRW)
!+        21/08/2010
!+        V6P0
!+   Creation of DOXYGEN tags for automated documentation and
!+   cross-referencing of the FORTRAN sources
!
!~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~
!| A              |<->| MATRIX (GIVEN OR BUILT DEPENDING ON BLDMAT)
!| BLDMAT         |-->| IF YES : MATRIX BUILT ACCORDING TO FORMUL
!| F,G,H,U,V,W    |-->| FUNCTIONS THAT MAY BE USED FOR BUILDING A
!| FORMUL         |-->| FORMULA DESCRIBING THE MATRIX (AS IN MATRIX)
!| MSK            |-->| IF YES, THERE IS MASKED ELEMENTS.
!| MASKEL         |-->| MASKING OF ELEMENTS
!|                |   | =1. : NORMAL   =0. : MASKED ELEMENT
!| N              |-->| FILTERING WILL BE DONE N TIMES
!| T1             |<->| WORK ARRAY
!| T2             |<->| WORK ARRAY. MATRIX A LUMPED AT THE END
!| VEC            |<->| VECTOR TO BE FILTERED
!| XMUL           |-->| MULTIPLICATION FACTOR
!|                |   | NO INFLUENCE EXCEPT ON T2.
!~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~
!
      USE bief, ex_filter => filter
!
      USE declarations_special
      IMPLICIT NONE
!
!+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+
!
      INTEGER, INTENT(IN)           :: N
      DOUBLE PRECISION, INTENT(IN)  :: XMUL
      LOGICAL, INTENT(IN)           :: BLDMAT,MSK
      CHARACTER(LEN=16), INTENT(IN) :: FORMUL
      TYPE(bief_mesh), INTENT(INOUT):: MESH
      TYPE(bief_obj), INTENT(INOUT) :: VEC,A,T1,T2
      TYPE(bief_obj), INTENT(IN)    :: F,G,H,U,V,W,MASKEL
!
!+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+
!
      INTEGER I
!
      DOUBLE PRECISION C
!
!-----------------------------------------------------------------------
!
      DO i=1,n
!
!  COMPUTES THE MATRIX ACCORDING TO THE GIVEN FORMULATION (OPTIONAL)
!
      IF(bldmat.AND.i.EQ.1) THEN
!
          CALL matrix(a,'M=N     ',formul,vec%ELM,vec%ELM,
     &                xmul,f,g,h,u,v,w,mesh,msk,maskel)
!
      ENDIF
!
!-----------------------------------------------------------------------
!
!  COMPUTES THE PRODUCT A * VEC (WITH ASSEMBLY)
!
      CALL matvec( 'X=AY    ',t1,a,vec,c,mesh)
      IF(ncsize.GT.1) CALL parcom(t1,2,mesh)
!
!-----------------------------------------------------------------------
!
!  COMPRESSES A ON ITS DIAGONAL
!
      IF(i.EQ.1) THEN
        CALL lump(t2,a,mesh,xmul)
        IF(ncsize.GT.1) CALL parcom(t2,2,mesh)
        CALL os('X=1/Y   ',x=t2,y=t2,iopt=2,infini=0.d0,zero=1.d-20)
      ENDIF
!
!-----------------------------------------------------------------------
!
!  COMPUTES F = A * F / (ASSEMBLED A)
!
!  CHECKS DIVISIONS BY 0 CAUSED BY EXTERNAL POINTS IN
!  THE LEONARD FORMAT, WHICH CAN HAVE 0 VALUES
!
      CALL os('X=YZ    ',x=vec,y=t1,z=t2)
!
!-----------------------------------------------------------------------
!
      ENDDO ! I
!
!-----------------------------------------------------------------------
!
      RETURN
      END