example_cpl_t2d_sis.f

Go to the documentation of this file.

      SUBROUTINE example_cpl_t2d_sis()
      USE api_interface, ex_lu => lu
      USE api_instance_sis
      USE api_instance_t2d
      USE declarations_partel, ONLY : code
      USE declarations_special, ONLY : path_len
!
#if defined HAVE_MPI
!
#  if defined HAVE_MPI_MOD
        USE mpi
        IMPLICIT NONE
#  else
        IMPLICIT NONE
        include 'mpif.h'
#  endif
#endif
        INTEGER ::  I, IERR, ID_SIS, ID_T2D, IDUM, IDUM1
        INTEGER :: CPL_PERIOD
        INTEGER :: NTIME_STEPS_T2D
        CHARACTER(LEN=PATH_LEN) :: GEO_FILE,PRE_FILE
        CHARACTER(LEN=PATH_LEN) :: REF_FILE_T2D, REF_FILE_SIS
        CHARACTER(LEN=PATH_LEN) :: CLI_FILE_T2D, CLI_FILE_SIS
        CHARACTER(LEN=PATH_LEN) :: RES_FILE_T2D, RES_FILE_SIS
        CHARACTER(LEN=PATH_LEN) :: CAS_FILE_T2D, DICO_FILE_T2D
        CHARACTER(LEN=PATH_LEN) :: CAS_FILE_SIS, DICO_FILE_SIS
        CHARACTER(LEN=PATH_LEN) :: DUMMY
        CHARACTER(LEN=SIS_VAR_LEN) :: VARNAME
        INTEGER LU,LNG,NPLAN,PARALLEL,REFFILE,PREFILE
        INTEGER RANK,NCSIZE,PMETHOD,VAR_SIZE,COMM
        dummy = ' '
        comm = 0

!     OUTPUT FOR WRITING
        lu=6
        ! 1 FOR FRENCH 2 FOR ENGLISH
        lng=2
        id_sis = 0
        id_t2d = 0
        !READING THE FILES NAMES
        OPEN(unit=12,file='param_api')
        READ(12,'(A)') dico_file_t2d
        READ(12,'(A)') dico_file_sis
        READ(12,*) cas_file_t2d
        READ(12,*) cas_file_sis
        READ(12,*) cpl_period
        READ(12,*) res_file_t2d
        READ(12,*) res_file_sis
        READ(12,*) geo_file
        READ(12,*) cli_file_t2d
        READ(12,*) cli_file_sis
        READ(12,*) reffile
        IF (reffile.EQ.1) THEN
          READ(12,*) ref_file_t2d
          READ(12,*) ref_file_sis
        ELSE
          READ(12,*)
          READ(12,*)
        ENDIF
        READ(12,*) prefile
        IF (prefile.EQ.1) THEN
          READ(12,*) pre_file
        ELSE
          READ(12,*)
        ENDIF
        READ(12,*) parallel
        CLOSE(12)

        print*, "DICO T2D : ",dico_file_t2d
        print*, "DICO SIS : ",dico_file_sis
        print*, "CAS  T2D : ",cas_file_t2d
        print*, "CAS  SIS : ",cas_file_sis
        print*, "COUPLING PERIOD  : ", cpl_period
        print*, "RES  T2D : ",res_file_t2d
        print*, "RES  SIS : ",res_file_sis
        print*, "GEO  : ",geo_file
        print*, "CLI  T2D : ",cli_file_t2d
        print*, "CLI  SIS : ",cli_file_sis
        IF(reffile.EQ.1) print*,"REFERENCE FILES PRESENT : ",
     &                           ref_file_t2d, ref_file_sis
        IF(prefile.EQ.1) print*,"PREVIOUS CALCULATIONS FILE PRESENT : ",
     &                                                         pre_file
        IF(parallel.EQ.0) print*,"MPI : SEQUENTIAL RUN"
        IF(parallel.EQ.1) print*,"MPI : PARALLEL RUN"
        print*
!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!
        IF(parallel.EQ.1) THEN
          ! Partitioning method to use 1: metis
          pmethod=1
#if defined HAVE_MPI
          ! Initialising mpi
!! COMPAD-DCO-MPICHECK  BEGIN  JR2016
#  if defined COMPAD
          WRITE(lu,*) '(AD) COMPAD :: HOMERE_API.F : DIRECT CALL OF ',
     &         'MPI_INIT NOT AD-READY'
          WRITE(lu,*) '  PLEASE CONTACT JR @ ADJOINTWARE'
          CALL plante(1)
          stop
#  endif
!! COMPAD-DCO-MPICHECK  END  JR2016
          CALL mpi_init(ierr)
          ! Getting rank
          CALL mpi_comm_rank(mpi_comm_world,rank,ierr)
          ! Getting the number of process
          CALL mpi_comm_size(mpi_comm_world,ncsize,ierr)
          comm = mpi_comm_world
#else
        rank = -1
