dirich.f

Go to the documentation of this file.

!                   *****************
                    SUBROUTINE dirich
!                   *****************
!
     &(f, s, sm , fbor,limdir,work,mesh,kdir,msk,maskpt)
!
!***********************************************************************
! BIEF   V6P1                                   21/08/2010
!***********************************************************************
!
!brief    TAKES INTO ACCOUNT POINTS OF TYPE DIRICHLET IN A SYSTEM
!+                OF LINEAR EQUATIONS WITH SYMMETRICAL MATRIX.
!+
!+            IN THE EQUATIONS FOR POINTS NOT OF TYPE DIRICHLET :
!+                DIRICHLET VALUES ARE REMOVED.
!+
!+            IN THE EQUATIONS FOR POINTS OF TYPE DIRICHLET :
!+                DEFINES AN EQUATION FIXING THE IMPOSED VALUE.
!
!warning  FOR SYSTEMS OF MATRICES BLOCKS :
!+            THE EXTRA-DIAGONAL MATRICES MUST BE NONSYMMETRICAL
!+            BECAUSE TAKING INTO ACCOUNT THE DIRICHLET POINTS
!+            MAKES THEM NONSYMMETRICAL
!
!history  J-M HERVOUET (LNHE)
!+        11/07/2008
!+        V5P9
!+   LIMPRO DIMENSION MODIFIED FOR QUADRATIC ELEMENTS
!
!history  N.DURAND (HRW), S.E.BOURBAN (HRW)
!+        13/07/2010
!+        V6P0
!+   Translation of French comments within the FORTRAN sources into
!+   English comments
!
!history  N.DURAND (HRW), S.E.BOURBAN (HRW)
!+        21/08/2010
!+        V6P0
!+   Creation of DOXYGEN tags for automated documentation and
!+   cross-referencing of the FORTRAN sources
!
!~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~
!| F              |-->| VARIABLE THAT WILL BE GIVEN ITS DIRICHLET VALUE
!| FBOR           |-->| DIRICHLET BOUNDARY CONDITIONS
!| KDIR           |-->| CONVENTION FOR DIRICHLET BOUNDARY CONDITIONS
!| LIMDIR         |-->| TYPES OF BOUNDARY CONDITIONS
!|                |   | IF LIMDIR(K) = KDIR LE KTH BOUNDARY POINT
!|                |   | IS OF DIRICHLET TYPE.
!| MASKPT         |-->| MASKING PER POINT.
!|                |   | =1. : NORMAL   =0. : MASKED
!| MESH           |-->| MESH STRUCTURE
!| MSK            |-->| IF YES, THERE IS MASKED ELEMENTS.
!| S              |<->| MATRIX OF THE LINEAR SYSTEM
!| SM             |-->| RIGHT HAND SIDE
!| WORK           |-->| BLOCK OF WORK ARRAYS
!~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~
!
      USE bief, ex_dirich => dirich
!
      USE declarations_special
      IMPLICIT NONE
!
!+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+
!
      TYPE(bief_mesh), INTENT(INOUT) :: MESH
!                                                   DIMLIM,6
      INTEGER        , INTENT(IN)    :: KDIR,LIMDIR(*)
      LOGICAL        , INTENT(IN)    :: MSK
      TYPE(bief_obj) , INTENT(INOUT) :: WORK
      TYPE(bief_obj) , INTENT(INOUT) :: F,SM,S
      TYPE(bief_obj) , INTENT(IN)    :: FBOR,MASKPT
!
!+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+
!
      INTEGER DIMLIM
!
!----------------------------------------------------------------------
!
!  IF S IS A MATRIX
!
      IF(s%TYPE.EQ.3) THEN
!
      CALL diri01(f, s, sm , fbor,limdir,work%ADR(1)%P,work%ADR(2)%P,
     &            mesh,kdir,msk,maskpt)
!
!  IF S IS A BLOCK OF 4 MATRICES
!
      ELSEIF(s%TYPE.EQ.4.AND.s%N.EQ.4) THEN
!
      dimlim=max(fbor%ADR(1)%P%DIM1,
     &           fbor%ADR(2)%P%DIM1)
!
      CALL diri04(f%ADR(1)%P,f%ADR(2)%P,
     &     s%ADR(1)%P,s%ADR(2)%P,s%ADR(3)%P,s%ADR(4)%P,
     &     sm%ADR(1)%P,sm%ADR(2)%P,
     &     work%ADR(1)%P,work%ADR(2)%P,work%ADR(3)%P,work%ADR(4)%P,
     &     fbor%ADR(1)%P,fbor%ADR(2)%P,
     &     limdir(1:dimlim),limdir(dimlim+1:2*dimlim),
     &     mesh,kdir,msk,maskpt)
!
!  IF S IS A BLOCK OF 9 MATRICES
!
      ELSEIF(s%TYPE.EQ.4.AND.s%N.EQ.9) THEN
!
      dimlim=max(fbor%ADR(1)%P%DIM1,
     &           fbor%ADR(2)%P%DIM1,
     &           fbor%ADR(3)%P%DIM1)
!
      CALL diri09(f%ADR(1)%P,f%ADR(2)%P,f%ADR(3)%P,
     &            s%ADR(1)%P,s%ADR(2)%P,s%ADR(3)%P,
     &            s%ADR(4)%P,s%ADR(5)%P,s%ADR(6)%P,
     &            s%ADR(7)%P,s%ADR(8)%P,s%ADR(9)%P,
     &            sm%ADR(1)%P,sm%ADR(2)%P,sm%ADR(3)%P,
     &            work%ADR(1)%P,work%ADR(2)%P,work%ADR(3)%P,
     &            work%ADR(4)%P,work%ADR(5)%P,work%ADR(6)%P,
     &            fbor%ADR(1)%P,fbor%ADR(2)%P,fbor%ADR(3)%P,
     &            limdir(         1:  dimlim),
     &            limdir(  dimlim+1:2*dimlim),
     &            limdir(2*dimlim+1:3*dimlim),
     &            mesh,kdir,msk,maskpt)
!
!  ERROR
!
      ELSE
!
        WRITE(lu,1001) s%TYPE
1001    FORMAT(1x,'DIRICH (BIEF): WRONG TYPE FOR S:',1i6)
        CALL plante(1)
        stop
!
      ENDIF
!
!----------------------------------------------------------------------
!
      RETURN
      END