diffin.f

Go to the documentation of this file.

!                   *****************
                    SUBROUTINE diffin
!                   *****************
!
     &(masktr,limtra,litbor,clt,u,v,xnebor,ynebor,nbor,
     & nptfr,kent,ksort,klog,kneu,kdir,kddl,
     & iconv,nelbor,npoin,msk,maskel,
     & nfrliq,thomfr,frtype,tn,tbor,numliq,iklbor,neleb,nelebx)
!
!***********************************************************************
! BIEF   V7P0                                   21/08/2010
!***********************************************************************
!
!brief    INITIALISES THE BOUNDARY CONDITIONS FOR TRACER DIFFUSION.
!
!history  J-M HERVOUET (LNH)
!+        25/06/2008
!+        V5P9
!+   MOVED FROM TELEMAC-2D TO ALLOW CALL BY SISYPHE
!
!history  N.DURAND (HRW), S.E.BOURBAN (HRW)
!+        13/07/2010
!+        V6P0
!+   Translation of French comments within the FORTRAN sources into
!+   English comments
!
!history  N.DURAND (HRW), S.E.BOURBAN (HRW)
!+        21/08/2010
!+        V6P0
!+   Creation of DOXYGEN tags for automated documentation and
!+   cross-referencing of the FORTRAN sources
!
!history  J-M HERVOUET (LNH)
!+        28/046/2011
!+        V6P1
!+   LIQUID BOUNDARIES MASK ADDED
!+   CALL PARCOM_BORD DELETED (NOT USEFUL, WE DEAL HERE WITH SEGMENTS
!+   WHICH BELONG TO A SINGLE PROCESSOR)
!
!history  J-M HERVOUET (EDF LAB, LNHE)
!+        13/03/2014
!+        V7P0
!+   Now written to enable different numbering of boundary points and
!+   boundary segments.
!
!~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~
!| CLT            |<--| A MODIFIED COPY OF LITBOR.
!| FRTYPE         |-->| TYPE OF BOUNDARY CONDITIONS
!|                |   | 1: NORMAL   2: THOMPSON
!| ICONV          |-->| OPTION FOR ADVECTION : 1) CHARACTERISTICS
!|                |   |                        2) SUPG, ETC.
!| IKLBOR         |-->| CONNECTIVITY TABLE FOR BOUNDARY ELEMENTS
!| KDDL           |-->| CONVENTION FOR DEGREE OF FREEDOM
!| KDIR           |-->| CONVENTION FOR DIRICHLET POINT
!| KENT           |-->| CONVENTION FOR LIQUID INPUT WITH PRESCRIBED VALUE
!| KLOG           |-->| CONVENTION FOR SOLID BOUNDARY
!| KNEU           |-->| CONVENTION FOR NEUMANN CONDITION
!| KSORT          |-->| CONVENTION FOR LIQUID OUTPUT WITH FREE VALUE
!| LIMTRA         |<--| TECHNICAL BOUNDARY CONDITIONS FOR TRACERS
!| LITBOR         |-->| PHYSICAL BOUNDARY CONDITIONS FOR TRACERS
!| MASKEL         |-->| MASKING OF ELEMENTS
!|                |   | =1. : NORMAL   =0. : MASKED ELEMENT
!| MSK            |-->| IF YES, THERE IS MASKED ELEMENTS.
!| MSK            |-->| IF YES, THERE IS MASKED ELEMENTS.
!| NELBOR         |-->| FOR THE KTH BOUNDARY EDGE, GIVES THE CORRESPONDING
!|                |   | ELEMENT.
!| NELEB          |-->| NUMBER OF BOUNDARY ELEMENTS
!| NELEBX         |-->| MAXIMUM NUMBER OF BOUNDARY ELEMENTS
!| NFRLIQ         |-->| NUMBER OF LIQUID BOUNDARIES
!| NPOIN          |-->| NUMBER OF POINTS
!| NPTFR          |-->| NUMBER OF BOUNDARY POINTS
!| TBOR           |-->| DIRICHLET BOUNDARY CONDITIONS ON TRACERS
!| THOMFR         |-->| IF YES, THERE ARE THOMPSON BOUNDARY CONDITIONS
!| TN             |-->| TRACERS AT OLD TIME STEP
!| U              |-->| X-COMPONENT OF VELOCITY
!| V              |-->| Y-COMPONENT OF VELOCITY
!| XNEBOR         |-->| X-COMPONENT OF EXTERNAL NORMAL BOUNDARY VECTOR
!| YNEBOR         |-->| Y-COMPONENT OF EXTERNAL NORMAL BOUNDARY VECTOR
!~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~
!
      USE bief, ex_diffin => diffin
