elebd31.f

Go to the documentation of this file.

!                   ******************
                    SUBROUTINE elebd31
!                   ******************
!
     &(nelbor,nulone,iklbor,ifabor,nbor,ikle,
     & nelem,neleb,nelmax,npoin,nptfr,ielm)
!
!***********************************************************************
! BIEF   V6P0                                   21/08/2010
!***********************************************************************
!
!brief    BUILDS NELBOR, NULONE, IKLBORD.
!
!history  LAM MINH-PHUONG
!+
!+
!+
!
!history  J-M HERVOUET (LNH)
!+        09/04/04
!+        V5P5
!+
!
!history  N.DURAND (HRW), S.E.BOURBAN (HRW)
!+        13/07/2010
!+        V6P0
!+   Translation of French comments within the FORTRAN sources into
!+   English comments
!
!history  N.DURAND (HRW), S.E.BOURBAN (HRW)
!+        21/08/2010
!+        V6P0
!+   Creation of DOXYGEN tags for automated documentation and
!+   cross-referencing of the FORTRAN sources
!
!history  S.E.BOURBAN (HRW)
!+        21/03/2017
!+        V7P3
!+   Replacement of the DATA declarations by the PARAMETER associates
!
!~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~
!| IELM           |-->| TYPE D'ELEMENT.
!| IFABOR         |-->| TABLEAU DES VOISINS DES FACES.
!| IKLBOR         |<--| NUMERO LOCAL DES NOEUDS A PARTIR D'UN ELEMENT
!|                |   | DE BORD
!| IKLE           |-->| NUMEROS GLOBAUX DES POINTS DE CHAQUE ELEMENT.
!| NBOR           |-->| NUMERO GLOBAL D'UN NOEUD A PARTIR DU NUMERO LOCAL
!| NELBOR         |<--| NUMERO DE L'ELEMENT ADJACENT AU KIEME SEGMENT
!| NELEB          |-->| NOMBRE D'ELEMENTS DE BORD.
!| NELEM          |-->| NOMBRE TOTAL D'ELEMENTS DANS LE MAILLAGE.
!| NELMAX         |---|
!| NPOIN          |-->| NOMBRE TOTAL DE POINTS DU DOMAINE.
!| NPTFR          |-->| NOMBRE DE POINTS FRONTIERES.
!| NULONE         |<--| NUMERO LOCAL D'UN POINT DE BORD DANS
!|                |   | L'ELEMENT ADJACENT DONNE PAR NELBOR
!~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~
!
      USE bief, ex_elebd31 => elebd31
!
      USE declarations_special
      IMPLICIT NONE
!
!+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+
!
      INTEGER, INTENT(IN)    :: NELEM,NELEB,NELMAX
      INTEGER, INTENT(IN)    :: NPOIN,NPTFR,IELM
      INTEGER, INTENT(IN)    :: NBOR(nptfr)
      INTEGER, INTENT(IN)    :: IFABOR(nelmax,4)
      INTEGER, INTENT(IN)    :: IKLE(nelem,4)
      INTEGER, INTENT(OUT)   :: NELBOR(neleb),NULONE(neleb,3)
      INTEGER, INTENT(OUT)   :: IKLBOR(neleb,3)
!
!+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+
!
      INTEGER   :: IELEM, IELEB, J,K,IPOIN
      INTEGER   :: IPOBO(npoin)
!
      INTEGER :: SOMFAC(3,4)
      parameter( somfac = reshape( (/
     &           1,2,3 , 4,1,2 , 2,3,4 , 3,4,1  /), shape=(/ 3,4 /) ) )
!     SIDE NUMBER:   1       2       3       4
!
!+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+
!
      IF(ielm /= 31) THEN
        WRITE(lu,99) ielm
99      FORMAT(1x,'VOISIN: IELM=',1i6,' TYPE OF ELEMENT NOT AVAILABLE')
        CALL plante(1)
        stop
      ENDIF
!
! BUILDS IPOBO TO GO FROM GLOBAL NUMBERING TO LOCAL NUMBERING
      DO ipoin=1,npoin
        ipobo(ipoin) = 0
      ENDDO
      DO k = 1, nptfr
        ipobo(nbor(k)) = k
      ENDDO
!
! BUILDS NELBOR, NULONE, IKLBORD
! ~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~
      ieleb = 0
      DO ielem = 1,nelem
        DO j = 1,4
          IF(ifabor(ielem,j).EQ.0.OR.ifabor(ielem,j).EQ.-1) THEN
            ieleb           = ieleb + 1
            IF ( ieleb .GT. neleb ) THEN
              WRITE(lu,102)
102           FORMAT(1x,'ELEBD31 : ERROR IN MESH')
              CALL plante(1)
              stop
            END IF
            nelbor(ieleb)   = ielem
            nulone(ieleb,1) = somfac(1,j)
            nulone(ieleb,2) = somfac(2,j)
            nulone(ieleb,3) = somfac(3,j)
            iklbor(ieleb,1) = ipobo(ikle(nelbor(ieleb),somfac(1,j)))
            iklbor(ieleb,2) = ipobo(ikle(nelbor(ieleb),somfac(2,j)))
            iklbor(ieleb,3) = ipobo(ikle(nelbor(ieleb),somfac(3,j)))
          ENDIF
        ENDDO
      ENDDO
!
!-----------------------------------------------------------------------
!
      RETURN
      END SUBROUTINE elebd31