dirale.f

Go to the documentation of this file.

!                   *****************
                    SUBROUTINE dirale
!                   *****************
!
     &(dale,expos,tetah,tetmin,tetmax,ndale)
!
!***********************************************************************
! ARTEMIS   V6P1                                   21/08/2010
!***********************************************************************
!
!brief    DISCRETISES A DIRECTIONAL ENERGY SPECTRUM IN
!+                NDALE BANDS OF EQUAL ENERGY. THE RESULT IS A
!+                LIST OF DIRECTIONS CORRESPONDING TO EACH BAND.
!+
!+      USES THE FORMULATION GIVEN BY GODA IN ' RANDOM SEAS AND
!+      DESIGN OF MARITIME STRUCTURES' - UNIVERSITY OF TOKYO PRESS
!+
!+      G = ( COS( (TETA-TETAH))/2 ) )**EXPOS
!
!history  J-M HERVOUET (LNH)
!+
!+
!+   LINKED TO BIEF 5.0
!
!history  D. AELBRECHT (LNH)
!+        02/06/1999
!+        V5P1
!+
!
!history  N.DURAND (HRW), S.E.BOURBAN (HRW)
!+        13/07/2010
!+        V6P0
!+   Translation of French comments within the FORTRAN sources into
!+   English comments
!
!history  N.DURAND (HRW), S.E.BOURBAN (HRW)
!+        21/08/2010
!+        V6P0
!+   Creation of DOXYGEN tags for automated documentation and
!+   cross-referencing of the FORTRAN sources
!
!~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~
!| DALE           |<--| DIRECTIONS FOR SPECTRUM DISCRETISATION
!| EXPOS          |-->| COEFFICIENT FOR THE SPECTRUM FORMULA
!| NDALE          |-->| NUMBER OF DISCRETISATION BAND
!| TETAH          |-->| MAIN DIRECTION OF THE PROPAGATION
!| TETMAX         |-->| MAXIMUM VALUE FOR THE PROPAGATION ANGLE
!| TETMIN         |-->| MAXIMUM VALUE FOR THE PROPAGATION ANGLE
!~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~
!
      USE bief
      USE interface_artemis, ONLY: spd
      USE declarations_artemis, ONLY: expo
      USE declarations_special
      IMPLICIT NONE
!
      INTEGER NDALE,NPAS,I,K
!
      DOUBLE PRECISION DALE(ndale)
      DOUBLE PRECISION EXPOS,TETMIN,TETMAX,TETAH,DTETA,SUMB,VAR,SUMICI
!
!-----------------------------------------------------------------------
!
! EXPOS IS IN THE COMMON STATEMENT OF FUNCTION SPD (CANNOT BE
! CALLED EXPOS BECAUSE IT IS AN ARGUMENT OF THIS SUBROUTINE)
      expo = expos
!
!-----------------------------------------------------------------------
!
!     NUMBER OF INTEGRATION INTERVALS FOR THE TRAPEZOIDS METHOD
      npas = 2000*ndale
!
!     WIDTH OF AN INTEGRATION INTERVAL
      dteta = (tetmax-tetmin)/float(npas)
!
!     SURFACE OF THE SPECTRUM
      sumb = (spd(tetmin-tetah) + spd(tetmax-tetah))/2.d0
      DO i = 2,npas-1
        sumb = sumb + spd(tetmin-tetah+float(i)*dteta)
      ENDDO
!
!     DIVIDES THE SPECTRUM INTO 2*NDALE BANDS OF EQUAL ENERGY
      sumb = sumb/float(2*ndale)
!
!     IDENTIFIES THE ANGLES EVERY (2*I-1)*SUMB (I=1,NDALE)
      sumici = spd(tetmin-tetah)/2.d0
      i   = 1
      DO k=1,npas
        var = spd(tetmin-tetah+dteta*float(k))
        sumici = sumici + var/2.d0
        IF (sumici.GE.sumb*float(2*i-1)) THEN
          dale(i) =  tetmin + dteta*(float(k)-0.5d0)
          i = i + 1
          IF (i.GT.ndale) RETURN
        ENDIF
        sumici = sumici + var/2.d0
      ENDDO
!
!-----------------------------------------------------------------------
!
      RETURN
      END SUBROUTINE