ecrdeb.f

Go to the documentation of this file.

!                       *****************
                        SUBROUTINE ecrdeb
!                       *****************
!
     &(canal,fformat,titcas,nbvar,c2dh,textlu,ic,n)
!
!***********************************************************************
! POSTEL3D VERSION 5.1   01/09/99   T. DENOT (LNH) 01 30 87 74 89
! FORTRAN90
!***********************************************************************
!
!     FONCTION  :  OUVERTURE D'UN FICHIER POUR UNE COUPE
!               + ECRITURE DU DEBUT DE l'ENTETE (TITRE,NBV,TEXTE).
!
!-----------------------------------------------------------------------
!                             ARGUMENTS
! .________________.____.______________________________________________.
! !      NOM       !MODE!                   ROLE                       !
! !________________!____!______________________________________________!
! !   CANAL        ! -->! CANAL DE SORTIE                              !
! !   FFORMAT      ! -->! FORMAT DU FICHIER POUR LES COUPES            !
! !   TITCAS       ! -->! TITRE LU DANS LE FICHIER DE RESULTATS        !
! !   NBV          ! -->! NOMBRE DE VARIABLES EN SORTIE                !
! !   SORG3D       ! -->! INDICATEUR DES VARIABLES ENREGISTREES        !
! !   C2DH         ! -->! INDICATEUR DE LA NATURE DE LA COUPE (H OU V) !
! !________________!____!______________________________________________!
! MODE : -->(DONNEE NON MODIFIEE), <--(RESULTAT), <-->(DONNEE MODIFIEE)
!-----------------------------------------------------------------------
!
! SOUS-PROGRAMME APPELE PAR : PRE2DH , COUPEV
! SOUS-PROGRAMME APPELES : ECRI2
!
!history Y AUDOUIN (LNHE)
!+       25/05/2015
!+       V7P0
!+       Modification to comply with the hermes module
!
!***********************************************************************
!
      USE bief
      USE interface_hermes
!
      USE declarations_special
      IMPLICIT NONE
!
!+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+
!
      INTEGER ,INTENT(IN) :: NBVAR
      INTEGER, INTENT(INOUT) :: CANAL
      INTEGER, INTENT(IN) :: IC,N
      LOGICAL, INTENT(IN) :: C2DH
      CHARACTER(LEN=72), INTENT(IN) :: TITCAS
      CHARACTER(LEN=32), INTENT(IN) :: TEXTLU(100)
      CHARACTER(LEN=8), INTENT(INOUT) ::  FFORMAT
!
!+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+
!
      INTEGER :: I
      CHARACTER(LEN=80) TITRE
      CHARACTER(LEN=15)  NOMCOU
!
      CHARACTER(LEN=3) :: EXTEN1
      CHARACTER(LEN=7) :: EXTEN2
      EXTERNAL exten1,exten2
      CHARACTER(LEN=32), ALLOCATABLE :: VAR_NAME(:)
      INTEGER :: IVAR, IERR
!
!-----------------------------------------------------------------------
!
!     OUVERTURE DU FICHIER D'UNE COUPE
!
      IF(c2dh) THEN
        nomcou = 'POSHOR_' // exten1(ic) // '     '
      ELSE
        nomcou = 'POSVER_' // exten2(ic,n+1)
      ENDIF
!
      CALL open_mesh(fformat,nomcou,canal,'WRITE    ',ierr)
      CALL check_call(ierr,'ECRDEB:OPEN_MESH')
!
!-----------------------------------------------------------------------
!
!  ECRITURE DU TITRE
!
      titre = titcas // fformat
!
!-----------------------------------------------------------------------
!
!  ECRITURE DU NOMBRE DE VARIABLES EN SORTIE
!
!
      ivar = 1
!
!-----------------------------------------------------------------------
!
!  ECRITURE DES TEXTES
!
      IF (c2dh) THEN
        ALLOCATE(var_name(nbvar+1),stat=ierr)
        CALL check_allocate(ierr,'ECRDEB:VAR_NAME')
!
        IF (lng.EQ.lng_fr) var_name(ivar) =
     &                        'INDICATEUR DOM.                 '
        IF (lng.EQ.lng_en) var_name(ivar) =
     &                        'DOMAIN INDICATOR                '
        ivar = ivar + 1
!
      ELSE
        ALLOCATE(var_name(nbvar),stat=ierr)
        CALL check_allocate(ierr,'ECRDEB:VAR_NAME')
!
        IF (lng.EQ.lng_fr) var_name(ivar) =
     &                        'VITESSE UT      M/S             '
        IF (lng.EQ.lng_en) var_name(ivar) =
     &                        'VELOCITY UT     M/S             '
        ivar = ivar + 1
!
        IF (lng.EQ.lng_fr) var_name(ivar) =
     &                        'VITESSE W       M/S             '
        IF (lng.EQ.lng_en) var_name(ivar) =
     &                        'VELOCITY W      M/S             '
        ivar = ivar + 1
!
        IF (lng.EQ.lng_fr) var_name(ivar) =
     &                        'VITESSE UN      M/S             '
        IF (lng.EQ.lng_en) var_name(ivar) =
     &                        'VELOCITY UN     M/S             '
        ivar = ivar + 1
!
      ENDIF
!
!     Adding z
      var_name(ivar) = textlu(1)
      ivar = ivar + 1
      IF (c2dh) THEN
        DO i=2,nbvar
          var_name(ivar) = textlu(i)
          ivar = ivar + 1
        ENDDO
      ELSE
        IF (nbvar.GT.4) THEN
          ! Adding the rest of the variable skipping velocity
          DO i=5,nbvar
            var_name(ivar) = textlu(i)
            ivar = ivar + 1
          ENDDO
        ENDIF
      ENDIF
      CALL set_header(fformat,canal,titre,ivar-1,
     &                var_name(1:ivar-1),ierr)
      CALL check_call(ierr,'ECRDEB:SET_HEADER')
!
!-----------------------------------------------------------------------
!
      RETURN
      END