downup.f

Go to the documentation of this file.

!                   *****************
                    SUBROUTINE downup
!                   *****************
!
     &(x, a,b ,ditr,mesh)
!
!***********************************************************************
! BIEF   V6P1                                   21/08/2010
!***********************************************************************
!
!brief    SOLVES THE SYSTEM A X = B.
!+
!+            THE MATRIX A IS HERE THE RESULT OF A DECOMPOSITION
!+                DONE IN SUBROUTINE DECLDU.
!code
!+            EACH ELEMENTARY MATRIX WAS FACTORISED IN THE FORM :
!+
!+            LE X DE X UE
!+
!+            LE : LOWER TRIANGULAR WITH 1S ON THE DIAGONAL
!+            DE : DIAGONAL
!+            UE : UPPER TRIANGULAR WITH 1S ON THE DIAGONAL
!+
!+                                                T
!+            IF THE MATRIX IS SYMMETRICAL : LE =  UE
!+
!+            "DE" MATRICES ARE CONSIDERED LIKE DIAGONALS OF SIZE
!+            NPOIN X NPOIN, WHICH ARE FILLED WITH 1S FOR THE POINTS
!+            WHICH DO NOT BELONG TO THE CONSIDERED ELEMENT
!+
!+            THEN PERFORMS THE PRODUCT OF ALL THESE DIAGONALS
!+            YIELDING DIAGONAL DB
!+
!+
!+ !!!!!!!!!  FINALLY: DB HAS BEEN INVERTED BECAUSE THAT'S HOW
!+                     IT IS USED IN THIS SUBROUTINE
!+
!+            MATRIX A IS HERE :
!+
!+            THE PRODUCT FROM 1 TO NELEM OF ALL THE MATRICES: LE
!+
!+            MULTIPLIED BY :
!+
!+            THE DIAGONAL: DB
!+
!+            MULTIPLIED BY :
!+
!+            THE PRODUCT FROM NELEM TO 1 OF ALL THE MATRICES: UE
!
!code
!+-----------------------------------------------------------------------
!+  MEANING OF IELM :
!+
!+  TYPE OF ELEMENT      NUMBER OF POINTS      CODED IN THIS SUBROUTINE
!+
!+  11 : P1 TRIANGLE            3                       YES
!+  12 : QUASI-BUBBLE TRIANGLE  4                       YES
!+  21 : Q1 QUADRILATERAL       4                       YES
!+  41 : TELEMAC-3D PRISMS      6                       YES
!+
!+-----------------------------------------------------------------------
!
!history  J-M HERVOUET (LNH)
!+        24/04/97
!+        V5P1
!+
!
!history  N.DURAND (HRW), S.E.BOURBAN (HRW)
!+        13/07/2010
!+        V6P0
!+   Translation of French comments within the FORTRAN sources into
!+   English comments
!
!history  N.DURAND (HRW), S.E.BOURBAN (HRW)
!+        21/08/2010
!+        V6P0
!+   Creation of DOXYGEN tags for automated documentation and
!+   cross-referencing of the FORTRAN sources
!
!~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~
!| A              |-->| MATRIX A
!| B              |<--| RIGHT-HAND SIDE OF THE SYSTEM
!| DITR           |-->| OPTION  'D' : MATRIX A IS TAKEN
!|                |   |         'T' : MATRIX TRANSPOSED(A)
!| MESH           |-->| MESH STRUCTURE
!| X              |<--| SOLUTION OF SYSTEM AX = B
!~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~
!
      USE bief, ex_doxnup => downup
!
      USE declarations_special
      IMPLICIT NONE
!
!+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+
!
      TYPE(bief_obj), INTENT(INOUT) :: X
      TYPE(bief_obj), INTENT(IN)    :: A,B
      TYPE(bief_mesh), INTENT(IN)   :: MESH
      CHARACTER(LEN=1), INTENT(IN)  :: DITR
!
!+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+
!
      INTEGER S,SA,I
!
!-----------------------------------------------------------------------
!
      IF(x%TYPE.EQ.4) THEN
        s = x%N
      ELSE
        s = 0
      ENDIF
!
!     COVERS THE CASE WHERE THE SYSTEM IS A BLOCK BUT WHERE ONLY ONE OF
!     PRECONDITIONING MATRICES IS USED
!
      IF(a%TYPE.EQ.3) THEN
        sa = 0
      ELSEIF(a%TYPE.EQ.4) THEN
        sa = a%N
      ELSE
        WRITE(lu,400) a%TYPE
400     FORMAT(1x,'DOWNUP (BIEF) :',1i6,' UNEXPECTED TYPE FOR A.')
        CALL plante(1)
        stop
      ENDIF
!
!-----------------------------------------------------------------------
!
      IF(s.EQ.0.AND.sa.EQ.0) THEN
!
!     CASE WHERE A IS A SIMPLE MATRIX AND X A SIMPLE VECTOR
!
        CALL dwnup1(x, a,b ,ditr,mesh)
!
      ELSEIF(s.GT.0.AND.s.EQ.sa) THEN
!
!     CASE WHERE BLOCK A ONLY CONTAINS THE DIAGONALS
!
        DO i=1,s
          CALL dwnup1(x%ADR(i)%P,
     &                a%ADR(i)%P,
     &                b%ADR(i)%P,
     &                ditr,mesh)
        ENDDO ! I
!
      ELSEIF(s.GT.0.AND.s**2.EQ.sa) THEN
!
!     CASE WHERE BLOCK A CONTAINS AS MANY MATRICES AS THERE ARE IN
!     THE COMPLETE SYSTEM: ONLY CONSIDERS THE DIAGONALS
!
        DO i=1,s
          CALL dwnup1(x%ADR(i)%P,
     &                a%ADR(1+(s+1)*(i-1))%P,
     &                b%ADR(i)%P,
     &                ditr,mesh)
        ENDDO ! I
!
!     CASE WHERE A IS A SINGLE MATRIX AND X IS A BLOCK
!
      ELSEIF(s.GT.0.AND.sa.EQ.0) THEN
!
        DO i=1,s
          CALL dwnup1(x%ADR(i)%P,
     &                a,
     &                b%ADR(i)%P,
     &                ditr,mesh)
        ENDDO ! I
!
      ELSE
        WRITE(lu,401)
401     FORMAT(1x,'DOWNUP (BIEF) : UNEXPECTED CASE')
        CALL plante(1)
        stop
      ENDIF
!
!-----------------------------------------------------------------------
!
      RETURN
      END