entete_sisyphe.f

Go to the documentation of this file.

!                   *************************
                    SUBROUTINE entete_sisyphe
!                   *************************
!
     &(ietape,at,lt)
!
!***********************************************************************
! SISYPHE   V6P1                                   21/07/2011
!***********************************************************************
!
!brief    WRITES HEADINGS TO THE LISTING
!+                AT VARIOUS STAGES OF THE PROGRAM.
!
!history  J-M HERVOUET (LNHE)
!+        06/06/2008
!+        V5P9
!+
!
!history  N.DURAND (HRW), S.E.BOURBAN (HRW)
!+        13/07/2010
!+        V6P0
!+   Translation of French comments within the FORTRAN sources into
!+   English comments
!
!history  N.DURAND (HRW), S.E.BOURBAN (HRW)
!+        21/08/2010
!+        V6P0
!+   Creation of DOXYGEN tags for automated documentation and
!+   cross-referencing of the FORTRAN sources
!
!~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~
!| IETAPE         |-->| SHOW COMPUTATION STEPS
!~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~
!
      USE declarations_special
      IMPLICIT NONE
!
!+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+
!
      DOUBLE PRECISION, INTENT(IN) :: AT
!
      INTEGER, INTENT(IN):: LT,IETAPE
!
!+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+
!
      INTEGER J,H,M
      DOUBLE PRECISION S
      INTRINSIC int
      CHARACTER(LEN=32) :: FR(15),GB(15)
!
!-----------------------------------------------------------------------
!
!     AD: NO DATA STATEMENT FOR TYPES WITH ALLOCATABLE COMPONENTS
      parameter( fr = (/
     &     '                                ' ,
     &     '                                ' ,
     &     '     ETAPE DE CONVECTION        ' ,
     &     '       MODELE K-EPSILON         ' ,
     &     '  ETAPE DE DIFFUSION DU TRACEUR ' ,
     &     ' ETAPE DE DIFFUSION-PROPAGATION ' ,
     &     '      BILAN DE VOLUME D''EAU     ' ,
     &     ' BILAN FINAL DE VOLUME D''EAU    ' ,
     &     '  TEMPS :                       ' ,
     &     ' SECONDES                       ' ,
     &     'ITERATION                       ' ,
     &     '     DERIVE DE FLOTTEUR(S)      ' ,
     &     '   DERIVE(S) LAGRANGIENNE(S)    ' ,
     &     '     GLISSEMENT DU SEDIMENT     ' ,
     &     '      TASSEMENT DU SEDIMENT     '  /) )
      parameter( gb = (/
     &     '                                ' ,
     &     '                                ' ,
     &     '        ADVECTION STEP          ' ,
     &     '        K-EPSILON MODEL         ' ,
     &     '   DIFFUSION OF TRACER STEP     ' ,
     &     '  DIFFUSION-PROPAGATION STEP    ' ,
     &     '     BALANCE OF WATER VOLUME    ' ,
     &     ' FINAL BALANCE OF WATER VOLUME  ' ,
     &     '    TIME:                       ' ,
     &     ' SECONDS                        ' ,
     &     'ITERATION                       ' ,
     &     '       DRIFT OF DROGUE(S)       ' ,
     &     '      LAGRANGIAN DRIFT(S)       ' ,
     &     '         SEDIMENT SLIDE         ' ,
     &     '          CONSOLIDATION         '  /) )
!
!-----------------------------------------------------------------------
!
!  DECOMPOSITION OF TIME IN DAYS, HOURS, MINUTES AND SECONDS
!
      s = at
      j = int(at/86400.d0)
      s = s - 86400.d0 * j
      h = int(s/3600.d0)
      s = s - 3600.d0 * h
      m = int(s/60.d0)
      s = s - 60.d0 * m
!
!-----------------------------------------------------------------------
!
!   WRITES OUT: TIME AND ITERATIONS
!
      IF (ietape.EQ.1.OR.ietape.EQ.2) THEN
!
        IF(j.NE.0) THEN
          IF(lng.EQ.lng_fr) WRITE(lu,10) fr(11),lt,fr(9),j,h,m,s,at
          IF(lng.EQ.lng_en) WRITE(lu,11) gb(11),lt,gb(9),j,h,m,s,at
        ELSEIF(h.NE.0) THEN
          IF(lng.EQ.lng_fr) WRITE(lu,20) fr(11),lt,fr(9),h,m,s,at
          IF(lng.EQ.lng_en) WRITE(lu,20) gb(11),lt,gb(9),h,m,s,at
        ELSEIF(m.NE.0) THEN
          IF(lng.EQ.lng_fr) WRITE(lu,30) fr(11),lt,fr(9),m,s,at
          IF(lng.EQ.lng_en) WRITE(lu,30) gb(11),lt,gb(9),m,s,at
        ELSE
          IF(lng.EQ.lng_fr) WRITE(lu,40) fr(11),lt,fr(9),s
          IF(lng.EQ.lng_en) WRITE(lu,40) gb(11),lt,gb(9),s
        ENDIF
!       AN EMPTY LINE
        WRITE(lu,*)
!
!   WRITES OUT: TITLES OF THE STAGES
!
      ELSE
!
        IF(lng.EQ.lng_fr) WRITE(lu,200) fr(ietape)
        IF(lng.EQ.lng_en) WRITE(lu,200) gb(ietape)
!
      ENDIF
!
!-----------------------------------------------------------------------
!
10     FORMAT(/,80('='),/,1x,a10,i8,a10,
     &     1i4,' J ',1i2,' H ',1i2,' MIN ',f8.4,' S',5x,'(',f15.4,' S)')
11     FORMAT(/,80('='),/,1x,a10,i8,a10,
     &     1i4,' D ',1i2,' H ',1i2,' MN ',f8.4,' S',5x,'(',f15.4,' S)')
20     FORMAT(/,80('='),/,1x,a10,i8,a10,1i2,' H ',1i2,' MIN ',f8.4,' S',
     &                                               5x,'(',f12.4,' S)')
30     FORMAT(/,80('='),/,1x,a10,i8,a10,1i2,' MN ',f8.4,' S',
     &                                               5x,'(',f12.4,' S)')
40     FORMAT(/,80('='),/,1x,a10,i8,a10,f8.4,' S')
200    FORMAT(80('-'),/,18x,a32)
!
!-----------------------------------------------------------------------
!
      RETURN
      END