dump2d.f

Go to the documentation of this file.

!                   *****************
                    SUBROUTINE dump2d
!                   *****************
!
     &(  xf1 , np1 )
!
!***********************************************************************
! TOMAWAC   V6P3                                   15/06/2011
!***********************************************************************
!
!brief    WRITES OUT WAVE, WIND, CURRENT, BATHYMETRY, ...
!+                VARIABLES AT EACH NODE OF THE MESH.
!+                VARIES SPATIALLY IN 2D (BINARY SELAFIN FORMAT).
!
!warning  STSDER used as work array here.
!
!
!history  F. MARCOS
!+        01/02/95
!+        V1P0
!+   CREATED
!
!history  M. BENOIT
!+        04/07/96
!+        V1P2
!+   MODIFIED
!
!history  N.DURAND (HRW), S.E.BOURBAN (HRW)
!+        13/07/2010
!+        V6P0
!+   Translation of French comments within the FORTRAN sources into
!+   English comments
!
!history  N.DURAND (HRW), S.E.BOURBAN (HRW)
!+        21/08/2010
!+        V6P0
!+   Creation of DOXYGEN tags for automated documentation and
!+   cross-referencing of the FORTRAN sources
!
!history  G.MATTAROLO (EDF - LNHE)
!+        15/06/2011
!+        V6P1
!+   Translation of French names of the variables in argument
!
!history  J-M HERVOUETO (EDF R&D, LNHE)
!+        26/02/2013
!+        V6P3
!+   Use of work arrays optimised.
!
!~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~
!| NP1            |-->| NPOIN2.NDIRE.NF
!| XF1            |-->| VARIANCE DENSITY DIRECTIONAL SPECTRUM
!~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~
!
      USE declarations_tomawac
      USE interface_tomawac, ex_dump2d => dump2d
!
      IMPLICIT NONE
!
!+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+
!
      INTEGER, INTENT(IN)          :: NP1
      DOUBLE PRECISION, INTENT(IN) :: XF1(np1)
!
!+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+
!
      INTEGER          IP
      DOUBLE PRECISION U10   , FMIN  , FMAX
!
      fmin=freq(1)
      fmax=freq(nf)
!
!=====C====================================
!     C COMPUTES THE SELECTED VARIABLES
!=====C====================================
! THE ORDER IN WHICH THE VARIABLES ARE COMPUTED DOES NOT CORRESPOND TO THAT OF
! THE GRAPHICAL OUTPUT IN AN EFFORT TO LIMIT THE NUMBER OF WORKING ARRAYS.
!
!     ------------------------------- RADIATION STRESSES
!
      IF(.NOT.proinf) THEN
        IF(sorleo(11).OR.sorleo(12).OR.sorleo(13).OR.
     &     sorleo(14).OR.sorleo(15) ) CALL radiat
     &        ( fx, fy, xk, xf1, cg ,
     &  tsder,tra36, tra37, tra38, tra39)
      ENDIF
!
!     ------------------------------- DIRECTIONAL DIR_SPREADING
!
      IF(sorleo(4)) THEN
        CALL dir_spread( tra31, xf1, ndire, nf, npoin2)
      ENDIF
!
!     ------------------------------- MEAN DIRECTION
!
      IF(sorleo(3)) THEN
        CALL tetmoy( tra32, xf1, ndire, nf  , npoin2)
        IF(trigo) THEN
          DO ip=1,npoin2
            tra32(ip)=(pisur2-tra32(ip))*gradeg
          ENDDO
        ELSE
          DO ip=1,npoin2
            tra32(ip)=tra32(ip)*gradeg
          ENDDO
        ENDIF
      ENDIF
!
!     ------------------------------- MEAN FREQUENCY FMOY
!
      IF(sorleo(18).OR.sorleo(28)) THEN
        CALL fremoy( fmoy, xf1, nf, ndire, npoin2)
        IF(sorleo(28)) THEN
          DO ip=1,npoin2
            ptmoy(ip)=1.d0/min(max(fmoy(ip),fmin),fmax)
          ENDDO
        ENDIF
      ENDIF