!
      USE declarations_special
      IMPLICIT NONE
!
!+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+
!
      TYPE(bief_obj), INTENT(INOUT) :: MASKTR,TBOR
      TYPE(bief_obj), INTENT(IN)    :: TN
      INTEGER, INTENT(IN)    :: NELEB,NELEBX
      INTEGER, INTENT(IN)    :: NPOIN,NPTFR,ICONV,NFRLIQ
      INTEGER, INTENT(IN)    :: LITBOR(nptfr),NBOR(nptfr)
      INTEGER, INTENT(INOUT) :: LIMTRA(nptfr),CLT(nptfr)
      INTEGER, INTENT(IN)    :: IKLBOR(nelebx,2)
      INTEGER, INTENT(IN)    :: KENT,KSORT,KLOG,KDIR,KDDL,KNEU
      INTEGER, INTENT(IN)    :: NELBOR(nelebx),NUMLIQ(*)
      INTEGER, INTENT(IN)    :: FRTYPE(nfrliq)
!
      DOUBLE PRECISION, INTENT(IN) :: U(npoin), V(npoin)
      DOUBLE PRECISION, INTENT(IN) :: XNEBOR(nptfr), YNEBOR(nptfr)
      DOUBLE PRECISION, INTENT(IN) :: MASKEL(*)
!
      LOGICAL, INTENT(IN) :: MSK,THOMFR
!
!+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+
!
      INTEGER K,K1,K2,IELEM,DIR,DDL,NEU,OND,NONEU,IFRLIQ,IELEB
      DOUBLE PRECISION USCALN
!
!-----------------------------------------------------------------------
!
      dir=1
      ddl=2
      neu=3
      ond=4
      noneu=5
!
!     CLT CONTAINS ARRAY LITBOR, POSSIBLY MODIFIED ACCORDING TO THE SIGN
!     OF U.N ON THE LIQUID BOUNDARIES, WHERE N IS THE OUTGOING NORMAL.
!
      DO k=1,nptfr
        clt(k) = litbor(k)
!       LOCATES THE LIQUID BOUNDARIES:
        IF(clt(k).EQ.kent) THEN
          uscaln = u(nbor(k))*xnebor(k) + v(nbor(k))*ynebor(k)
!         OUTGOING VELOCITY, FREE TRACER
          IF(uscaln.GT.0.d0) clt(k) = ksort
        ELSEIF(clt(k).EQ.ksort) THEN
          uscaln = u(nbor(k))*xnebor(k) + v(nbor(k))*ynebor(k)
!
!         INCOMING VELOCITY, TRACER IMPOSED AT THE LAST VALUE
          IF(uscaln.LT.0.d0) THEN
            tbor%R(k)=tn%R(nbor(k))
            clt(k) = kent
          ENDIF
        ENDIF
      ENDDO
!
!     BUILDS ARRAY MASKTR ACCORDING TO CLT
!
!     MASKTR EQUALS 1 FOR A SEGMENT OF TYPE NEUMANN, 0 OTHERWISE
!
!     A SEGMENT IS OF TYPE NEUMANN IF AT LEAST ONE OF ITS POINTS
!     IS SPECIFIED AS NEUMANN BY THE USER.
!
!
!     INITIALISES THE MASKS TO 0
!
      CALL os('X=0     ',x=masktr)
      DO ieleb = 1 , neleb
        k1=iklbor(ieleb,1)
        k2=iklbor(ieleb,2)
        IF(clt(k1).EQ.klog.OR.clt(k2).EQ.klog) THEN
