decldu.f

Go to the documentation of this file.

!                   *****************
                    SUBROUTINE decldu
!                   *****************
!
     &(b,a,mesh,copy,lv)
!
!***********************************************************************
! BIEF   V6P1                                   21/08/2010
!***********************************************************************
!
!brief    L D U FACTORISATION OF THE ELEMENTARY MATRICES
!+                IN MATRIX A.
!+
!+            REQUIRES THAT THE DIAGONAL OF A BE THE IDENTITY.
!code
!+            EACH ELEMENTARY MATRIX IS DECOMPOSED IN THE FORM:
!+
!+            LE X DE X UE
!+
!+            LE : LOWER TRIANGULAR WITH 1S ON THE DIAGONAL
!+            DE : DIAGONAL
!+            UE : UPPER TRIANGULAR WITH 1S ON THE DIAGONAL
!+
!+                                                T
!+            IF THE MATRIX IS SYMMETRICAL : LE =  UE
!+
!+            "DE" MATRICES ARE CONSIDERED LIKE DIAGONALS OF SIZE
!+            NPOIN X NPOIN, WHICH ARE FILLED WITH 1S FOR THE POINTS
!+            WHICH DO NOT BELONG TO THE CONSIDERED ELEMENT
!+
!+            THEN PERFORMS THE PRODUCT OF ALL THESE DIAGONALS
!+            YIELDING DIAGONAL DB
!+
!+   ||||||   FINALLY: DB IS INVERTED BECAUSE THAT'S HOW IT WILL BE
!+                     USED IN DESREM
!
!code
!+-----------------------------------------------------------------------
!+  MEANING OF IELM :
!+
!+  TYPE OF ELEMENT      NUMBER OF POINTS      CODED IN THIS SUBROUTINE
!+
!+  11 : P1 TRIANGLE            3                       YES
!+  21 : Q1 QUADRILATERAL       4                       YES
!+  41 : TELEMAC-3D PRISMS      6                       YES
!+
!+-----------------------------------------------------------------------
!
!history  J-M HERVOUET (LNH)
!+        26/02/04
!+        V5P5
!+
!
!history  N.DURAND (HRW), S.E.BOURBAN (HRW)
!+        13/07/2010
!+        V6P0
!+   Translation of French comments within the FORTRAN sources into
!+   English comments
!
!history  N.DURAND (HRW), S.E.BOURBAN (HRW)
!+        21/08/2010
!+        V6P0
!+   Creation of DOXYGEN tags for automated documentation and
!+   cross-referencing of the FORTRAN sources
!
!~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~
!| A              |<--| MATRIX A.
!| B              |<--| MATRICE B, THE RESULT.
!| COPY           |-->| IF .TRUE. A IS COPIED INTO B.
!|                |   | IF .FALSE. B IS CONSIDERED ALREADY INITIALISED
!| LV             |-->| VECTOR LENGTH OF THE COMPUTER
!| MESH           |-->| MESH STRUCTURE
!~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~
!
      USE bief, ex_decldu => decldu
!
      USE declarations_special
      IMPLICIT NONE
!
!+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+
!
      TYPE(bief_obj) , INTENT(INOUT) :: B
      TYPE(bief_obj) , INTENT(IN)    :: A
      TYPE(bief_mesh), INTENT(INOUT) :: MESH
      LOGICAL        , INTENT(IN)    :: COPY
      INTEGER        , INTENT(IN)    :: LV
!
!+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+
!
      INTEGER NELMAX,IELM,NPOIN,NELEM
!
      CHARACTER(LEN=1) TYPDA,TYPEA
!
!-----------------------------------------------------------------------
!
      ielm   = a%ELMLIN
      nelem  = mesh%NELEM
      nelmax = mesh%NELMAX
!
      typda = a%TYPDIA
      typea = a%TYPEXT
!
      npoin = a%D%DIM1
!
!-----------------------------------------------------------------------
!
      IF(a%STO.EQ.1) THEN
!
      IF(ielm.EQ.11) THEN
!
        CALL dldu11(b%D%R,b%X%R,typda,a%X%R,typea,
     &              mesh%IKLE%I,nelem,nelmax,npoin,mesh%W%R,copy,lv)
!
      ELSEIF(ielm.EQ.21.OR.ielm.EQ.12.OR.ielm.EQ.31.OR.ielm.EQ.51) THEN
!
        CALL dldu21(b%D%R,b%X%R,typda,a%X%R,typea,
     &              mesh%IKLE%I,nelem,nelmax,npoin,mesh%W%R,copy,lv)
!
      ELSEIF(ielm.EQ.41) THEN
!
        CALL dldu41(b%D%R,b%X%R,typda,a%X%R,typea,
     &              mesh%IKLE%I,nelem,nelmax,npoin,mesh%W%R,copy,lv)
!
!  IELM NOT IMPLEMENTED: ERROR
!
      ELSE
        WRITE(lu,101) ielm
101   FORMAT(1x,'DECLDU (BIEF) : IELM = ',1i6,' ELEMENT NOT AVAILABLE')
        CALL plante(1)
        stop
      ENDIF
!
      ELSEIF(a%STO.EQ.3) THEN
        CALL dlduseg(b%D%R,b%X%R,typda,a%X%R,typea,
     &               mesh%GLOSEG%I,mesh%NSEG,npoin,copy)
      ELSE
        WRITE(lu,*) 'UNKNOWN MATRIX STORAGE IN DECLDU'
        CALL plante(1)
        stop
      ENDIF
!
!-----------------------------------------------------------------------
!
!  DESCRIPTION OF B
!
      b%TYPDIA='Q'
      b%TYPEXT=typea
!
!-----------------------------------------------------------------------
!
      RETURN
      END