elapse.f

Go to the documentation of this file.

!                   *****************
                    SUBROUTINE elapse
!                   *****************
!
     &(tdeb,tfin)
!
!***********************************************************************
! BIEF   V6P1                                   21/08/2010
!***********************************************************************
!
!brief    PRINTS THE DURATION BETWEEN TWO TIMES GIVEN BY THE
!+                CALL TO DATE_AND_TIME.
!
!history  J-M HERVOUET (LNHE)
!+        20/09/2001
!+        V5P3
!+
!
!history  N.DURAND (HRW), S.E.BOURBAN (HRW)
!+        13/07/2010
!+        V6P0
!+   Translation of French comments within the FORTRAN sources into
!+   English comments
!
!history  N.DURAND (HRW), S.E.BOURBAN (HRW)
!+        21/08/2010
!+        V6P0
!+   Creation of DOXYGEN tags for automated documentation and
!+   cross-referencing of the FORTRAN sources
!
!~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~
!| TDEB           |-->| TIME OF BEGINNING
!| TFIN           |-->| TIME OF END
!~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~
!
      USE declarations_special
      IMPLICIT NONE
!
!+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+
!
      INTEGER, INTENT(IN) :: TDEB(8),TFIN(8)
!
!+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+
!
      INTEGER YEAR,MONTH,DAY,NDAY,J1,J2,HOURS,MINUTES
      INTEGER Y,M
      DOUBLE PRECISION TD,TF,TT
!
      INTRINSIC int
!
      INTEGER, PARAMETER :: GREG=15+31*(10+12*1582)
!
!-----------------------------------------------------------------------
!
!     COMPUTES THE NUMBER OF DAYS (USES THE JULIAN DAY SYSTEM)
!
      year=tdeb(1)
      month=tdeb(2)
      day=tdeb(3)
      IF(month.GT.2) THEN
        y=year
        m=month+1
      ELSE
        y=year-1
        m=month+13
      ENDIF
!
      j1=int(365.25d0*y)+int(30.6001d0*m)+day+1720995
      IF(day+31*(month+12*year).GE.greg) THEN
        j1=j1+2-int(0.01d0*y)+int(0.25d0*int(0.01d0*y))
      ENDIF
!
      year=tfin(1)
      month=tfin(2)
      day=tfin(3)
      IF(month.GT.2) THEN
        y=year
        m=month+1
      ELSE
        y=year-1
        m=month+13
      ENDIF
!
      j2=int(365.25d0*y)+int(30.6001d0*m)+day+1720995
      IF(day+31*(month+12*year).GE.greg) THEN
        j2=j2+2-int(0.01d0*y)+int(0.25d0*int(0.01d0*y))
      ENDIF
!
      nday=j2-j1
!
      td = 3600.d0*tdeb(5) + 60.d0*tdeb(6) + tdeb(7)
      tf = 3600.d0*tfin(5) + 60.d0*tfin(6) + tfin(7)
      IF(tf.LT.td) THEN
        nday=nday-1
        tf=tf+86400.d0
      ENDIF
      tt=tf-td
      hours=int(tt/3600.d0)
      tt=tt-3600.d0*hours
      minutes=int(tt/60.d0)
      tt=tt-60.d0*minutes
!
!---------------------------------------------------------------------
!
      WRITE(lu,*)   'ELAPSE TIME : '
      IF(nday.GT.0) THEN
        WRITE(lu,*) '                  ',nday,' DAYS'
      ENDIF
      IF(hours.GT.0) THEN
        WRITE(lu,*) '                  ',hours,' HOURS'
      ENDIF
      IF(minutes.GT.0) THEN
        WRITE(lu,*) '                  ',minutes,' MINUTES'
      ENDIF
      WRITE(lu,*)   '                  ',int(tt),' SECONDS'
!
!---------------------------------------------------------------------
!
      RETURN
      END