!         SEGMENTS OF TYPE NEUMANN
          masktr%ADR(neu)%P%R(ieleb)=1.d0
        ELSEIF(clt(k1).EQ.kent.AND.clt(k2).EQ.ksort) THEN
!         SEGMENTS OF TYPE EXIT
          masktr%ADR(ddl)%P%R(ieleb)=1.d0
        ELSEIF(clt(k1).EQ.ksort.OR.clt(k2).EQ.ksort) THEN
          masktr%ADR(ddl)%P%R(ieleb)=1.d0
        ELSEIF(clt(k1).EQ.ksort.AND.clt(k2).EQ.kent) THEN
!         SEGMENTS OF TYPE EXIT
          masktr%ADR(ddl)%P%R(ieleb)=1.d0
        ELSEIF(clt(k1).EQ.kent.OR.clt(k2).EQ.kent) THEN
          masktr%ADR(dir)%P%R(ieleb)=1.d0
        ELSE
          WRITE(lu,101)
101       FORMAT(1x,'DIFFIN : UNEXPECTED CASE')
          CALL plante(1)
          stop
        ENDIF
      ENDDO
!
!  POSSIBLE MASKING
!
      IF(msk) THEN
        DO ieleb = 1 , neleb
          k1=iklbor(ieleb,1)
          ielem=nelbor(ieleb)
          masktr%ADR(dir)%P%R(ieleb) = masktr%ADR(dir)%P%R(ieleb) *
     &                                                   maskel(ielem)
          masktr%ADR(ddl)%P%R(ieleb) = masktr%ADR(ddl)%P%R(ieleb) *
     &                                                   maskel(ielem)
          masktr%ADR(neu)%P%R(ieleb) = masktr%ADR(neu)%P%R(ieleb) *
     &                                                   maskel(ielem)
          masktr%ADR(ond)%P%R(ieleb) = masktr%ADR(ond)%P%R(ieleb) *
     &                                                   maskel(ielem)
        ENDDO
      ENDIF
!
!-----------------------------------------------------------------------
!
!     LIQUID BOUNDARIES MASK
!
      DO ieleb=1,neleb
        masktr%ADR(noneu)%P%R(ieleb)=1.d0-masktr%ADR(neu)%P%R(ieleb)
      ENDDO
!
!-----------------------------------------------------------------------
!
! FROM PHYSICAL TO TECHNICAL CONDITIONS
!
      DO k=1,nptfr
!
        IF(clt(k).EQ.kent ) THEN
!
!         ENTERING THE DOMAIN: IMPOSED TRACER
!
          limtra(k) = kdir
!
        ELSEIF(clt(k).EQ.ksort) THEN
!
!         LEAVING THE DOMAIN : FREE IF SUPG OR PSI SCHEME,
!                              RESULT OF IMPOSED ADVECTION OTHERWISE
!
          IF(iconv.EQ.1) THEN
!           SEE DIFFCL : TTILD PUT IN TBOR
            limtra(k) = kdir
          ELSE
            limtra(k) = kddl
          ENDIF
!
        ELSEIF(clt(k).EQ.klog ) THEN
!
!         WALL: NEUMANN CONDITIONS (IT'S NOT ACTUALLY USED)
!
          limtra(k) = kneu
!
        ELSE
!
!         ERROR, UNKNOWN VALUE OF LITBOR
!
          WRITE(lu,12) k,litbor(k)
12        FORMAT(1x,'DIFFIN: POINT ',1i6,' LITBOR= ',1i6,' ?????')
          CALL plante(1)
          stop
!
        ENDIF
!
      ENDDO
!
!----------------------------------------------------------------------
!
!     POST-TREATMENT FOR LIQUID BOUNDARY CONDITIONS (THOMPSON METHOD)
!     THE TRACER BOUNDARY CONDITION THEN IS OF TYPE DIRICHLET
!
      IF(nfrliq.GT.0.AND.thomfr) THEN
!
        DO k= 1 , nptfr
          ifrliq=numliq(k)
          IF(ifrliq.GT.0) THEN
            IF(frtype(ifrliq).EQ.2) limtra(k) = kdir
          ENDIF
        ENDDO
!
      ENDIF
!
!-----------------------------------------------------------------------
!
      RETURN
      END