dlduseg.f

Go to the documentation of this file.

!                   ******************
                    SUBROUTINE dlduseg
!                   ******************
!
     &(db,xb,typdia,xa,typexa,gloseg,nseg,npoin,copy)
!
!***********************************************************************
! BIEF   V6P1                                   21/08/2010
!***********************************************************************
!
!brief    L D U FACTORISATION OF THE ELEMENTARY MATRICES BY SEGMENT
!+                FOR SEGMENTS.
!+
!+            REQUIRES THAT THE DIAGONAL OF A BE THE IDENTITY.
!code
!+            EACH ELEMENTARY MATRIX IS DECOMPOSED IN THE FORM:
!+
!+            LE X DE X UE
!+
!+            LE : LOWER TRIANGULAR WITH 1S ON THE DIAGONAL
!+            DE : DIAGONAL
!+            UE : UPPER TRIANGULAR WITH 1S ON THE DIAGONAL
!+
!+                                                T
!+            IF THE MATRIX IS SYMMETRICAL : LE =  UE
!+
!+            "DE" MATRICES ARE CONSIDERED LIKE DIAGONALS OF SIZE
!+            NPOIN X NPOIN, WHICH ARE FILLED WITH 1S FOR THE POINTS
!+            WHICH DO NOT BELONG TO THE CONSIDERED ELEMENT
!+
!+            THEN PERFORMS THE PRODUCT OF ALL THESE DIAGONALS
!+            YIELDING DIAGONAL DB
!+
!+
!+
!+      (  1   X12 )   (  1   0 ) (  1       0     ) (  1   X12 )
!+      (          ) = (        ) (                ) (          )
!+      ( X21   1  )   ( X21  1 ) (  0   1-X12*X21 ) (  0     1 )
!
!history  J-M HERVOUET (LNH)    ; F LEPEINTRE (LNH)
!+        24/04/97
!+        V5P5
!+
!
!history  N.DURAND (HRW), S.E.BOURBAN (HRW)
!+        13/07/2010
!+        V6P0
!+   Translation of French comments within the FORTRAN sources into
!+   English comments
!
!history  N.DURAND (HRW), S.E.BOURBAN (HRW)
!+        21/08/2010
!+        V6P0
!+   Creation of DOXYGEN tags for automated documentation and
!+   cross-referencing of the FORTRAN sources
!
!~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~
!| COPY           |-->| IF .TRUE. A IS COPIED INTO B.
!|                |   | IF .FALSE. B IS CONSIDERED ALREADY INITIALISED
!| DB             |<--| DIAGONAL OF MATRIX B
!| GLOSEG         |-->| FIRST AND SECOND POINT OF SEGMENTS
!| NPOIN          |-->| NUMBER OF POINTS
!| NSEG           |-->| NUMBER OF SEGMENTS
!| TYPDIA         |<--| TYPE OF DIAGONAL ( 'Q', 'I' , OR '0' )
!| TYPEXA         |<--| TYPE OF OFF-DIAGONAL TERMS ('Q','S',OR '0')
!| XA             |<--| OFF-DIAGONAL TERMS OF MATRIX A
!| XB             |<--| OFF-DIAGONAL TERMS OF MATRIX B
!~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~
!
      USE bief, ex_dlduseg => dlduseg
!
      USE declarations_special
      IMPLICIT NONE
!
!+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+
!
      INTEGER, INTENT(IN)           :: NSEG,NPOIN
      DOUBLE PRECISION, INTENT(INOUT) :: DB(npoin),XB(nseg,*)
      DOUBLE PRECISION, INTENT(IN)  :: XA(nseg,*)
      CHARACTER(LEN=1), INTENT(IN)  :: TYPDIA,TYPEXA
      INTEGER, INTENT(IN)           :: GLOSEG(nseg,2)
      LOGICAL, INTENT(IN)           :: COPY
!
!+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+
!
      INTEGER ISEG
!
!-----------------------------------------------------------------------
!
! REQUIRES THAT THE DIAGONAL OF A BE THE IDENTITY (EXCEPT IN PARALLEL MODE)
!
      IF(typdia(1:1).NE.'I'.AND.ncsize.LE.1) THEN
        WRITE(lu,101) typdia(1:1)
101     FORMAT(1x,'DLDUSEG (BIEF) : DIAGONAL OF A NOT IDENTITY :',a1)
        CALL plante(1)
        stop
      ENDIF
!
!-----------------------------------------------------------------------
!
      IF(typexa(1:1).EQ.'S') THEN
!
        IF(copy) THEN
          CALL ov('X=Y     ', x=xb, y=xa, dim1=nseg)
        ENDIF
!
!-----------------------------------------------------------------------
!
      ELSEIF(typexa(1:1).EQ.'Q') THEN
!
        IF(copy) THEN
          CALL ov('X=Y     ', x=xb , y=xa, dim1=2*nseg)
        ENDIF
!
!-----------------------------------------------------------------------
!
      ELSE
        WRITE(lu,201) typexa(1:1)
201     FORMAT(1x,'DLDUSEG (BIEF) : TYPE OF MATRIX NOT TREATED:',a1)
        CALL plante(1)
        stop
      ENDIF
!
!-----------------------------------------------------------------------
!
!  MULTIPLICATIVE ASSEMBLY OF THE DIAGONAL WITH INITIALISATION
!  OF DB TO 1
!
      CALL ov('X=C     ' , x=db, c=1.d0, dim1=npoin)
!
      IF(typexa(1:1).EQ.'S') THEN
!
      DO iseg=1,nseg
        db(gloseg(iseg,2))=db(gloseg(iseg,2))*(1.d0-xb(iseg,1)**2)
      ENDDO
!
      ELSE
!
      DO iseg=1,nseg
        db(gloseg(iseg,2))=
     &  db(gloseg(iseg,2))*(1.d0-xb(iseg,1)*xb(iseg,2))
      ENDDO
!
      ENDIF
!
!  INVERTS DB (COULD DIVIDE BY 0)
!
      CALL ov('X=1/Y   ', x=db, y=db, dim1=npoin)
!
!-----------------------------------------------------------------------
!
      RETURN
      END