#endif
!
          code = 'SIS'
          ! The partitioning is done sequentially
          IF(rank.EQ.0) THEN
            ! PARITIONING THE GEOMETRY FILE
            CALL partel(geo_file,cli_file_sis,ncsize,pmethod,
     &                  'SERAFIN ',' ',' ')
            IF(reffile.EQ.1)   CALL parres(geo_file,ref_file_sis,
     &                  ncsize,'SERAFIN ','SERAFIN ')
          ENDIF
          code = 'T2D'
          ! The partitioning is done sequentially
          IF(rank.EQ.0) THEN
            ! PARITIONING THE GEOMETRY FILE
            CALL partel(geo_file,cli_file_t2d,ncsize,pmethod,
     &                  'SERAFIN ',' ',' ')
            IF(reffile.EQ.1)   CALL parres(geo_file,ref_file_t2d,
     &                  ncsize,'SERAFIN ','SERAFIN ')
            IF(prefile.EQ.1)   CALL parres(geo_file,pre_file,
     &                  ncsize,'SERAFIN ','SERAFIN ')
          ENDIF
        ENDIF
!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!
!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!
!!!!!!!!!!!!!!!!!!!!!!!!!!!!TELEMAC 2D!!!!!!!!!!!!!!!!!!!!!!!!!!!!!
        CALL run_set_config_t2d(id_t2d,lu,lng,comm,ierr)

        CALL run_read_case_t2d(id_t2d,cas_file_t2d,dico_file_t2d,
     &                         .true.,ierr,dummy,dummy)

        ! Changing the name of the result file
        varname = 'MODEL.RESULTFILE'
        CALL get_var_size(id_t2d,'T2D',varname,var_size,
     &                        idum,idum1,ierr)
        print *, 'rank:',rank,'VAR_SIZE:',var_size
        CALL set_string(id_t2d,'T2D',varname,res_file_t2d,var_size,
     &                      0,0,ierr)

        CALL run_allocation_t2d(id_t2d,ierr)
!
!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!
!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!
!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!SISYPHE!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!
        CALL run_set_config_sis(id_sis,lu,lng,comm,ierr)

        CALL run_read_case_sis(id_sis,'TELEMAC2D               ',
     &                         cas_file_sis,dico_file_sis,
     &                         .false.,ierr)

        ! Changing the name of the result file
        varname = 'MODEL.RESULTFILE'
        CALL get_var_size(id_sis,'SIS',varname,var_size,idum,idum1,ierr)
        print *, 'rank:',rank,'VAR_SIZE:',var_size
        CALL set_string(id_sis,'SIS',varname,res_file_sis,var_size,
     &                      0,0,ierr)

        CALL run_allocation_sis(id_sis,ierr)
!
!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!
!!!!!!!!!!!!!!!!!!!!!!!!!!!!!TIME LOOP!!!!!!!!!!!!!!!!!!!!!!!!!!!!!
!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!
        CALL run_init_t2d(id_t2d,ierr)
        varname = 'MODEL.CPL_PERIOD'
        CALL set_integer(id_t2d, 'T2D', varname, cpl_period,
     &                       0, 0, 0, ierr)
        CALL cpl_init(id_t2d,ierr)
        CALL set_var_sis(id_t2d, id_sis, 0, ierr)
        CALL run_init_sis(id_sis,ierr)
        CALL set_var_t2d(id_t2d, id_sis, ierr)
        CALL save_charr_susp(id_t2d, id_sis, ierr)

        !Get the number of timesteps
        varname = 'MODEL.NTIMESTEPS'
        CALL get_integer(id_t2d, 'T2D', varname, ntime_steps_t2d,
     &                       0, 0, 0, ierr)

        !Get the coupling period
        varname = 'MODEL.CPL_PERIOD'
        CALL get_integer(id_t2d,'T2D',varname,cpl_period, 0, 0, 0, ierr)

        DO i=1,ntime_steps_t2d
          CALL run_timestep_compute_t2d(id_t2d,ierr)
          !COUPLAGE
          IF(cpl_period*(i/cpl_period).EQ.i) THEN
            CALL run_timestep_sis_cpl(id_t2d, id_sis, ierr)
          ENDIF
          CALL run_timestep_res_t2d(id_t2d,ierr)
        ENDDO
!


!!!!!!!!!!!!!!!!!!!!!!!!!!!FINALISATION!!!!!!!!!!!!!!!!!!!!!!!!!!!!
        CALL run_finalize_t2d(id_t2d,ierr)
        CALL run_finalize_sis(id_sis,ierr)
!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!
        IF(parallel.EQ.1) THEN
!         Mergin step
          IF(rank.EQ.0) THEN
            CALL gretel_autop(geo_file,'SERAFIN ',res_file_t2d,
     &                        'SERAFIN ', ncsize,nplan)
            CALL gretel_autop(geo_file,'SERAFIN ',res_file_sis,
     &                        'SERAFIN ', ncsize,nplan)

          ENDIF
#if defined HAVE_MPI
#  if defined COMPAD
          WRITE(lu,*) '(AD) COMPAD :: HOMERE_API.F : DIRECT CALL OF ',
     &         'MPI_FINALIZE NOT AD-READY'
          WRITE(lu,*) '  PLEASE CONTACT JR @ ADJOINTWARE'
          CALL plante(1)
          stop
#  endif
          CALL mpi_finalize(ierr)
#endif
        ENDIF
!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!
        END SUBROUTINE example_cpl_t2d_sis