dcpldu.f

Go to the documentation of this file.

!                   *****************
                    SUBROUTINE dcpldu
!                   *****************
!
     &(b,a,mesh,copy,lv)
!
!***********************************************************************
! BIEF   V6P1                                   21/08/2010
!***********************************************************************
!
!brief    L D U FACTORISATION OF THE ELEMENTARY MATRICES
!+                IN MATRIX A.
!+
!+           (A CAN ALSO BE A BLOCK OF MATRICES, IN WHICH CASE
!+                THE DIAGONAL MATRICES OF THE BLOCK ARE TREATED).
!+
!+            REQUIRES THAT THE DIAGONAL OF A BE THE IDENTITY.
!code
!+            EACH ELEMENTARY MATRIX IS DECOMPOSED IN THE FORM:
!+
!+            LE X DE X UE
!+
!+            LE : LOWER TRIANGULAR WITH 1S ON THE DIAGONAL
!+            DE : DIAGONAL
!+            UE : UPPER TRIANGULAR WITH 1S ON THE DIAGONAL
!+
!+                                                T
!+            IF THE MATRIX IS SYMMETRICAL : LE =  UE
!+
!+            "DE" MATRICES ARE CONSIDERED LIKE DIAGONALS OF SIZE
!+            NPOIN X NPOIN, WHICH ARE FILLED WITH 1S FOR THE POINTS
!+            WHICH DO NOT BELONG TO THE CONSIDERED ELEMENT
!+
!+            THEN PERFORMS THE PRODUCT OF ALL THESE DIAGONALS
!+            YIELDING DIAGONAL DB
!+
!+   ||||||   FINALLY: DB IS INVERTED BECAUSE THAT'S HOW IT WILL BE
!+                     USED IN DOWNUP.
!
!history  J-M HERVOUET (LNH)
!+        23/12/94
!+        V5P1
!+
!
!history  N.DURAND (HRW), S.E.BOURBAN (HRW)
!+        13/07/2010
!+        V6P0
!+   Translation of French comments within the FORTRAN sources into
!+   English comments
!
!history  N.DURAND (HRW), S.E.BOURBAN (HRW)
!+        21/08/2010
!+        V6P0
!+   Creation of DOXYGEN tags for automated documentation and
!+   cross-referencing of the FORTRAN sources
!
!~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~
!| A              |<--| MATRIX A.
!| B              |<--| MATRICE B, THE RESULT.
!| COPY           |-->| IF .TRUE. A IS COPIED INTO B.
!|                |   | IF .FALSE. B IS CONSIDERED ALREADY INITIALISED
!| LV             |-->| VECTOR LENGTH OF THE COMPUTER
!| MESH           |-->| MESH STRUCTURE
!~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~
!
      USE bief, ex_dcpldu => dcpldu
!
      USE declarations_special
      IMPLICIT NONE
!
!+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+
!
      TYPE(bief_obj) , INTENT(INOUT) :: B
      TYPE(bief_obj) , INTENT(IN)    :: A
      TYPE(bief_mesh), INTENT(INOUT) :: MESH
      LOGICAL        , INTENT(IN)    :: COPY
      INTEGER        , INTENT(IN)    :: LV
!
!+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+
!
      INTEGER SA,SB,I
!
!-----------------------------------------------------------------------
!
      IF(a%TYPE.EQ.3) THEN
        sa = 0
      ELSEIF(a%TYPE.EQ.4) THEN
        sa = a%N
      ELSE
        WRITE(lu,400) a%TYPE
400     FORMAT(1x,'DCPLDU (BIEF) :',1i6,' UNEXPECTED TYPE FOR A.')
        CALL plante(1)
        stop
      ENDIF
!
      IF(b%TYPE.EQ.3) THEN
        sb = 0
      ELSEIF(b%TYPE.EQ.4) THEN
        sb = b%N
      ELSE
        WRITE(lu,401) b%TYPE
401     FORMAT(1x,'DCPLDU (BIEF) :',1i6,' UNEXPECTED TYPE FOR B.')
        CALL plante(1)
        stop
      ENDIF
!
!-----------------------------------------------------------------------
!
      IF(sa.EQ.0.AND.sb.EQ.0) THEN
!
        CALL decldu(b,a,mesh,copy,lv)
!
      ELSEIF(sb.GT.0.AND.sa.GT.0) THEN
!
!       TAKES THE DIAGONALS OF BLOCK A
!
        DO i=1,sb
          CALL decldu(b%ADR(i)%P,a%ADR(1+(sb+1)*(i-1))%P,
     &                mesh,copy,lv)
        ENDDO
!
      ELSEIF(sa.NE.0.AND.sb.EQ.0) THEN
!
!       TAKES THE FIRST DIAGONAL OF BLOCK A
!
        CALL decldu(b,a%ADR(1)%P,mesh,copy,lv)
!
      ELSE
!
        WRITE(lu,402)
402     FORMAT(1x,'DCPLDU (BIEF) : UNEXPECTED CASE')
        CALL plante(1)
        stop
!
      ENDIF
!
!-----------------------------------------------------------------------
!
      RETURN
      END