dots.f

Go to the documentation of this file.

!                   ******************************
                    DOUBLE PRECISION FUNCTION dots
!                   ******************************
!
     &( x , y )
!
!***********************************************************************
! BIEF   V6P1                                   21/08/2010
!***********************************************************************
!
!brief    SCALAR PRODUCT OF TWO OBJECTS, WHICH CAN BE:
!+
!+            TWO VECTORS STRUCTURES, OR
!+
!+            TWO VECTOR BLOCKS STRUCTURES OF IDENTICAL NUMBER AND
!+                CHARACTERISTICS.
!
!warning  IF THE VECTORS HAVE A SECOND DIMENSION, IT IS IGNORED
!+            FOR THE TIME BEING
!
!history  J-M HERVOUET (LNH)
!+        08/12/94
!+        V5P1
!+
!
!history  N.DURAND (HRW), S.E.BOURBAN (HRW)
!+        13/07/2010
!+        V6P0
!+   Translation of French comments within the FORTRAN sources into
!+   English comments
!
!history  N.DURAND (HRW), S.E.BOURBAN (HRW)
!+        21/08/2010
!+        V6P0
!+   Creation of DOXYGEN tags for automated documentation and
!+   cross-referencing of the FORTRAN sources
!
!~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~
!| X              |-->| FIRST VECTOR OR BLOCK
!| Y              |-->| SECOND VECTOR OR BLOCK
!~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~
!
      USE bief, ex_dots => dots
!
      USE declarations_special
      IMPLICIT NONE
!
!+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+
!
      TYPE(bief_obj), INTENT(IN) :: X,Y
!
!+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+
!
      INTEGER IBL
!
!-----------------------------------------------------------------------
!
!     CASE WHERE THE STRUCTURES ARE BLOCKS
!
      IF(x%TYPE.EQ.4) THEN
!
        dots = 0.d0
        DO ibl = 1 , x%N
          dots=dots+dot(x%ADR(ibl)%P%DIM1,x%ADR(ibl)%P%R,y%ADR(ibl)%P%R)
        ENDDO
!
!-----------------------------------------------------------------------
!
!       CASE WHERE THE STRUCTURES ARE NOT BLOCKS
!       IT ASSUMES THAT Y HAS THE SAME TYPE AS X
!
      ELSEIF(x%TYPE.EQ.2) THEN
!
        dots = dot(x%DIM1,x%R,y%R)
!
!-----------------------------------------------------------------------
!
!     ERROR
!
      ELSE
!
        WRITE(lu,60) x%NAME,x%TYPE
        WRITE(lu,61) y%NAME,y%TYPE
        WRITE(lu,63)
60      FORMAT(1x,'DOTS (BIEF) : NAME OF X : ',a6,'  TYPE : ',1i6)
61      FORMAT(1x,'              NAME OF Y : ',a6,'  TYPE : ',1i6)
63      FORMAT(1x,'              NOT IMPLEMENTED')
        CALL plante(1)
        stop
!
      ENDIF
!
!-----------------------------------------------------------------------
!
      RETURN
      END