eleb3d.f

Go to the documentation of this file.

!                   *****************
                    SUBROUTINE eleb3d
!                   *****************
!
     &(ikle3,nbor,nelbor,iklbor,neleb,nelebx,nulone,
     & nelem2,npoin2,nplan,netage,nptfr)
!
!***********************************************************************
! BIEF   V7P0                                   19/03/2014
!***********************************************************************
!
!brief    BUILDS THE 3D MESH.
!+
!+            INPUT: 3D MESH ARRAYS FILLED BY A PRELIMINARY CALL
!+                       TO ELEBD.
!+
!+            OUTPUT: ARRAYS COMPLETE IN 3D.
!
!history  J-M HERVOUET (LNHE)
!+        23/06/2008
!+        V5P9
!+
!
!history  N.DURAND (HRW), S.E.BOURBAN (HRW)
!+        13/07/2010
!+        V6P0
!+   Translation of French comments within the FORTRAN sources into
!+   English comments
!
!history  N.DURAND (HRW), S.E.BOURBAN (HRW)
!+        21/08/2010
!+        V6P0
!+   Creation of DOXYGEN tags for automated documentation and
!+   cross-referencing of the FORTRAN sources
!
!history  J-M HERVOUET (EDF LAB, LNHE)
!+        19/03/2014
!+        V7P0
!+   Boundary segments have now their own numbering, independent of
!+   boundary points numbering.
!
!~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~
!| IKLBOR         |-->| CONNECTIVITY TABLE OF BOUNDARY ELEMENTS
!| IKLE3          |<--| CONNECTIVITY TABLE IN 3D
!| NBOR           |-->| GLOBAL NUMBER OF BOUNDARY POINTS IN 2D
!| NELBOR         |-->| FOR THE KTH BOUNDARY EDGE, GIVES THE CORRESPONDING
!|                |   | ELEMENT.
!| NELEB          |-->| NUMBER OF BOUNDARY ELEMENTS
!|                |   | AT THE BEGINNING : IN 2D, AT THE EXIT, IN 3D
!|                |   | NUMBER OF BOUNDARY ELEMENTS
!| NELEBX         |-->| MAXIMUM NUMBER OF BOUNDARY ELEMENTS
!|                |   | USED AS FIRST DIMENSION OF IKLBOR
!| NELEM2         |-->| NUMBER OF ELEMENTS IN 2D
!| NETAGE         |-->| NUMBER OF PLANES - 1
!| NPLAN          |-->| NUMBER OF PLANES
!| NPOIN2         |-->| NUMBER OF POINTS IN 2D
!| NPTFR          |-->| NUMBER OF BOUNDARY POINTS
!| NULONE         |-->| GOES WITH ARRAY NELBOR. NELBOR GIVES THE
!|                |   | ADJACENT ELEMENT, NULONE GIVES THE LOCAL
!|                |   | NUMBER OF THE FIRST NODE OF THE BOUNDARY EDGE
!|                |   | I.E. 1, 2 OR 3 FOR TRIANGLES.
!|                |   | !!!!!  HERE IN 3D !!!!!!
!|                |   | WITH PRISMS, A CONDITION IS THAT THE FIRST
!|                |   | NPTFR VALUES OF MESH3D%NULONE ARE EQUAL
!|                |   | TO MESH2D%NULONE (SEE CALL TO STOSEG41 IN INBIEF)
!~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~
!
      USE bief, ex_eleb3d => eleb3d
!
      USE declarations_special
      IMPLICIT NONE
!
!+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+
!
      INTEGER, INTENT(IN)    :: NELEM2,NPOIN2,NPLAN,NETAGE,NPTFR
      INTEGER, INTENT(IN)    :: NELEBX
      INTEGER, INTENT(INOUT) :: NELEB
      INTEGER, INTENT(INOUT) :: IKLE3(nelem2,netage,6)
      INTEGER, INTENT(INOUT) :: IKLBOR(nelebx,4),NULONE(nelebx,4)
      INTEGER, INTENT(INOUT) :: NELBOR(nelebx),NBOR(nptfr*nplan)
!
!+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+
!
      INTEGER IELEM,IPOIN,IELEB2,IELEB3,K1,K2,IETAGE,IPTFR,I1,I2,I3
      INTEGER IPLAN
!
!-----------------------------------------------------------------------
!
!     CONNECTIVITY TABLES FOR BOUNDARY FACES --> IKLBOR , NBOR ,
!     CORRESPONDENCE BETWEEN LOCAL BOUNDARY NUMBERS
!     AND 3D LOCAL NUMBERS --> NULONE
!
!     LATERAL BOUNDARIES: BUILDING NBOR
!
      DO iplan=2,nplan
        DO iptfr=1,nptfr
          nbor(iptfr+(iplan-1)*nptfr)=nbor(iptfr)+(iplan-1)*npoin2
        ENDDO
      ENDDO
!
!     LATERAL BOUNDARIES
!
      DO ietage = 1,netage
        DO ieleb2=1,neleb
          ieleb3=ieleb2+(ietage-1)*neleb
          k1=iklbor(ieleb2,1)
          k2=iklbor(ieleb2,2)
          iklbor(ieleb3,1) = k1 + (ietage-1)*nptfr
          iklbor(ieleb3,2) = k2 + (ietage-1)*nptfr
          iklbor(ieleb3,3) = iklbor(ieleb3,2) + nptfr
          iklbor(ieleb3,4) = iklbor(ieleb3,1) + nptfr
          ielem = nelbor(ieleb2)
          ipoin = nbor(k1)
          nelbor(ieleb3)=ielem+(ietage-1)*nelem2
          i1=ikle3(ielem,1,1)
          i2=ikle3(ielem,1,2)
          i3=ikle3(ielem,1,3)
          IF(ipoin.EQ.i1) THEN
            nulone(ieleb3,1) = 1
            nulone(ieleb3,2) = 2
            nulone(ieleb3,3) = 5
            nulone(ieleb3,4) = 4
          ELSEIF(ipoin.EQ.i2) THEN
            nulone(ieleb3,1) = 2
            nulone(ieleb3,2) = 3
            nulone(ieleb3,3) = 6
            nulone(ieleb3,4) = 5
          ELSEIF(ipoin.EQ.i3) THEN
            nulone(ieleb3,1) = 3
            nulone(ieleb3,2) = 1
            nulone(ieleb3,3) = 4
            nulone(ieleb3,4) = 6
          ELSE
            WRITE(lu,102) ipoin,i1,i2,i3,k1,ielem
            CALL plante(1)
            stop
          ENDIF
        ENDDO
      ENDDO
!
!-----------------------------------------------------------------------
!
!     NOW NELEB BECOMES THE 3D VALUE
!
      neleb=neleb*netage
!
!-----------------------------------------------------------------------
!
102   FORMAT(' ELEB3D: PROBLEM WHEN BUILDING NULONE, IPOIN =',
     &  i6,'   I1,2,3=',i6,1x,i6,1x,i6,' K1=',i6,' IELEM=',i6)
!
!-----------------------------------------------------------------------
!
      RETURN
      END