dwnup1.f

Go to the documentation of this file.

!                   *****************
                    SUBROUTINE dwnup1
!                   *****************
!
     &(x, a,b ,ditr,mesh)
!
!***********************************************************************
! BIEF   V6P1                                   21/08/2010
!***********************************************************************
!
!brief    SOLVES THE SYSTEM A X = B.
!+
!+            THE MATRIX A IS HERE THE RESULT OF A DECOMPOSITION
!+                DONE IN SUBROUTINE DECLDU.
!code
!+            EACH ELEMENTARY MATRIX WAS FACTORISED IN THE FORM :
!+
!+            LE X DE X UE
!+
!+            LE : LOWER TRIANGULAR WITH 1S ON THE DIAGONAL
!+            DE : DIAGONAL
!+            UE : UPPER TRIANGULAR WITH 1S ON THE DIAGONAL
!+
!+                                                T
!+            IF THE MATRIX IS SYMMETRICAL : LE =  UE
!+
!+            "DE" MATRICES ARE CONSIDERED LIKE DIAGONALS OF SIZE
!+            NPOIN X NPOIN, WHICH ARE FILLED WITH 1S FOR THE POINTS
!+            WHICH DO NOT BELONG TO THE CONSIDERED ELEMENT
!+
!+            THEN PERFORMS THE PRODUCT OF ALL THESE DIAGONALS
!+            YIELDING DIAGONAL DB
!+
!+
!+ !!!!!!!!!  FINALLY: DB HAS BEEN INVERTED BECAUSE THAT'S HOW
!+                     IT IS USED IN THIS SUBROUTINE
!+
!+            MATRIX A IS HERE :
!+
!+            THE PRODUCT FROM 1 TO NELEM OF ALL THE MATRICES: LE
!+
!+            MULTIPLIED BY :
!+
!+            THE DIAGONAL: DB
!+
!+            MULTIPLIED BY :
!+
!+            THE PRODUCT FROM NELEM TO 1 OF ALL THE MATRICES: UE
!
!code
!+-----------------------------------------------------------------------
!+  MEANING OF IELM :
!+
!+  TYPE OF ELEMENT      NUMBER OF POINTS      CODED IN THIS SUBROUTINE
!+
!+  11 : P1 TRIANGLE            3                       YES
!+  12 : QUASI-BUBBLE TRIANGLE  4                       YES
!+  21 : Q1 QUADRILATERAL       4                       YES
!+  41 : TELEMAC-3D PRISMS      6                       YES
!+
!+-----------------------------------------------------------------------
!
!history  J-M HERVOUET (LNH)
!+        26/02/04
!+        V5P5
!+
!
!history  N.DURAND (HRW), S.E.BOURBAN (HRW)
!+        13/07/2010
!+        V6P0
!+   Translation of French comments within the FORTRAN sources into
!+   English comments
!
!history  N.DURAND (HRW), S.E.BOURBAN (HRW)
!+        21/08/2010
!+        V6P0
!+   Creation of DOXYGEN tags for automated documentation and
!+   cross-referencing of the FORTRAN sources
!
!~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~
!| A              |-->| MATRIX A IN LDU FORM
!| B              |<--| RIGHT-HAND SIDE OF THE SYSTEM
!| DITR           |-->| OPTION  'D' : MATRIX A IS TAKEN
!|                |   |         'T' : MATRIX TRANSPOSED(A)
!| MESH           |-->| MESH STRUCTURE
!| X              |<--| SOLUTION OF SYSTEM AX = B
!~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~
!
      USE bief, ex_dwnup1 => dwnup1
!
      USE declarations_special
      IMPLICIT NONE
!
!+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+
!
      TYPE(bief_obj), INTENT(INOUT) :: X
      TYPE(bief_obj), INTENT(IN)    :: B
      TYPE(bief_obj), INTENT(IN)    :: A
      TYPE(bief_mesh), INTENT(IN)   :: MESH
      CHARACTER(LEN=1), INTENT(IN)  :: DITR
!
!+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+
!
      INTEGER IELM,NPOIN,NELEM,NELMAX
!
      CHARACTER(LEN=1) TYPD,TYPX
!
!-----------------------------------------------------------------------
!
      typd  = a%TYPDIA
      typx  = a%TYPEXT
      npoin = a%D%DIM1
      ielm  = a%ELMLIN
      nelem = mesh%NELEM
      nelmax= mesh%NELMAX
      CALL cpstvc(b,x)
!
!-----------------------------------------------------------------------
!
! 1) DESCENT WITH COPY OF B IN X
!
      IF(a%STO.EQ.1) THEN
        CALL descen(x%R, a%X%R,typx,b%R,
     &       mesh%IKLE%I,nelem,nelmax,npoin,ielm,ditr,.true.,mesh%LV)
      ELSEIF(a%STO.EQ.3) THEN
        CALL desseg(x%R, a%X%R,typx,b%R,
     &              mesh%GLOSEG%I,mesh%NSEG,npoin,ditr,.true.)
      ENDIF
!
!-----------------------------------------------------------------------
!
! 2) RESUMES INVERSIONS OF DIAGONAL MATRICES
!
      IF(typd(1:1).NE.'I') THEN
        CALL ov('X=XY    ', x=x%R, y=a%D%R, dim1=npoin)
      ENDIF
!
!-----------------------------------------------------------------------
!
! 3) TRACES BACK WITHOUT PRELIMINARY COPY OF B IN X
!
      IF(a%STO.EQ.1) THEN
        CALL remont(x%R, a%X%R,typx,b%R,
     &       mesh%IKLE%I,nelem,nelmax,npoin,ielm,ditr,.false.,mesh%LV)
      ELSE
        CALL remseg(x%R, a%X%R,typx,b%R,
     &              mesh%GLOSEG%I,mesh%NSEG,npoin,ditr,.false.)
      ENDIF
!
!-----------------------------------------------------------------------
!
      RETURN
      END