diraux.f

Go to the documentation of this file.

!                   *****************
                    SUBROUTINE diraux
!                   *****************
!
     & ( x , y , z , w , f , indic , criter , mesh )
!
!***********************************************************************
! BIEF   V6P1                                   21/08/2010
!***********************************************************************
!
!brief    HELPS PREPARE A LINEAR SYSTEM WITH DIRICHLET CONDITIONS.
!code
!+             X, Y AND Z MUST BE STRUCTURES.
!+
!+             HERE X IS A VECTOR DEFINED ON THE DOMAIN
!+                  Y IS A VECTOR DEFINED ON THE DOMAIN
!+                  Z IS A VECTOR DEFINED ON THE DOMAIN OR BOUNDARY
!+
!+             INDIC IS AN ARRAY, NOT A STRUCTURE ||||||||||
!+
!+  |||||||| : THE OPERATION IS ONLY PERFORMED IF INDIC(K)=CRITER
!+             FOR A GLOBAL OR BOUNDARY NUMBER K.
!+
!+  OPERATIONS :
!+
!+             W SET TO 0.D0 FOR POINTS WHERE INDIC(K) = CRITER
!+                   TO 1.D0 OTHERWISE
!+
!+             X = Y MULTIPLIED BY Z IF INDIC(K) = CRITER
!+
!+             F = Z IF INDIC(K) = CRITER
!+
!+  THESE OPERATIONS ARE USED TO TREAT THE POINTS OF TYPE DIRICHLET.
!+
!+             X IS THE SECOND MEMBER (WILL BE EQUAL TO THE DIAGONAL
!+             MULTIPLIED BY THE DIRICHLET VALUE Z)
!+
!+             F IS THE UNKNOWN (SET TO ITS DIRICHLET VALUE)
!+
!+             W IS A WORKING ARRAY USED TO CANCEL THE MATRICES
!+             TERMS TOUCHING DIRICHLET POINTS
!
!history  J-M HERVOUET (LNH)
!+        06/12/94
!+        V5P1
!+
!
!history  N.DURAND (HRW), S.E.BOURBAN (HRW)
!+        13/07/2010
!+        V6P0
!+   Translation of French comments within the FORTRAN sources into
!+   English comments
!
!history  N.DURAND (HRW), S.E.BOURBAN (HRW)
!+        21/08/2010
!+        V6P0
!+   Creation of DOXYGEN tags for automated documentation and
!+   cross-referencing of the FORTRAN sources
!
!~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~
!| CRITER         |-->| INTEGER, CONVENTION FOR DIRICHLET
!| F              |-->| VARIABLE THAT WILL BE GIVEN ITS DIRICHLET VALUE
!|                |   | TAKEN IN Z
!| INDIC          |-->| BOUNDARY CONDITIONS AT VALUE CRITER OR NOT
!| MESH           |-->| MESH STRUCTURE
!| W              |<->| WORK ARRAY
!| X              |<--| Y MULTIPLIED BY Z IF INDIC(K) = CRITER
!| Y              |-->| VECTOR, A DATA
!| Z              |-->| DIRICHLET VALUES
!~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~
!
      USE bief, ex_diraux => diraux
!
      USE declarations_special
      IMPLICIT NONE
!
!+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+
!
      TYPE(bief_obj) , INTENT(INOUT) :: X,W,F
      TYPE(bief_obj) , INTENT(IN)    :: Y,Z
      INTEGER        , INTENT(IN)    :: INDIC(*),CRITER
      TYPE(bief_mesh), INTENT(IN)    :: MESH
!
!+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+
!
      INTEGER K,NPOIN,IELMX,IELMZ,N
!
!-----------------------------------------------------------------------
!
      npoin = z%DIM1
!
!-----------------------------------------------------------------------
!
!  W SET TO 1
!
      CALL os( 'X=C     ' , x=w , c=1.d0 )
!
!-----------------------------------------------------------------------
!
      ielmx=x%ELM
      ielmz=z%ELM
!
      IF(ielmx.NE.ielmz) THEN
!
        DO k=1,npoin
          IF(indic(k).EQ.criter) THEN
            n = mesh%NBOR%I(k)
            x%R(n) = y%R(n) * z%R(k)
            w%R(n) = 0.d0
            f%R(n) = z%R(k)
          ENDIF
        ENDDO
!
      ELSE
!
        DO k=1,npoin
          IF(indic(k).EQ.criter) THEN
            x%R(k) = y%R(k) * z%R(k)
            w%R(k) = 0.d0
            f%R(k) = z%R(k)
          ENDIF
        ENDDO
!
      ENDIF
!
!-----------------------------------------------------------------------
!
      RETURN
      END