!
!     ------------------------------- MEAN FREQUENCY FM01
!
      IF(sorleo(19).OR.sorleo(29)) THEN
        CALL frem01( tra34, xf1,  nf, ndire, npoin2)
        IF (sorleo(29)) THEN
          DO ip=1,npoin2
            ptm01(ip)=1.d0/min(max(tra34(ip),fmin),fmax)
          ENDDO
        ENDIF
      ENDIF
!
!     ------------------------------- MEAN FREQUENCY FM02
!
      IF (sorleo(20).OR.sorleo(30)) THEN
        CALL frem02( tra35, xf1, nf, ndire, npoin2)
        IF (sorleo(30)) THEN
          DO ip=1,npoin2
            ptm02(ip)=1.d0/min(max(tra35(ip),fmin),fmax)
          ENDDO
        ENDIF
      ENDIF
!
!     ------------------------------- DISCRETE PEAK FREQUENCY
!
      IF (sorleo(21).OR.sorleo(31)) THEN
        CALL frepic( tra36, xf1,  nf, ndire, npoin2)
        IF (sorleo(31)) THEN
          DO ip=1,npoin2
            pptpd(ip)=1.d0/min(max(tra36(ip),fmin),fmax)
          ENDDO
        ENDIF
      ENDIF
!
!     ------------------------------- PEAK FREQUENCY (READ 5TH ORDER)
!
      IF (sorleo(22).OR.sorleo(32)) THEN
        CALL fpread( frea5, xf1, nf, ndire, npoin2, 5.d0 )
        IF (sorleo(32)) THEN
          DO ip=1,npoin2
            prea5(ip)=1.d0/min(max(frea5(ip),fmin),fmax)
          ENDDO
        ENDIF
      ENDIF
!
!     ------------------------------- PEAK FREQUENCY (READ 8TH ORDER)
!
      IF (sorleo(23).OR.sorleo(33)) THEN
        CALL fpread( frea8, xf1, nf, ndire, npoin2, 8.d0  )
        IF (sorleo(33)) THEN
          DO ip=1,npoin2
            prea8(ip)=1.d0/min(max(frea8(ip),fmin),fmax)
          ENDDO
        ENDIF
      ENDIF
!
      IF(vent) THEN
!
!       ------------------------------- DRAG COEFFICIENT
!
        IF(sorleo(25)) THEN
          DO ip=1,npoin2
            u10=uv(ip)**2+vv(ip)**2
            IF (u10.GT.1.d-6) THEN
              cdra2(ip)=usold(ip)**2/u10
            ELSE
              cdra2(ip)=0.d0
            ENDIF
          ENDDO
        ENDIF
      ENDIF
!
!     ------------------------------- BOTTOM SPEED
!
      IF(.NOT.proinf) THEN
        IF(sorleo(16)) THEN
          CALL vitfon(vifond,xf1, xk, nf, npoin2, ndire)
        ENDIF
      ENDIF
!
!     ------------------------------- VARIANCE
!
      IF(sorleo(1).OR.sorleo(2)) THEN
        CALL totnrj( varian, xf1, nf, ndire, npoin2)
!
!     ------------------------------- SIGNIFICANT WAVE HEIGHT
!
        IF(sorleo(2)) THEN
          DO ip=1,npoin2
            IF (varian(ip).GE.0) THEN
              tra38(ip)=4.d0*sqrt(varian(ip))
            ELSE
              tra38(ip)=0
            ENDIF
          ENDDO
        ENDIF
      ENDIF
!
!     ------------------------------- POWER PER UNIT LENGTH
!
      IF(sorleo(34)) THEN
        CALL wpower(xf1, cg, nf, ndire, npoin2)
      ENDIF
!
!     ------------------------------- USER FUNCTION
!
      CALL user_dump2d(xf1, np1)

!
!-----------------------------------------------------------------------
!
      RETURN
      END