decv11.f

Go to the documentation of this file.

!                   *****************
                    SUBROUTINE decv11
!                   *****************
!
     &(teta,sl,zf,ikle,nelem,nelmax)
!
!***********************************************************************
! BIEF   V6P1                                   21/08/2010
!***********************************************************************
!
!brief    IDENTIFIES TIDAL FLATS.
!+
!+            DRYING ELEMENT : TETA = 0,
!+
!+            NORMAL ELEMENT : TETA = 1.
!+
!+            THE CRITERION FOR DRYING ELEMENTS IS THAT OF
!+                J.-M. JANIN : BOTTOM ELEVATION OF A POINT IN AN
!+                ELEMENT BEING HIGHER THAN THE FREE SURFACE
!+                ELEVATION OF ANOTHER.
!
!history  J-M HERVOUET (LNH)
!+        09/12/94
!+        V5P1
!+
!
!history  N.DURAND (HRW), S.E.BOURBAN (HRW)
!+        13/07/2010
!+        V6P0
!+   Translation of French comments within the FORTRAN sources into
!+   English comments
!
!history  N.DURAND (HRW), S.E.BOURBAN (HRW)
!+        21/08/2010
!+        V6P0
!+   Creation of DOXYGEN tags for automated documentation and
!+   cross-referencing of the FORTRAN sources
!
!history  J-M HERVOUET (LNHE)
!+        12/06/2012
!+        V6P2
!+   Optimisation
!
!~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~
!| IKLE           |-->| CONNECTIVITY TABLE
!| NELEM          |-->| NUMBER OF ELEMENTS IN THE MESH
!| NELMAX         |-->| MAXIMUM NUMBER OF ELEMENTS IN THE MESH
!| SL             |-->| FREE SURFACE
!| TETA           |<--| STATES IF AN ELEMENT IS DRY OR NOT
!| ZF             |-->| BOTTOM ELEVATION
!~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~
!
      USE declarations_special
      IMPLICIT NONE
!
!+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+
!
      INTEGER         , INTENT(IN)  :: NELEM,NELMAX
      INTEGER         , INTENT(IN)  :: IKLE(nelmax,*)
      DOUBLE PRECISION, INTENT(OUT) :: TETA(nelem)
      DOUBLE PRECISION, INTENT(IN)  :: SL(*),ZF(*)
!
!+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+
!
      INTEGER IELEM
!
      DOUBLE PRECISION SL1,SL2,SL3,ZF1,ZF2,ZF3
!
      INTRINSIC max,min
!
!-----------------------------------------------------------------------
!
      DO ielem = 1 , nelem
!
        sl1 = sl(ikle(ielem,1))
        sl2 = sl(ikle(ielem,2))
        sl3 = sl(ikle(ielem,3))
!
        zf1 = zf(ikle(ielem,1))
        zf2 = zf(ikle(ielem,2))
        zf3 = zf(ikle(ielem,3))
!
        IF(max(zf1,zf2,zf3).GT.min(sl1,sl2,sl3)) THEN
          teta(ielem) = 0.d0
        ELSE
          teta(ielem) = 1.d0
        ENDIF
!
      ENDDO
!
!-----------------------------------------------------------------------
!
      RETURN
      END